Move views vector icons from source_set to part of views target.

ui/views/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/features.gni")
 import("//build/config/ui.gni")
 import("//testing/test.gni")
 import("//ui/base/ui_features.gni")
 import("//ui/ozone/ozone.gni")
 
 config("flags") {
   defines = [ "TOOLKIT_VIEWS=1" ]
 }
 
+action("aggregate_vector_icons") {
+  visibility = [ ":*" ]
+
+  script = "//ui/gfx/vector_icons/aggregate_vector_icons.py"
+
+  icons = [
+    "vector_icons/checkbox_active.icon",
+    "vector_icons/checkbox_normal.icon",
+    "vector_icons/menu_check.1x.icon",
+    "vector_icons/menu_check.icon",
+    "vector_icons/menu_radio_empty.icon",
+    "vector_icons/menu_radio_selected.icon",
+    "vector_icons/radio_button_active.icon",
+    "vector_icons/radio_button_normal.icon",
+    "vector_icons/submenu_arrow.1x.icon",
+    "vector_icons/submenu_arrow.icon",
+  ]
+
+  if (is_mac) {
+    icons += [
+      "vector_icons/combobox_arrow_mac_enabled.icon",
+      "vector_icons/combobox_arrow_mac_disabled.icon",
+    ]
+  }
+
+  output_cc = "$target_gen_dir/vector_icons.cc"
+  output_h = "$target_gen_dir/vector_icons.h"
+
+  inputs = icons
+  inputs += [
+    "vector_icons/vector_icons.cc.template",
+    "vector_icons/vector_icons.h.template",
+  ]
+  outputs = [
+    output_cc,
+    output_h,
+  ]
+
+  response_file_contents = rebase_path(icons, root_build_dir)
+
+  args = [
+    "--working_directory=" + rebase_path("./vector_icons"),
+    "--file_list={{response_file_name}}",
+    "--output_cc=" + rebase_path(output_cc, root_build_dir),
+    "--output_h=" + rebase_path(output_h, root_build_dir),
+  ]
+}
+
 component("views") {
   all_dependent_configs = [ ":flags" ]
   sources = [
     "accessibility/native_view_accessibility.cc",
     "accessibility/native_view_accessibility.h",
     "accessibility/native_view_accessibility_win.cc",
     "accessibility/native_view_accessibility_win.h",
     "accessible_pane_view.cc",
     "accessible_pane_view.h",
     "animation/bounds_animator.cc",
@@ skipping 354 matching lines @@
     "window/non_client_view.cc",
     "window/non_client_view.h",
     "window/window_button_order_provider.cc",
     "window/window_button_order_provider.h",
     "window/window_resources.h",
     "window/window_shape.cc",
     "window/window_shape.h",
     "word_lookup_client.h",
   ]
 
+  sources += get_target_outputs(":aggregate_vector_icons")
+
   configs += [
     "//build/config:precompiled_headers",
 
     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
     "//build/config/compiler:no_size_t_to_int_warning",
   ]
 
   defines = [ "VIEWS_IMPLEMENTATION" ]
 
   deps = [
+    ":aggregate_vector_icons",
     "//base:i18n",
     "//base/third_party/dynamic_annotations",
     "//services/ui/public/interfaces",
     "//skia",
     "//third_party/icu",
     "//ui/accessibility",
     "//ui/display",
     "//ui/native_theme",
     "//ui/native_theme:native_theme_browser",
     "//ui/resources",
     "//ui/strings",
     "//ui/views/resources",
-    "//ui/views/resources/vector_icons",
     "//url",
   ]
 
   public_deps = [
     "//base",
     "//ui/accessibility:ax_gen",
     "//ui/base",
     "//ui/base/ime",
     "//ui/compositor",
     "//ui/display",
@@ skipping 601 matching lines @@
       "//ui/base:test_support",
       "//ui/compositor",
       "//ui/events:test_support",
       "//ui/gl:test_support",
       "//ui/resources",
       "//ui/resources:ui_test_pak",
       "//ui/strings",
     ]
   }
 }