Create the IOSImageDataFetcherWrapper

components/image_fetcher/ios/ios_image_data_fetcher_wrapper.mm

Index: components/image_fetcher/ios/ios_image_data_fetcher_wrapper.mm
diff --git a/components/image_fetcher/ios/ios_image_data_fetcher_wrapper.mm b/components/image_fetcher/ios/ios_image_data_fetcher_wrapper.mm
new file mode 100644
index 0000000000000000000000000000000000000000..95746d9c221707bd69221becd5e0b113de72c4d8
--- /dev/null
+++ b/components/image_fetcher/ios/ios_image_data_fetcher_wrapper.mm
@@ -0,0 +1,116 @@
+// Copyright 2017 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "components/image_fetcher/ios/ios_image_data_fetcher_wrapper.h"
+
+#import "base/mac/bind_objc_block.h"
+#import "base/mac/scoped_nsobject.h"
+#include "base/memory/ptr_util.h"
+#include "base/task_runner.h"
+#include "base/task_runner_util.h"
+#import "ios/web/public/image_fetcher/webp_decoder.h"
+#include "net/http/http_response_headers.h"
+#include "net/http/http_status_code.h"
+#include "net/url_request/url_fetcher.h"
+#include "url/url_constants.h"
+
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
+#pragma mark - WebpDecoderDelegate
+
+namespace {
+
+class WebpDecoderDelegate : public webp_transcode::WebpDecoder::Delegate {
+ public:
+  NSData* data() const { return decoded_image_; }
+
+  // WebpDecoder::Delegate methods
+  void OnFinishedDecoding(bool success) override {
+    if (!success)
+      decoded_image_.reset();
+  }
+  void SetImageFeatures(
+      size_t total_size,
+      webp_transcode::WebpDecoder::DecodedImageFormat format) override {
+    decoded_image_.reset([[NSMutableData alloc] initWithCapacity:total_size]);
+  }
+  void OnDataDecoded(NSData* data) override {
+    DCHECK(decoded_image_);
+    [decoded_image_ appendData:data];
+  }
+
+ private:
+  ~WebpDecoderDelegate() override {}
+  base::scoped_nsobject<NSMutableData> decoded_image_;

[sdefresne, 2017/02/01 09:43:44]

Just use a raw Objective-C pointer here, ARC takes care of the reference for
you.

  NSMutableData* decoded_image_;

[gambard, 2017/02/02 10:03:46]

Done.

+};

[sdefresne, 2017/02/01 09:43:44]

DISALLOW_COPY_AND_ASSIGN(WebpDecoderDelegate)

[gambard, 2017/02/02 10:03:46]

Done.

+
+// Content-type header for WebP images.
+static const char kWEBPFirstByte[] = "RIFF";

[sdefresne, 2017/02/01 09:43:44]

nit: I do not think those are bytes (i.e. one char) but instead words (i.e. four
chars), so maybe rename them too the following

const char kWEBPFirstMagicWord[] = "RIFF";
const char kWEBPSecondMagicWord[] = "WEBP";

or maybe even

const char kWEBPFirstMagicPattern[] = "RIFF";
const char kWEBPSecondMagicPattern[] = "WEBP";

[gambard, 2017/02/02 10:03:46]

Done.

+static const char kWEBPSecondByte[] = "WEBP";

[Marc Treib, 2017/01/31 17:25:24]

nit: "static" isn't required, since this is inside an anonymous namespace
(unless there's some difference between C++ and ObjC that I'm not aware of?)

[sdefresne, 2017/02/01 09:43:44]

+1, "static" is not required here.

[gambard, 2017/02/02 10:03:46]

Done.

+
+// Returns a NSData object containing the decoded image.
+// Returns nil in case of failure.
+NSData* DecodeWebpImage(NSData* webp_image) {
+  scoped_refptr<WebpDecoderDelegate> delegate(new WebpDecoderDelegate);
+  scoped_refptr<webp_transcode::WebpDecoder> decoder(
+      new webp_transcode::WebpDecoder(delegate.get()));
+  decoder->OnDataReceived(webp_image);
+  DLOG_IF(ERROR, !delegate->data()) << "WebP image decoding failed.";
+  return base::scoped_nsobject<NSData>(delegate->data());

[sdefresne, 2017/02/01 09:43:44]

If this code were to be build without ARC, then this line would lead to
overreleasing the NSData* because base::scoped_nsobject<> steal the reference
that it is passed, and WebpDecoderDelegate::data() does not increase the
reference of the object before returning it. This would lead to two different
base::scoped_nsobject<> calling -release on the NSData* but with only one
corresponding -retain (the one implicit in the -alloc -init dance). Moreover,
since WebpDecoderDelegate::data() returns a NSData* and this method returns a
NSData* too, the roundtrip to a base::scoped_nsobject<> is useless (in addition
of being harmful) whether you build with or without ARC.

TL;DR: remove this base::scoped_nsobject<> here.

[gambard, 2017/02/02 10:03:46]

Done.
Thanks for the explanation!

+}
+
+}  // namespace
+
+#pragma mark - IOSImageDataFetcherWrapper
+
+namespace image_fetcher {
+
+IOSImageDataFetcherWrapper::IOSImageDataFetcherWrapper(
+    net::URLRequestContextGetter* url_request_context_getter,
+    const scoped_refptr<base::TaskRunner>& task_runner)
+    : task_runner_(task_runner),
+      image_data_fetcher_(url_request_context_getter) {
+  DCHECK(task_runner_.get());
+}
+
+IOSImageDataFetcherWrapper::~IOSImageDataFetcherWrapper() {}
+
+void IOSImageDataFetcherWrapper::FetchImageDataWebpDecoded(
+    const GURL& image_url,
+    IOSImageDataFetcherCallback callback) {
+  DCHECK(callback);
+
+  scoped_refptr<base::TaskRunner> task_runner = task_runner_;
+  ImageDataFetcher::ImageDataFetcherCallback local_callback =
+      base::BindBlockArc(^(const std::string& image_data) {
+        // Create a NSData from the returned data and notify the callback.
+        NSData* data =
+            [NSData dataWithBytes:image_data.data() length:image_data.size()];
+
+        if (data.length < 12) {
+          callback(data);
+          return;
+        }
+
+        if (image_data.compare(0, 4, kWEBPFirstByte) == 0 &&

[sdefresne, 2017/02/01 09:43:44]

Can you change this test in early return mode too?

  if (image_data.size() < 12 ||
      image_data.compare(0, 4, kWEBPFirstByte) != 0 ||
      image_data.compare(8, 4, kWEBPSecondByte) != 0) {
    callback(data);
    return;
  }

  base::PostTaskAndReplyWithResult(
    task_runner.get(), FROM_HERE,
    base::Bind(&DecodeWebpImage, data),
    base::BindBlockArc(callback));

[gambard, 2017/02/02 10:03:46]

Done.

+            image_data.compare(8, 4, kWEBPSecondByte) == 0) {
+          // The image is a webp image.
+          base::PostTaskAndReplyWithResult(task_runner.get(), FROM_HERE,
+                                           base::Bind(&DecodeWebpImage, data),
+                                           base::BindBlockArc(callback));
+          return;
+        }
+        callback(data);
+      });
+  image_data_fetcher_.FetchImageData(image_url, local_callback);
+}
+
+void IOSImageDataFetcherWrapper::SetDataUseServiceName(
+    DataUseServiceName data_use_service_name) {
+  image_data_fetcher_.SetDataUseServiceName(data_use_service_name);
+}
+
+}  // namespace image_fetcher