Port BatteryMonitor into Device Service

services/device/BUILD.gn

 # Copyright 2016 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
+import("//build/config/features.gni")
 import("//services/service_manager/public/cpp/service.gni")
 import("//services/service_manager/public/service_manifest.gni")
 
+if (is_android) {
+  import("//build/config/android/rules.gni")  # For generate_jni().
+}
+
 source_set("lib") {
   sources = [
     "device_service.cc",
     "device_service.h",
   ]
 
   deps = [
     "//base",
+    "//device/battery:mojo_bindings",
     "//device/power_monitor",
     "//device/time_zone_monitor",
     "//services/service_manager/public/cpp",
   ]
 
   public_deps = [
     # TODO(blundell): This dep shouldn't be necessary at all,
     # but content_shell fails to link in the component build if
     # this isn't here as a public_dep.
     "//device/time_zone_monitor/public/interfaces",
   ]
+
+  if (is_android) {
+    deps += [ ":device_service_jni_headers" ]
+  } else {
+    deps += [ "//device/battery" ]
+  }
 }
 
 service_manifest("manifest") {
   name = "device"
   source = "manifest.json"
 }
+
+if (is_android) {
+  generate_jni("device_service_jni_headers") {
+    sources = [
+      "android/java/src/org/chromium/services/device/InterfaceRegistrar.java",
+    ]
+    jni_package = "device_service"
+  }
+
+  android_library("java") {
+    java_files = [ "android/java/src/org/chromium/services/device/InterfaceRegistrar.java" ]
+    deps = [
+      "//base:base_java",
+      "//device/battery:mojo_bindings_java",
+      "//device/battery/android:battery_monitor_java",
+      "//mojo/android:system_java",
+      "//mojo/public/java:bindings_java",
+      "//mojo/public/java:system_java",
+      "//services/service_manager/public/interfaces:interfaces_java",
+      "//services/service_manager/public/java:service_manager_java",
+    ]
+  }
+}