[ios] Wait for sync query to return before displaying history

ios/chrome/browser/ui/history/history_collection_view_controller.mm

 // Copyright 2016 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "ios/chrome/browser/ui/history/history_collection_view_controller.h"
 
 #import <MobileCoreServices/MobileCoreServices.h>
 
 #include <memory>
 
 #import "base/ios/weak_nsobject.h"
 #include "base/mac/foundation_util.h"
 #import "base/mac/objc_property_releaser.h"
 #include "base/mac/scoped_nsobject.h"
 #include "base/strings/sys_string_conversions.h"
 #include "base/strings/utf_string_conversions.h"
 #include "components/browsing_data/core/history_notice_utils.h"
 #include "components/strings/grit/components_strings.h"
 #include "components/url_formatter/url_formatter.h"
 #include "ios/chrome/browser/browser_state/chrome_browser_state.h"
 #include "ios/chrome/browser/chrome_url_constants.h"
 #import "ios/chrome/browser/signin/authentication_service.h"
 #include "ios/chrome/browser/signin/authentication_service_factory.h"
+#include "ios/chrome/browser/sync/sync_setup_service.h"
+#include "ios/chrome/browser/sync/sync_setup_service_factory.h"
 #import "ios/chrome/browser/ui/collection_view/cells/MDCCollectionViewCell+Chrome.h"
 #import "ios/chrome/browser/ui/collection_view/cells/activity_indicator_cell.h"
 #import "ios/chrome/browser/ui/collection_view/cells/collection_view_item.h"
 #import "ios/chrome/browser/ui/collection_view/cells/collection_view_text_item.h"
 #import "ios/chrome/browser/ui/collection_view/collection_view_model.h"
 #import "ios/chrome/browser/ui/context_menu/context_menu_coordinator.h"
 #include "ios/chrome/browser/ui/history/history_entries_status_item.h"
 #include "ios/chrome/browser/ui/history/history_entry.h"
 #include "ios/chrome/browser/ui/history/history_entry_inserter.h"
 #import "ios/chrome/browser/ui/history/history_entry_item.h"
@@ skipping 66 matching lines @@
 - (void)fetchHistoryForQuery:(NSString*)query
                  priorToTime:(const base::Time&)time;
 // Updates header section to provide relevant information about the currently
 // displayed history entries.
 - (void)updateEntriesStatusMessage;
 // Removes selected items from the visible collection, but does not delete them
 // from browser history.
 - (void)removeSelectedItemsFromCollection;
 // Removes all items in the collection that are not included in entries.
 - (void)filterForHistoryEntries:(NSArray*)entries;
+// Adds loading indicator to the top of the history collection, if one is not
+// already present.
+- (void)addLoadingIndicator;
 // Displays context menu on cell pressed with gestureRecognizer.
 - (void)displayContextMenuInvokedByGestureRecognizer:
     (UILongPressGestureRecognizer*)gestureRecognizer;
 // Opens URL in the current tab and dismisses the history view.
 - (void)openURL:(const GURL&)URL;
 // Opens URL in a new non-incognito tab and dismisses the history view.
 - (void)openURLInNewTab:(const GURL&)URL;
 // Opens URL in a new incognito tab and dismisses the history view.
 - (void)openURLInNewIncognitoTab:(const GURL&)URL;
 // Copies URL to the clipboard.
@@ skipping 188 matching lines @@
          inSectionWithIdentifier:
              [self.entryInserter sectionIdentifierForTimestamp:item.timestamp]];
   }
 }
 
 #pragma mark - HistoryServiceFacadeDelegate
 
 - (void)historyServiceFacade:(HistoryServiceFacade*)facade
        didReceiveQueryResult:(HistoryServiceFacade::QueryResult)result {
   self.loading = NO;
-  // Remove loading indicator.
-  CollectionViewItem* headerItem = [self.collectionViewModel
-      itemAtIndexPath:[NSIndexPath indexPathForItem:0 inSection:0]];
-  if ([headerItem.cellClass isSubclassOfClass:[ActivityIndicatorCell class]]) {
-    [self.collectionViewModel removeItemWithType:kItemTypeEnumZero
-                       fromSectionWithIdentifier:kSectionIdentifierEnumZero];
-    [self.collectionView
-        deleteItemsAtIndexPaths:@[ [NSIndexPath indexPathForItem:0
-                                                       inSection:0] ]];
+  // If history sync is enabled and there hasn't been a response from synced
+  // history, try fetching again.
+  SyncSetupService* syncSetupService =
+      SyncSetupServiceFactory::GetForBrowserState(_browserState);
+  if (syncSetupService->IsSyncEnabled() &&
+      syncSetupService->IsDataTypeEnabled(syncer::HISTORY_DELETE_DIRECTIVES) &&
+      !result.sync_returned) {
+    [self showHistoryMatchingQuery:_currentQuery];
+    return;
   }
 
   // If there are no results and no URLs have been loaded, report that no
   // history entries were found.
   if (result.entries.empty() && !self.hasHistoryEntries) {
     DCHECK(self.entriesType == NO_ENTRIES);
     [self updateEntriesStatusMessage];
     [self.delegate historyCollectionViewControllerDidChangeEntries:self];
     return;
   }
@@ skipping 182 matching lines @@
         [self.collectionViewModel itemAtIndexPath:indexPath]);
     [self fetchHistoryForQuery:_currentQuery priorToTime:lastItem.timestamp];
   }
 }
 
 #pragma mark - Private methods
 
 - (void)fetchHistoryForQuery:(NSString*)query
                  priorToTime:(const base::Time&)time {
   self.loading = YES;
-  // Add loading indicator if nothing else is shown.
+  // Add loading indicator if no items are shown.
   if (!self.hasHistoryEntries && !self.isSearching) {
-    [self.collectionView performBatchUpdates:^{
-      NSIndexPath* indexPath = [NSIndexPath indexPathForItem:0 inSection:0];
-      if ([self.collectionViewModel hasItemAtIndexPath:indexPath]) {
-        [self.collectionViewModel
-                   removeItemWithType:kItemTypeEnumZero
-            fromSectionWithIdentifier:kSectionIdentifierEnumZero];
-        [self.collectionView deleteItemsAtIndexPaths:@[ indexPath ]];
-      }
-      CollectionViewItem* loadingIndicatorItem = [[[CollectionViewItem alloc]
-          initWithType:kItemTypeEnumZero] autorelease];
-      loadingIndicatorItem.cellClass = [ActivityIndicatorCell class];
-      [self.collectionViewModel addItem:loadingIndicatorItem
-                toSectionWithIdentifier:kEntriesStatusSectionIdentifier];
-      [self.collectionView insertItemsAtIndexPaths:@[ indexPath ]];
-    }
-                                  completion:nil];
+    [self addLoadingIndicator];
   }
 
   BOOL fetchAllHistory = !query || [query isEqualToString:@""];
   base::string16 queryString =
       fetchAllHistory ? base::string16() : base::SysNSStringToUTF16(query);
   history::QueryOptions options;
   options.end_time = time;
   options.duplicate_policy =
       fetchAllHistory ? history::QueryOptions::REMOVE_DUPLICATES_PER_DAY
                       : history::QueryOptions::REMOVE_ALL_DUPLICATES;
   options.max_count = kMaxFetchCount;
   options.matching_algorithm =
       query_parser::MatchingAlgorithm::ALWAYS_PREFIX_SEARCH;
-  _historyServiceFacade->QueryOtherFormsOfBrowsingHistory();
   _historyServiceFacade->QueryHistory(queryString, options);
   // Also determine whether notice regarding other forms of browsing history
   // should be shown.
   _historyServiceFacade->QueryOtherFormsOfBrowsingHistory();
 }
 
 - (void)updateEntriesStatusMessage {
   CollectionViewItem* entriesStatusItem = nil;
   if (!self.hasHistoryEntries) {
     CollectionViewTextItem* noResultsItem = [[[CollectionViewTextItem alloc]
@@ skipping 89 matching lines @@
               selectItemAtIndexPath:indexPath
                            animated:NO
                      scrollPosition:UICollectionViewScrollPositionNone];
         }
       }
     }
   }
   [self removeSelectedItemsFromCollection];
 }
 
+- (void)addLoadingIndicator {
+  NSIndexPath* indexPath = [NSIndexPath indexPathForItem:0 inSection:0];
+  if ([self.collectionViewModel hasItemAtIndexPath:indexPath] &&
+      [[[self.collectionViewModel itemAtIndexPath:indexPath] cellClass]
+          isSubclassOfClass:[ActivityIndicatorCell class]]) {
+    // Do not add indicator a sectond time.

[lpromero, 2016/12/20 23:13:42]

second*

Can't you look instead in the model then ?

[Jackie Quinn, 2016/12/20 23:18:10]

Done. There is no ActivityIndicatorItem, only the cell.

[lpromero, 2016/12/20 23:26:23]

That's where giving a specific type to the item can come in handy I guess. Would
it be worth it here?

[Jackie Quinn, 2016/12/20 23:33:21]

If the sole purpose is checking for the type of item, I feel like an extra class
is overkill here when you can just check the cellClass. If you feel differently
let me know.

[lpromero, 2016/12/20 23:38:51]

I meant just the enum value you pass to the initializer -initWithType:, not the
type in the sense of compiler. I agree that we shouldn't need a subclass.

[Jackie Quinn, 2016/12/21 00:02:05]

Oh, I see. Yeah that sounds reasonable. Updated!

+    return;
+  }
+
+  [self.collectionView performBatchUpdates:^{
+    if ([self.collectionViewModel hasItemAtIndexPath:indexPath]) {
+      [self.collectionViewModel removeItemWithType:kItemTypeEnumZero
+                         fromSectionWithIdentifier:kSectionIdentifierEnumZero];
+      [self.collectionView deleteItemsAtIndexPaths:@[ indexPath ]];
+    }
+    CollectionViewItem* loadingIndicatorItem = [[[CollectionViewItem alloc]
+        initWithType:kItemTypeEnumZero] autorelease];
+    loadingIndicatorItem.cellClass = [ActivityIndicatorCell class];
+    [self.collectionViewModel addItem:loadingIndicatorItem
+              toSectionWithIdentifier:kEntriesStatusSectionIdentifier];
+    [self.collectionView insertItemsAtIndexPaths:@[ indexPath ]];
+  }
+                                completion:nil];
+}
+
 #pragma mark Context Menu
 
 - (void)displayContextMenuInvokedByGestureRecognizer:
     (UILongPressGestureRecognizer*)gestureRecognizer {
   if (gestureRecognizer.numberOfTouches != 1 || self.editing ||
       gestureRecognizer.state != UIGestureRecognizerStateBegan) {
     return;
   }
 
   CGPoint touchLocation =
@@ skipping 102 matching lines @@
   NSData* plainText = [base::SysUTF8ToNSString(URL.spec())
       dataUsingEncoding:NSUTF8StringEncoding];
   NSDictionary* copiedItem = @{
     (NSString*)kUTTypeURL : net::NSURLWithGURL(URL),
     (NSString*)kUTTypeUTF8PlainText : plainText,
   };
   [[UIPasteboard generalPasteboard] setItems:@[ copiedItem ]];
 }
 
 @end