Add a test for our workaround of an AppKit crash in SFChooseIdentityPanel.

chrome/browser/ui/cocoa/ssl_client_certificate_selector_cocoa_browsertest.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/ssl_client_certificate_selector_cocoa.h"
 
 #import <SecurityInterface/SFChooseIdentityPanel.h>
 
 #include "base/bind.h"
 #import "base/mac/mac_util.h"
 #include "base/macros.h"
 #include "base/memory/ptr_util.h"
 #include "chrome/browser/ssl/ssl_client_certificate_selector.h"
 #include "chrome/browser/ssl/ssl_client_certificate_selector_test.h"
 #include "chrome/browser/ui/browser.h"
 #include "chrome/browser/ui/browser_commands.h"
 #include "chrome/browser/ui/tabs/tab_strip_model.h"
 #include "components/web_modal/web_contents_modal_dialog_manager.h"
 #include "content/public/browser/client_certificate_delegate.h"
 #include "content/public/browser/web_contents.h"
 #include "content/public/test/test_utils.h"
 #import "testing/gtest_mac.h"
 #include "ui/base/cocoa/window_size_constants.h"
 
+#import <objc/runtime.h>
+
 using web_modal::WebContentsModalDialogManager;
 
 namespace {
 
 class TestClientCertificateDelegate
     : public content::ClientCertificateDelegate {
  public:
   // Creates a ClientCertificateDelegate that sets |*destroyed| to true on
   // destruction.
   explicit TestClientCertificateDelegate(bool* destroyed)
@@ skipping 77 matching lines @@
   AddBlankTabAndShow(browser());
   EXPECT_EQ(0.0, [sheetWindow alphaValue]);
   EXPECT_TRUE([[selector overlayWindow] ignoresMouseEvents]);
 
   // Switch back and verify that the sheet is shown. Interaction with the tab
   // underneath should be blocked while the sheet is showing.
   chrome::SelectNumberedTab(browser(), 0);
   EXPECT_EQ(1.0, [sheetWindow alphaValue]);
   EXPECT_FALSE([[selector overlayWindow] ignoresMouseEvents]);
 }
+
+@interface TestDeallocWatcher : NSObject
+@end
+
+@implementation TestDeallocWatcher {
+  BOOL* wasDeallocated_;
+}
+
++ (void)watchTarget:(NSObject*)target andSetFlag:(BOOL*)wasDeallocated {
+  TestDeallocWatcher* watcher = [[TestDeallocWatcher alloc] init];
+  watcher->wasDeallocated_ = wasDeallocated;
+  objc_setAssociatedObject(target, _cmd, watcher,
+                           OBJC_ASSOCIATION_RETAIN_NONATOMIC);
+  [watcher release];
+}
+
+- (void)dealloc {
+  *wasDeallocated_ = true;
+  [super dealloc];
+}
+
+@end
+
+// Test that we can't trigger the crash from https://crbug.com/653093
+IN_PROC_BROWSER_TEST_F(SSLClientCertificateSelectorCocoaTest,
+                       WorkaroundCrashySierra) {
+  BOOL selector_was_deallocated = false;
+
+  @autoreleasepool {
+    content::WebContents* web_contents =
+        browser()->tab_strip_model()->GetActiveWebContents();
+    SSLClientCertificateSelectorCocoa* selector =
+        [[SSLClientCertificateSelectorCocoa alloc]
+            initWithBrowserContext:web_contents->GetBrowserContext()
+                   certRequestInfo:auth_requestor_->cert_request_info_.get()
+                          delegate:nil];
+    [selector displayForWebContents:web_contents];
+    content::RunAllPendingInMessageLoop();
+
+    [TestDeallocWatcher watchTarget:selector
+                         andSetFlag:&selector_was_deallocated];
+
+    [selector.overlayWindow endSheet:selector.overlayWindow.attachedSheet];
+    content::RunAllPendingInMessageLoop();
+  }
+
+  EXPECT_TRUE(selector_was_deallocated);
+
+  // Without the workaround, this will crash on Sierra.

[Robert Sesek, 2017/01/11 22:03:31]

If you back out the fix, does it indeed crash here?

[Sidney San Martín, 2017/01/11 22:15:33]

It does… but not consistently, since the crash happens when AppKit sends a
message to a deallocated object. I can't think of simple, non-flaky test that
isn't brittle (i.e. likely to break when Apple fixes the bug). Thoughts? How do
you feel about this kind of flakiness (false negatives but no false positives)?

[Robert Sesek, 2017/01/11 22:33:56]

As long as it fails sometimes that I think is sufficient (we'd be able to pick
up when it started flaking through buildbot logs if it regressed).

+  [[NSNotificationCenter defaultCenter]
+      postNotificationName:NSPreferredScrollerStyleDidChangeNotification
+                    object:nil
+                  userInfo:@{
+                    @"NSScrollerStyle" : @(NSScrollerStyleLegacy)
+                  }];
+  [[NSNotificationCenter defaultCenter]
+      postNotificationName:NSPreferredScrollerStyleDidChangeNotification
+                    object:nil
+                  userInfo:@{
+                    @"NSScrollerStyle" : @(NSScrollerStyleOverlay)
+                  }];
+}