Converts ios/chrome/browser/native_app_launcher:native_app_launcher_internal to ARC.

ios/chrome/browser/native_app_launcher/native_app_navigation_controller.mm

 // Copyright 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/native_app_launcher/native_app_navigation_controller.h"
 
 #import <StoreKit/StoreKit.h>
 
 #include "base/metrics/user_metrics.h"
 #include "base/metrics/user_metrics_action.h"
 #include "components/infobars/core/infobar_manager.h"
 #include "ios/chrome/browser/infobars/infobar_manager_impl.h"
 #import "ios/chrome/browser/installation_notifier.h"
 #include "ios/chrome/browser/native_app_launcher/native_app_infobar_delegate.h"
 #include "ios/chrome/browser/native_app_launcher/native_app_navigation_util.h"
 #import "ios/chrome/browser/open_url_util.h"
 #import "ios/chrome/browser/tabs/tab.h"
 #include "ios/public/provider/chrome/browser/chrome_browser_provider.h"
 #import "ios/public/provider/chrome/browser/native_app_launcher/native_app_metadata.h"
 #import "ios/public/provider/chrome/browser/native_app_launcher/native_app_types.h"
 #import "ios/public/provider/chrome/browser/native_app_launcher/native_app_whitelist_manager.h"
 #include "ios/web/public/web_state/web_state.h"
+#import "ios/web/web_state/ui/crw_web_controller.h"
 #import "net/base/mac/url_conversions.h"
 #include "net/url_request/url_request_context_getter.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 using base::UserMetricsAction;
 
 @interface NativeAppNavigationController ()
 // Shows a native app infobar by looking at the page's URL and by checking
 // wheter that infobar should be bypassed or not.
 - (void)showInfoBarIfNecessary;
 
 // Returns a pointer to the NSMutableSet of |_appsPossiblyBeingInstalled|
 - (NSMutableSet*)appsPossiblyBeingInstalled;
 
 // Records what type of infobar was opened.
 - (void)recordInfobarDisplayedOfType:(NativeAppControllerType)type
                     onLinkNavigation:(BOOL)isLinkNavigation;
 
 @end
 
 @implementation NativeAppNavigationController {
   // WebState provides access to the *TabHelper objects. This will eventually
   // replace the need to have |_tab| in this object.
   web::WebState* _webState;
   // A reference to the URLRequestContextGetter needed to fetch icons.
   scoped_refptr<net::URLRequestContextGetter> _requestContextGetter;
   // DEPRECATED: Tab hosting the infobar and is also used for accessing Tab
   // states such as navigation manager and whether it is a pre-rendered tab.
   // Use |webState| whenever possible.
-  __unsafe_unretained Tab* _tab;  // weak
-  base::scoped_nsprotocol<id<NativeAppMetadata>> _metadata;
+  __weak Tab* _tab;
+  id<NativeAppMetadata> _metadata;
   // A set of appIds encoded as NSStrings.
-  base::scoped_nsobject<NSMutableSet> _appsPossiblyBeingInstalled;
+  NSMutableSet* _appsPossiblyBeingInstalled;
 }
 
 // Designated initializer. Use this instead of -init.
 - (instancetype)initWithWebState:(web::WebState*)webState
             requestContextGetter:(net::URLRequestContextGetter*)context
                              tab:(Tab*)tab {
   self = [super init];
   if (self) {
     DCHECK(context);
     _requestContextGetter = context;
     DCHECK(webState);
     _webState = webState;
     // Allows |tab| to be nil for unit testing. If not nil, it should have the
     // same webState.
     DCHECK(!tab || [tab webState] == webState);
     _tab = tab;
-    _appsPossiblyBeingInstalled.reset([[NSMutableSet alloc] init]);
+    _appsPossiblyBeingInstalled = [[NSMutableSet alloc] init];
   }
   return self;
 }
 
 - (void)copyStateFrom:(NativeAppNavigationController*)controller {
   DCHECK(controller);
-  _appsPossiblyBeingInstalled.reset([[NSMutableSet alloc]
-      initWithSet:[controller appsPossiblyBeingInstalled]]);
-  for (NSString* appIdString in _appsPossiblyBeingInstalled.get()) {
+  _appsPossiblyBeingInstalled = [[NSMutableSet alloc]
+      initWithSet:[controller appsPossiblyBeingInstalled]];
+  for (NSString* appIdString in _appsPossiblyBeingInstalled) {
     DCHECK([appIdString isKindOfClass:[NSString class]]);
     NSURL* appURL =
         [ios::GetChromeBrowserProvider()->GetNativeAppWhitelistManager()
             schemeForAppId:appIdString];
     [[InstallationNotifier sharedInstance]
         registerForInstallationNotifications:self
                                 withSelector:@selector(appDidInstall:)
                                    forScheme:[appURL scheme]];
   }
   [self showInfoBarIfNecessary];
 }
 
 - (void)dealloc {
   [[InstallationNotifier sharedInstance] unregisterForNotifications:self];
-  [super dealloc];
 }
 
 - (NSMutableSet*)appsPossiblyBeingInstalled {
   return _appsPossiblyBeingInstalled;
 }
 
 - (void)showInfoBarIfNecessary {
   // Find a potential matching native app.
   GURL pageURL = _webState->GetLastCommittedURL();
-  _metadata.reset(
-      [ios::GetChromeBrowserProvider()->GetNativeAppWhitelistManager()
-          newNativeAppForURL:pageURL]);
+  _metadata = [ios::GetChromeBrowserProvider()->GetNativeAppWhitelistManager()
+      nativeAppForURL:pageURL];
   if (!_metadata || [_metadata shouldBypassInfoBars])
     return;
 
   // Select the infobar type.
   NativeAppControllerType type;
   bool isLinkNavigation = native_app_launcher::IsLinkNavigation(_webState);
   if ([_metadata canOpenURL:pageURL]) {  // App is installed.
     type = isLinkNavigation && ![_metadata shouldAutoOpenLinks]
                ? NATIVE_APP_OPEN_POLICY_CONTROLLER
                : NATIVE_APP_LAUNCHER_CONTROLLER;
@@ skipping 110 matching lines @@
         if ([[appURL scheme] isEqualToString:schemeOfInstalledApp]) {
           appIDToRemove = appID;
           *stop = YES;
         }
       }];
   DCHECK(appIDToRemove);
   [_appsPossiblyBeingInstalled removeObject:appIDToRemove];
 }
 
 @end