Add a BUILD target and a script to build a public static library for ios/web_view.

ios/web_view/internal/BUILD.gn

 # Copyright 2016 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
-source_set("internal") {
+DEPS = [
+  "//base",
+  "//components/pref_registry",
+  "//components/prefs",
+  "//components/translate/core/browser",
+  "//components/translate/core/common",
+  "//ios/net",
+  "//ios/web",
+  "//ios/web:user_agent",
+  "//ios/web/public/app",
+  "//ios/web_view/internal/translate",
+  "//ios/web_view/public",
+  "//net",
+  "//net:extras",
+  "//ui/base",
+  "//url",
+]
+
+static_library("internal") {
   visibility = [
     "//ios/web_view",
     "//ios/web_view/internal/*",
   ]
 
   sources = [
     "criwv.mm",
     "criwv_browser_state.h",
     "criwv_browser_state.mm",
     "criwv_network_delegate.cc",
     "criwv_network_delegate.h",
     "criwv_url_request_context_getter.h",
     "criwv_url_request_context_getter.mm",
     "criwv_web_client.h",
     "criwv_web_client.mm",
     "criwv_web_main_delegate.h",
     "criwv_web_main_delegate.mm",
     "criwv_web_main_parts.h",
     "criwv_web_main_parts.mm",
     "criwv_web_view_impl.h",
     "criwv_web_view_impl.mm",
     "pref_names.cc",
     "pref_names.h",
   ]
-  deps = [
-    "//base",
-    "//components/pref_registry",
-    "//components/prefs",
-    "//components/translate/core/browser",
-    "//components/translate/core/common",
-    "//ios/net",
-    "//ios/web",
-    "//ios/web:user_agent",
-    "//ios/web/public/app",
-    "//ios/web_view/internal/translate",
-    "//ios/web_view/public",
-    "//net",
-    "//net:extras",
-    "//ui/base",
-    "//url",
-  ]
+  deps = DEPS
   allow_circular_includes_from = [ "//ios/web_view/internal/translate" ]
 }
+
+# A static library which contains all dependencies of "internal".
+# Used to build "web_view_public".
+static_library("deps_complete") {
+  complete_static_lib = true
+  deps = DEPS
+}
+
+# A static library expected to be used by apps outside Chromium code base.
+# This is a complete static library (containing all dependencies),
+# and it doesn't expose internal symbols to reduce risk of symbol conflict.
+#
+# //ios/web_view:web_view_public is an alias of this library.
+#
+# TODO(ichikawa): Support building a universal binary.
+action("web_view_public") {
+  script = "hide_symbols.py"
+  deps = [
+    ":deps_complete",
+    ":internal",
+  ]
+  outputs = [
+    "$target_out_dir/libweb_view_public.a",
+    "$target_out_dir/libweb_view_public.o",
+  ]
+  args = [
+    "--input_lib",
+    rebase_path("$target_out_dir/libinternal.a", root_build_dir),
+    "--deps_lib",
+    rebase_path("$target_out_dir/libdeps_complete.a", root_build_dir),
+    "--output_obj",
+    rebase_path("$target_out_dir/libweb_view_public.o", root_build_dir),
+    "--output_lib",
+    rebase_path("$target_out_dir/libweb_view_public.a", root_build_dir),
+  ]
+}