Expose thumbnails of pages to iOS share extensions.

ui/base/test/ios/ui_image_test_utils.mm

+// Copyright 2017 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#include "ui/base/test/ios/ui_image_test_utils.h"
+
+#include "base/logging.h"
+
+namespace ui {
+namespace test {
+namespace uiimage_utils {
+
+UIImage* UIImageWithSizeAndSolidColor(CGSize const& size, UIColor* color) {
+  UIGraphicsBeginImageContext(size);
+  CGContextRef context = UIGraphicsGetCurrentContext();
+  CGContextSetFillColorWithColor(context, [color CGColor]);
+  CGContextFillRect(context, CGRectMake(0, 0, size.width, size.height));
+  UIImage* imageWithSolidColor = UIGraphicsGetImageFromCurrentImageContext();

[Olivier, 2017/01/25 17:26:00]

I think you should use _ case in this file.

[jif, 2017/01/27 11:56:12]

Done.

+  UIGraphicsEndImageContext();
+  return imageWithSolidColor;
+}
+
+bool UIImagesAreEqual(UIImage* image1, UIImage* image2) {
+  if (image1 == image2)
+    return true;
+  DCHECK(image1.CGImage);

[sdefresne, 2017/01/26 14:50:40]

Should you check the images dimension? Looks like you only look at the image
data and length, but if you have a MxN and a NxM image with a solid color, your
function returns true when I would expect it to return false.

[jif, 2017/01/27 11:56:12]

Haha, nice catch!
Done.

+  DCHECK(image2.CGImage);
+
+  bool imagesAreEqual = false;
+
+  CFDataRef dataRef1 =

[sdefresne, 2017/01/26 14:50:40]

I think you should use ScopedCFTypeRef to avoid forgetting the CFRelease.

  base::ScopedCFTypeRef<CFDataRef> dataRef1(
      CGDataProviderCopyData(CGImageGetDataProvider(image1.CGImage));
  ...

[jif, 2017/01/27 11:56:12]

Thank you!

+      CGDataProviderCopyData(CGImageGetDataProvider(image1.CGImage));
+  CFDataRef dataRef2 =
+      CGDataProviderCopyData(CGImageGetDataProvider(image2.CGImage));
+  CFIndex length1 = CFDataGetLength(dataRef1);
+  CFIndex length2 = CFDataGetLength(dataRef2);
+  if (length1 == length2) {
+    const UInt8* ptr1 = CFDataGetBytePtr(dataRef1);
+    const UInt8* ptr2 = CFDataGetBytePtr(dataRef2);
+    // memcmp returns 0 if length is 0.
+    if (memcmp(ptr1, ptr2, length1) == 0)
+      imagesAreEqual = true;
+  }
+  CFRelease(dataRef1);
+  CFRelease(dataRef2);
+
+  return imagesAreEqual;
+}
+
+}  // namespace uiimage_utils
+}  // namespace test
+}  // namespace ui