Add Widevine signature files into Mac build

chrome/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/buildflag_header.gni")
 import("//build/config/chrome_build.gni")
 import("//build/config/compiler/compiler.gni")
 import("//build/config/compiler/pgo/pgo.gni")
 import("//build/config/features.gni")
 import("//build/config/locales.gni")
@@ skipping 631 matching lines @@
 
       # keystone_registration_framework copies the framework into the framework
       # bundle via a script that performs additional actions, rather than
       # relying on a bundle_data to copy it.
       ":keystone_registration_framework",
 
       # verify_chrome_framework_order depends on :chrome_framework and, for
       # non-component builds, will ensure the export symbol table is correct.
       ":verify_chrome_framework_order",
     ]
+
+    # Only official builds that include Widevine need the widevine
+    # signature file.
+    if (is_chrome_branded && enable_pepper_cdms) {
+      sources += [ "$root_out_dir/$chrome_framework_name.sig" ]
+      public_deps += [ ":sign_chrome_framework_for_widevine" ]
+    }
   }
 
   action("clean_up_old_versions") {
     script = "//chrome/tools/build/mac/clean_up_old_versions.py"
     outputs = [
       "$root_gen_dir/run_$target_name.stamp",
     ]
     args = [
              rebase_path("$root_out_dir/$chrome_product_full_name.app",
                          root_build_dir),
@@ skipping 193 matching lines @@
         "{{bundle_root_dir}}/Libraries/$widevine_cdm_path/{{source_file_part}}",
       ]
       public_deps = [
         # Need this intermediate dependency because "widevinecdm" is a
         # shared_library if !is_chrome_branded, and then depending on
         # "widevinecdm" directly would cause it to be linked into the Chromium
         # Framework, which we don't want.
         ":widevine_cdm_library_copy",
         "//third_party/widevine/cdm:widevinecdmadapter",
       ]
+
+      # Signatures are only generated for official chrome.
+      if (is_chrome_branded) {
+        sources += [
+          "$root_out_dir/$widevine_cdm_path/widevinecdmadapter.plugin.sig",
+          "$root_out_dir/libwidevinecdm.dylib.sig",
+        ]
+        public_deps += [ ":sign_cdm_adapter_for_widevine" ]
+      }
     }
 
     copy("widevine_cdm_library_copy") {
       sources = [
         "$root_out_dir/$widevine_cdm_path/libwidevinecdm.dylib",
       ]
+      if (is_chrome_branded) {
+        sources +=
+            [ "$root_out_dir/$widevine_cdm_path/libwidevinecdm.dylib.sig" ]
+      }
       outputs = [
         "$root_out_dir/{{source_file_part}}",
       ]
       deps = [
         "//third_party/widevine/cdm:widevinecdm",
       ]
     }
 
     bundle_data("widevine_cdm_library_manifest") {
       sources = [
         "$root_out_dir/WidevineCdm/manifest.json",
       ]
       outputs = [
         "{{bundle_root_dir}}/Libraries/WidevineCdm/{{source_file_part}}",
       ]
       public_deps = [
         "//third_party/widevine/cdm:widevine_cdm_manifest",
       ]
     }
+
+    widevine_sign_file("sign_cdm_adapter_for_widevine") {
+      file = "$root_out_dir/$widevine_cdm_path/widevinecdmadapter.plugin"
+      deps = [
+        "//third_party/widevine/cdm:widevinecdmadapter",
+      ]
+    }
+
+    widevine_sign_file("sign_chrome_framework_for_widevine") {
+      file = "$root_out_dir/$chrome_framework_name.framework/"
+      if (defined(chrome_framework_version)) {

[Robert Sesek, 2017/02/23 18:09:32]

Can the script that produces the signature file go through symlink at
"$root_out_dir/$chrome_framework_name.framework/$chrome_framework_name" ? 

[jrummell, 2017/02/23 18:39:03]

I tried it, and get the error:
ERROR Input to target not generated by a dependency.
The file:
  //out/Release/Google Chrome Framework.framework/Google Chrome Framework
is listed as an input or source for the target:
  //chrome:sign_chrome_framework_for_widevine
but no targets in the build generate that file.

The outputs for ":chrome_framework" include:
//out/Release/Google Chrome Framework.framework/Versions/A/Google Chrome
Framework

I don't see anything in this file that creates the symlink. Where is that done?

[Robert Sesek, 2017/02/23 18:54:49]

Ah, that makes sense. There's an issue with ninja where it does not properly
stat links (it uses stat instead of lstat), so you cannot actually have a build
edge be a symbolic link. To get around that, those symlinks are actually
generated at gn gen time, since that's the only reliable way to do it.

+        file += "Versions/$chrome_framework_version/"
+      }
+      file += "$chrome_framework_name"
+      signature_file = "$root_out_dir/$chrome_framework_name.sig"
+      deps = [
+        ":chrome_framework",
+      ]
+    }
   }
 
   group("widevine_cdm_library") {
     if (_should_bundle_widevine) {
       deps = [
         ":widevine_cdm_library_binaries",
         ":widevine_cdm_library_manifest",
       ]
     }
   }
@@ skipping 716 matching lines @@
       "//chrome/app/theme/$branding_path_component/product_logo_48.png",
       "//chrome/tools/build/linux/chrome-wrapper",
       "//third_party/xdg-utils/scripts/xdg-mime",
       "//third_party/xdg-utils/scripts/xdg-settings",
     ]
     outputs = [
       "$root_out_dir/{{source_file_part}}",
     ]
   }
 }