[Mac] Sinkhole __NSFireDelayedPerform and _CFXNotificationPost in the exception preprocessor.

chrome/browser/mac/exception_processor_unittest.mm

 // Copyright 2016 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/mac/exception_processor.h"
 
 #import <Cocoa/Cocoa.h>
 #include <stddef.h>
 #include <sys/wait.h>
 
@@ skipping 136 matching lines @@
 // Tests that exceptions can still be caught when the preprocessor is enabled.
 TEST(ExceptionProcessorTest, ThrowAndCatchExceptionInRunLoop) {
   ::testing::FLAGS_gtest_death_test_style = "threadsafe";
   EXPECT_EXIT(ThrowAndCatchExceptionInRunLoop(),
               [](int exit_code) -> bool {
                 return WEXITSTATUS(exit_code) == 0;
               },
               ".*TEST PASS.*");
 }
 
+void ThrowExceptionFromSelector() {
+  base::mac::DisableOSCrashDumps();
+  chrome::InstallObjcExceptionPreprocessor();
+
+  NSException* exception = [NSException exceptionWithName:@"ThrowFromSelector"
+                                                   reason:@""
+                                                 userInfo:nil];
+
+  [exception performSelector:@selector(raise) withObject:nil afterDelay:0.1];
+
+  [[NSRunLoop currentRunLoop] runUntilDate:
+      [NSDate dateWithTimeIntervalSinceNow:10]];
+
+  fprintf(stderr, "TEST FAILED\n");
+  exit(1);
+}
+
+TEST(ExceptionProcessorTest, ThrowExceptionFromSelector) {
+  ::testing::FLAGS_gtest_death_test_style = "threadsafe";
+  EXPECT_DEATH(ThrowExceptionFromSelector(),
+               ".*FATAL:exception_processor\\.mm.*"
+               "Terminating from Objective-C exception:.*");
+}
+
+void ThrowInNotificationObserver() {
+  base::mac::DisableOSCrashDumps();
+  chrome::InstallObjcExceptionPreprocessor();
+
+  NSNotification* notification =
+      [NSNotification notificationWithName:@"TestExceptionInObserver"
+                                    object:nil];
+
+  NSNotificationCenter* center = [NSNotificationCenter defaultCenter];
+  [center addObserverForName:[notification name]
+                      object:nil
+                       queue:nil
+                  usingBlock:^(NSNotification*) {
+                    [NSException raise:@"ThrowInNotificationObserver"
+                                format:@""];
+                  }];
+
+  [center performSelector:@selector(postNotification:)
+               withObject:notification
+               afterDelay:0];
+
+  [[NSRunLoop currentRunLoop] runUntilDate:
+      [NSDate dateWithTimeIntervalSinceNow:10]];
+
+  fprintf(stderr, "TEST FAILED\n");
+  exit(1);
+}
+
+TEST(ExceptionProcessorTest, ThrowInNotificationObserver) {
+  ::testing::FLAGS_gtest_death_test_style = "threadsafe";
+  EXPECT_DEATH(ThrowInNotificationObserver(),
+               ".*FATAL:exception_processor\\.mm.*"
+               "Terminating from Objective-C exception:.*");
+}
+
 void ThrowExceptionInRunLoopWithoutProcessor() {
   base::mac::DisableOSCrashDumps();
   chrome::UninstallObjcExceptionPreprocessor();
 
   @try {
     RaiseExceptionInRunLoop();
   } @catch (id exception) {
     fprintf(stderr, "TEST PASS\n");
     exit(0);
   }
 
   fprintf(stderr, "TEST FAILED\n");
   exit(1);
 }
 
 // Tests basic exception handling when the preprocessor is disabled.
 TEST(ExceptionProcessorTest, ThrowExceptionInRunLoopWithoutProcessor) {
   ::testing::FLAGS_gtest_death_test_style = "threadsafe";
   EXPECT_EXIT(ThrowExceptionInRunLoopWithoutProcessor(),
               [](int exit_code) -> bool {
                 return WEXITSTATUS(exit_code) == 0;
               },
               ".*TEST PASS.*");
 }
 
 }  // namespace chrome