Add a BUILD target and a script to build a public static library for ios/web_view.

ios/web_view/internal/BUILD.gn

 # Copyright 2016 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
-source_set("internal") {
-  visibility = [
-    "//ios/web_view",
-    "//ios/web_view/internal/*",
-  ]
+_deps = [
+  "//base",
+  "//components/pref_registry",
+  "//components/prefs",
+  "//components/translate/core/browser",
+  "//components/translate/core/common",
+  "//ios/net",
+  "//ios/web",
+  "//ios/web:user_agent",
+  "//ios/web/public/app",
+  "//ios/web_view/internal/translate",
+  "//ios/web_view/public",
+  "//net",
+  "//net:extras",
+  "//ui/base",
+  "//url",
+]
+
+# An incomplete static library for //ios/web_view.
+static_library("web_view_incomplete") {
+  visibility = [ ":*" ]
 
   sources = [
     "cwv.mm",
     "cwv_html_element.mm",
     "cwv_html_element_internal.h",
     "cwv_web_view.mm",
     "cwv_web_view_configuration.mm",
     "cwv_website_data_store.mm",
     "cwv_website_data_store_internal.h",
     "pref_names.cc",
     "pref_names.h",
     "web_view_browser_state.h",
     "web_view_browser_state.mm",
     "web_view_java_script_dialog_presenter.h",
     "web_view_java_script_dialog_presenter.mm",
     "web_view_network_delegate.cc",
     "web_view_network_delegate.h",
     "web_view_url_request_context_getter.h",
     "web_view_url_request_context_getter.mm",
     "web_view_web_client.h",
     "web_view_web_client.mm",
     "web_view_web_main_delegate.h",
     "web_view_web_main_delegate.mm",
     "web_view_web_main_parts.h",
     "web_view_web_main_parts.mm",
   ]
-  deps = [
-    "//base",
-    "//components/pref_registry",
-    "//components/prefs",
-    "//components/translate/core/browser",
-    "//components/translate/core/common",
-    "//ios/net",
-    "//ios/web",
-    "//ios/web:user_agent",
-    "//ios/web/public/app",
-    "//ios/web_view/internal/translate",
-    "//ios/web_view/public",
-    "//net",
-    "//net:extras",
-    "//ui/base",
-    "//url",
-  ]
+
+  deps = _deps
+
+  configs += [ "//build/config/compiler:enable_arc" ]
 
   allow_circular_includes_from = [ "//ios/web_view/internal/translate" ]
+}
 
-  configs += [ "//build/config/compiler:enable_arc" ]
+# A static library which contains all dependencies of :web_view_incomplete.
+static_library("deps_complete") {
+  visibility = [ ":*" ]
+  complete_static_lib = true
+  deps = _deps
 }
+
+# See the comment of //ios/web_view, which is a public alias of this library.
+#
+# TODO(crbug.com/689755): Support building a universal binary.
+action("lib_web_view") {
+  visibility = [
+    "//ios/web_view",
+    "//ios/web_view/internal/*",
+  ]
+  script = "hide_symbols.py"
+  deps = [
+    ":deps_complete",
+    ":web_view_incomplete",
+  ]
+  outputs = [
+    "$target_out_dir/libweb_view.a",
+    "$target_out_dir/libweb_view.o",
+  ]
+  args = [
+    "--input_libs",
+    rebase_path("$target_out_dir/libweb_view_incomplete.a", root_build_dir),
+    "--deps_lib",
+    rebase_path("$target_out_dir/libdeps_complete.a", root_build_dir),
+    "--output_obj",
+    rebase_path("$target_out_dir/libweb_view.o", root_build_dir),
+    "--output_lib",
+    rebase_path("$target_out_dir/libweb_view.a", root_build_dir),
+    "--current_cpu",
+    current_cpu,
+  ]
+}