[ObjC ARC] Converts ios/chrome/browser/ui/history:history to ARC.

ios/chrome/browser/ui/history/history_collection_view_controller.mm

 // Copyright 2016 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "ios/chrome/browser/ui/history/history_collection_view_controller.h"
 
 #import <MobileCoreServices/MobileCoreServices.h>
 
 #include <memory>
 
-#import "base/ios/weak_nsobject.h"
 #include "base/mac/foundation_util.h"
-#import "base/mac/objc_property_releaser.h"
-#include "base/mac/scoped_nsobject.h"
 #include "base/metrics/user_metrics.h"
 #include "base/metrics/user_metrics_action.h"
 #include "base/strings/sys_string_conversions.h"
 #include "base/strings/utf_string_conversions.h"
 #include "components/browsing_data/core/history_notice_utils.h"
 #include "components/strings/grit/components_strings.h"
 #include "components/url_formatter/url_formatter.h"
 #include "ios/chrome/browser/browser_state/chrome_browser_state.h"
 #include "ios/chrome/browser/chrome_url_constants.h"
 #import "ios/chrome/browser/signin/authentication_service.h"
@@ skipping 10 matching lines @@
 #include "ios/chrome/browser/ui/history/history_entry.h"
 #include "ios/chrome/browser/ui/history/history_entry_inserter.h"
 #import "ios/chrome/browser/ui/history/history_entry_item.h"
 #include "ios/chrome/browser/ui/history/history_service_facade.h"
 #include "ios/chrome/browser/ui/history/history_service_facade_delegate.h"
 #include "ios/chrome/browser/ui/history/history_util.h"
 #import "ios/chrome/browser/ui/url_loader.h"
 #include "ios/chrome/grit/ios_strings.h"
 #import "ios/third_party/material_components_ios/src/components/Collections/src/MaterialCollections.h"
 #import "ios/third_party/material_components_ios/src/components/Palettes/src/MaterialPalettes.h"
+#import "ios/third_party/material_components_ios/src/components/ActivityIndicator/src/MDCActivityIndicator.h"

[lpromero, 2017/01/11 18:03:51]

Sort

[stkhapugin, 2017/01/12 14:15:43]

Done.

 #import "ios/web/public/referrer.h"
 #import "ios/web/public/web_state/context_menu_params.h"
 #import "net/base/mac/url_conversions.h"
 #include "ui/base/l10n/l10n_util.h"
 #include "ui/base/l10n/l10n_util_mac.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 namespace {
 typedef NS_ENUM(NSInteger, ItemType) {
   ItemTypeHistoryEntry = kItemTypeEnumZero,
   ItemTypeEntriesStatus,
   ItemTypeActivityIndicator,
 };
 // Section identifier for the header (sync information) section.
 const NSInteger kEntriesStatusSectionIdentifier = kSectionIdentifierEnumZero;
 // Maximum number of entries to retrieve in a single query to history service.
 const int kMaxFetchCount = 100;
 // Horizontal inset for item separators.
 const CGFloat kSeparatorInset = 10;
 }
 
 @interface HistoryCollectionViewController ()<HistoryEntriesStatusItemDelegate,
                                               HistoryEntryInserterDelegate,
                                               HistoryEntryItemDelegate,
                                               HistoryServiceFacadeDelegate> {
-  base::mac::ObjCPropertyReleaser
-      _propertyReleaser_HistoryCollectionViewController;
   // Facade for communicating with HistoryService and WebHistoryService.
   std::unique_ptr<HistoryServiceFacade> _historyServiceFacade;
   // The main browser state. Not owned by HistoryCollectionViewController.
   ios::ChromeBrowserState* _browserState;
   // Backing ivar for delegate property.
-  base::WeakNSProtocol<id<HistoryCollectionViewControllerDelegate>> _delegate;
+  __weak id<HistoryCollectionViewControllerDelegate> _delegate;
   // Backing ivar for URLLoader property.
-  base::WeakNSProtocol<id<UrlLoader>> _URLLoader;
+  __weak id<UrlLoader> _URLLoader;
 }
 
 // Object to manage insertion of history entries into the collection view model.
-@property(nonatomic, retain) HistoryEntryInserter* entryInserter;
+@property(nonatomic, strong) HistoryEntryInserter* entryInserter;
 // Delegate for the history collection view.
-@property(nonatomic, assign, readonly)
-    id<HistoryCollectionViewControllerDelegate>
-        delegate;
+@property(nonatomic, weak, readonly) id<HistoryCollectionViewControllerDelegate>
+    delegate;
 // UrlLoader for navigating to history entries.
-@property(nonatomic, assign, readonly) id<UrlLoader> URLLoader;
+@property(nonatomic, weak, readonly) id<UrlLoader> URLLoader;
 // The current query for visible history entries.
 @property(nonatomic, copy) NSString* currentQuery;
 // Coordinator for displaying context menus for history entries.
-@property(nonatomic, assign) ContextMenuCoordinator* contextMenuCoordinator;
+@property(nonatomic, strong) ContextMenuCoordinator* contextMenuCoordinator;

[lpromero, 2017/01/11 18:03:51]

assign to strong?

[stkhapugin, 2017/01/12 14:15:44]

Seems to be the intended use. Nothing retains contextMenuCoordinator with ARC.
Before it was assigned to an assign property with a retain count of +1 (see line
740) and never released. 

 // Type of displayed history entries. Entries can be synced or local, or there
 // may be no history entries.
 @property(nonatomic, assign) HistoryEntriesStatus entriesType;
 // YES if the history panel should show a notice about additional forms of
 // browsing history.
 @property(nonatomic, assign)
     BOOL shouldShowNoticeAboutOtherFormsOfBrowsingHistory;
 // YES if there is an outstanding history query.
 @property(nonatomic, assign, getter=isLoading) BOOL loading;
 // YES if there are no more history entries to load.
@@ skipping 41 matching lines @@
 @synthesize loading = _loading;
 @synthesize finishedLoading = _finishedLoading;
 @synthesize filterQueryResult = _filterQueryResult;
 
 - (instancetype)initWithLoader:(id<UrlLoader>)loader
                   browserState:(ios::ChromeBrowserState*)browserState
                       delegate:(id<HistoryCollectionViewControllerDelegate>)
                                    delegate {
   self = [super initWithStyle:CollectionViewControllerStyleDefault];
   if (self) {
-    _propertyReleaser_HistoryCollectionViewController.Init(
-        self, [HistoryCollectionViewController class]);
     _historyServiceFacade.reset(new HistoryServiceFacade(browserState, self));
     _browserState = browserState;
-    _delegate.reset(delegate);
-    _URLLoader.reset(loader);
+    _delegate = delegate;
+    _URLLoader = loader;
     [self loadModel];
     // Add initial info section as header.
     [self.collectionViewModel
         addSectionWithIdentifier:kEntriesStatusSectionIdentifier];
     _entryInserter =
         [[HistoryEntryInserter alloc] initWithModel:self.collectionViewModel];
     _entryInserter.delegate = self;
     _entriesType = NO_ENTRIES;
     [self showHistoryMatchingQuery:nil];
   }
   return self;
 }
 
 - (void)viewDidLoad {
   [super viewDidLoad];
   self.styler.cellLayoutType = MDCCollectionViewCellLayoutTypeList;
   self.styler.separatorInset =
       UIEdgeInsetsMake(0, kSeparatorInset, 0, kSeparatorInset);
   self.styler.allowsItemInlay = NO;
 
   self.clearsSelectionOnViewWillAppear = NO;
   self.collectionView.keyboardDismissMode =
       UIScrollViewKeyboardDismissModeOnDrag;
 
-  base::scoped_nsobject<UILongPressGestureRecognizer> longPressRecognizer([
+  UILongPressGestureRecognizer* longPressRecognizer = [

[lpromero, 2017/01/11 18:03:51]

Are there other usage of scoped_nsobject in this file? If not, consider removing
the import.

[stkhapugin, 2017/01/12 14:15:43]

The import is already removed. 

       [UILongPressGestureRecognizer alloc]
       initWithTarget:self
-              action:@selector(displayContextMenuInvokedByGestureRecognizer:)]);
+              action:@selector(displayContextMenuInvokedByGestureRecognizer:)];
   [self.collectionView addGestureRecognizer:longPressRecognizer];
 }
 
 - (BOOL)isEditing {
   return self.editor.isEditing;
 }
 
 - (void)setEditing:(BOOL)editing {
   [self.editor setEditing:editing animated:YES];
 }
@@ skipping 152 matching lines @@
   self.finishedLoading = result.has_synced_results
                              ? result.finished && result.sync_finished
                              : result.finished;
   self.entriesType = result.has_synced_results ? SYNCED_ENTRIES : LOCAL_ENTRIES;
   std::vector<history::HistoryEntry> entries = result.entries;
 
   // Header section should be updated outside of batch updates, otherwise
   // loading indicator removal will not be observed.
   [self updateEntriesStatusMessage];
 
-  __block base::scoped_nsobject<NSMutableArray> filterResults(
-      [[NSMutableArray array] retain]);
-  __block base::scoped_nsobject<NSString> searchQuery(
-      [base::SysUTF16ToNSString(result.query) copy]);
+  __block NSMutableArray* filterResults = [NSMutableArray array];
+  __block NSString* searchQuery = [base::SysUTF16ToNSString(result.query) copy];
   [self.collectionView performBatchUpdates:^{
     // There should always be at least a header section present.
     DCHECK([[self collectionViewModel] numberOfSections]);
     for (const history::HistoryEntry& entry : entries) {
       HistoryEntryItem* item =
-          [[[HistoryEntryItem alloc] initWithType:ItemTypeHistoryEntry
-                                     historyEntry:entry
-                                     browserState:_browserState
-                                         delegate:self] autorelease];
+          [[HistoryEntryItem alloc] initWithType:ItemTypeHistoryEntry
+                                    historyEntry:entry
+                                    browserState:_browserState
+                                        delegate:self];
       [self.entryInserter insertHistoryEntryItem:item];
       if ([self isSearching] || self.filterQueryResult) {
         [filterResults addObject:item];
       }
     }
     [self.delegate historyCollectionViewControllerDidChangeEntries:self];
   }
       completion:^(BOOL) {
         if (([self isSearching] && [searchQuery length] > 0 &&
              [self.currentQuery isEqualToString:searchQuery]) ||
@@ skipping 183 matching lines @@
       query_parser::MatchingAlgorithm::ALWAYS_PREFIX_SEARCH;
   _historyServiceFacade->QueryHistory(queryString, options);
   // Also determine whether notice regarding other forms of browsing history
   // should be shown.
   _historyServiceFacade->QueryOtherFormsOfBrowsingHistory();
 }
 
 - (void)updateEntriesStatusMessage {
   CollectionViewItem* entriesStatusItem = nil;
   if (!self.hasHistoryEntries) {
-    CollectionViewTextItem* noResultsItem = [[[CollectionViewTextItem alloc]
-        initWithType:ItemTypeEntriesStatus] autorelease];
+    CollectionViewTextItem* noResultsItem =
+        [[CollectionViewTextItem alloc] initWithType:ItemTypeEntriesStatus];
     noResultsItem.text =
         self.isSearching ? l10n_util::GetNSString(IDS_HISTORY_NO_SEARCH_RESULTS)
                          : l10n_util::GetNSString(IDS_HISTORY_NO_RESULTS);
     entriesStatusItem = noResultsItem;
   } else {
     HistoryEntriesStatusItem* historyEntriesStatusItem =
-        [[[HistoryEntriesStatusItem alloc] initWithType:ItemTypeEntriesStatus]
-            autorelease];
+        [[HistoryEntriesStatusItem alloc] initWithType:ItemTypeEntriesStatus];
     historyEntriesStatusItem.delegate = self;
     AuthenticationService* authService =
         AuthenticationServiceFactory::GetForBrowserState(_browserState);
     BOOL signedIn = authService->IsAuthenticated();
 
     historyEntriesStatusItem.hidden =
         self.isSearching || (!signedIn && self.hasHistoryEntries);
     historyEntriesStatusItem.entriesStatus = self.entriesType;
     historyEntriesStatusItem.showsOtherBrowsingDataNotice =
         _shouldShowNoticeAboutOtherFormsOfBrowsingHistory;
@@ skipping 88 matching lines @@
   }
 
   [self.collectionView performBatchUpdates:^{
     if ([self.collectionViewModel hasItemAtIndexPath:indexPath]) {
       [self.collectionViewModel
                  removeItemWithType:[self.collectionViewModel
                                         itemTypeForIndexPath:indexPath]
           fromSectionWithIdentifier:kSectionIdentifierEnumZero];
       [self.collectionView deleteItemsAtIndexPaths:@[ indexPath ]];
     }
-    CollectionViewItem* loadingIndicatorItem = [[[CollectionViewItem alloc]
-        initWithType:ItemTypeActivityIndicator] autorelease];
+    CollectionViewItem* loadingIndicatorItem =
+        [[CollectionViewItem alloc] initWithType:ItemTypeActivityIndicator];
     loadingIndicatorItem.cellClass = [ActivityIndicatorCell class];
     [self.collectionViewModel addItem:loadingIndicatorItem
               toSectionWithIdentifier:kEntriesStatusSectionIdentifier];
     [self.collectionView insertItemsAtIndexPaths:@[ indexPath ]];
   }
                                 completion:nil];
 }
 
 #pragma mark Context Menu
 
@@ skipping 11 matching lines @@
   // If there's no index path, or the index path is for the header item, do not
   // display a contextual menu.
   if (!touchedItemIndexPath ||
       [touchedItemIndexPath
           isEqual:[NSIndexPath indexPathForItem:0 inSection:0]])
     return;
 
   HistoryEntryItem* entry = base::mac::ObjCCastStrict<HistoryEntryItem>(
       [self.collectionViewModel itemAtIndexPath:touchedItemIndexPath]);
 
-  base::WeakNSObject<HistoryCollectionViewController> weakSelf(self);
+  __weak HistoryCollectionViewController* weakSelf = self;
   web::ContextMenuParams params;
   params.location = touchLocation;
-  params.view.reset([self.collectionView retain]);
+  params.view.reset(self.collectionView);

[lpromero, 2017/01/11 18:03:52]

Is this a scoped_nsobject? ARC will do the right thing here?

[stkhapugin, 2017/01/12 14:15:44]

Yes and yes: 

This will call reset(x) on scoped_nsobject. Since this is called from ARC, it
will call the ARC version of this method (ifdef-ed) which retains the argument.
Just like any method call, the reset() will be called with an autoreleased
parameter. Hence the scoped_nsobject will own 1 refcount, as expected. 

   NSString* menuTitle =
       base::SysUTF16ToNSString(url_formatter::FormatUrl(entry.URL));
   params.menu_title.reset([menuTitle copy]);
 
   // Present sheet/popover using controller that is added to view hierarchy.
   UIViewController* topController = [params.view window].rootViewController;
   while (topController.presentedViewController)
     topController = topController.presentedViewController;
 
   self.contextMenuCoordinator =
@@ skipping 75 matching lines @@
   NSData* plainText = [base::SysUTF8ToNSString(URL.spec())
       dataUsingEncoding:NSUTF8StringEncoding];
   NSDictionary* copiedItem = @{
     (NSString*)kUTTypeURL : net::NSURLWithGURL(URL),
     (NSString*)kUTTypeUTF8PlainText : plainText,
   };
   [[UIPasteboard generalPasteboard] setItems:@[ copiedItem ]];
 }
 
 @end