a11y: Add a11y information to views::Tab and manually ignore its a11y children.

ui/accessibility/platform/ax_platform_node_mac.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ui/accessibility/platform/ax_platform_node_mac.h"
 
 #import <Cocoa/Cocoa.h>
 #include <stddef.h>
 
 #include "base/macros.h"
 #include "base/strings/sys_string_conversions.h"
 #include "ui/accessibility/ax_action_data.h"
 #include "ui/accessibility/ax_node_data.h"
 #include "ui/accessibility/platform/ax_platform_node_delegate.h"
+#include "ui/base/l10n/l10n_util.h"
 #import "ui/gfx/mac/coordinate_conversion.h"
+#include "ui/strings/grit/ui_strings.h"
 
 namespace {
 
 struct RoleMapEntry {
   ui::AXRole value;
   NSString* nativeValue;
 };
 
 struct EventMapEntry {
   ui::AXEvent value;
@@ skipping 151 matching lines @@
       {ui::AX_ROLE_MAIN, @"AXLandmarkMain"},
       {ui::AX_ROLE_MARQUEE, @"AXApplicationMarquee"},
       {ui::AX_ROLE_MATH, @"AXDocumentMath"},
       {ui::AX_ROLE_NAVIGATION, @"AXLandmarkNavigation"},
       {ui::AX_ROLE_NOTE, @"AXDocumentNote"},
       {ui::AX_ROLE_REGION, @"AXDocumentRegion"},
       {ui::AX_ROLE_SEARCH, @"AXLandmarkSearch"},
       {ui::AX_ROLE_SEARCH_BOX, @"AXSearchField"},
       {ui::AX_ROLE_STATUS, @"AXApplicationStatus"},
       {ui::AX_ROLE_SWITCH, @"AXSwitch"},
+      {ui::AX_ROLE_TAB, @"AXTab"},
       {ui::AX_ROLE_TAB_PANEL, @"AXTabPanel"},
       {ui::AX_ROLE_TIMER, @"AXApplicationTimer"},
       {ui::AX_ROLE_TOGGLE_BUTTON, @"AXToggleButton"},
       {ui::AX_ROLE_TOOLTIP, @"AXUserInterfaceTooltip"},
       {ui::AX_ROLE_TREE_ITEM, NSAccessibilityOutlineRowSubrole},
   };
 
   RoleMap subrole_map;
   for (size_t i = 0; i < arraysize(subroles); ++i)
     subrole_map[subroles[i].value] = subroles[i].nativeValue;
@@ skipping 165 matching lines @@
     default:
       break;
   }
   return axAttributes.autorelease();
 }
 
 - (BOOL)accessibilityIsAttributeSettable:(NSString*)attributeName {
   // Allow certain attributes to be written via an accessibility client. A
   // writable attribute will only appear as such if the accessibility element
   // has a value set for that attribute.
-  if ([attributeName isEqualToString:NSAccessibilitySelectedAttribute] ||
-      [attributeName
+  if ([attributeName
           isEqualToString:NSAccessibilitySelectedChildrenAttribute] ||
       [attributeName
           isEqualToString:NSAccessibilitySelectedTextRangeAttribute] ||
       [attributeName
           isEqualToString:NSAccessibilityVisibleCharacterRangeAttribute]) {
     return NO;
   }
 
+  // Since tabs use the Radio Button role on Mac, the standard way to set them
+  // is via the value attribute rather than the selected attribute.
+  if ([attributeName isEqualToString:NSAccessibilityValueAttribute] &&
+      node_->GetData().role == ui::AX_ROLE_TAB) {
+    return !node_->GetData().HasStateFlag(ui::AX_STATE_SELECTED);
+  }
+
   if ([attributeName isEqualToString:NSAccessibilityValueAttribute] ||
-      [attributeName isEqualToString:NSAccessibilitySelectedTextAttribute])
+      [attributeName isEqualToString:NSAccessibilitySelectedTextAttribute]) {
     return !ui::AXNodeData::IsFlagSet(node_->GetData().state,
                                       ui::AX_STATE_READ_ONLY);
+  }
 
   if ([attributeName isEqualToString:NSAccessibilityFocusedAttribute]) {
     return ui::AXNodeData::IsFlagSet(node_->GetData().state,
                                      ui::AX_STATE_FOCUSABLE);
   }
 
   // TODO(patricialor): Add callbacks for updating the above attributes except
   // NSAccessibilityValueAttribute and return YES.
   return NO;
 }
 
 - (void)accessibilitySetValue:(id)value forAttribute:(NSString*)attribute {
   ui::AXActionData data;
+
+  // Check for attributes which accept any |value| type (i.e. ids) first. Only
+  // the |data.action| should be set here - any type-specific information, if
+  // needed, should be set below, where there are type checks.
+  if ([attribute isEqualToString:NSAccessibilityValueAttribute]) {
+    data.action = node_->GetData().role == ui::AX_ROLE_TAB
+                      ? ui::AX_ACTION_SET_SELECTION
+                      : data.action = ui::AX_ACTION_SET_VALUE;

[tapted, 2017/01/10 16:22:18]

the single `=` doesn't look right on this line, although it probably achieves
the same thing (I think: delete `data.action = ` from this line)

[Patti Lor, 2017/01/11 05:51:44]

Oops, thank you - joined the line but didn't edit it.

+  }
+
+  // Set actions for attributes restricted to a specific type. Also set
+  // type-specific information as necessary for actions set above.

[tapted, 2017/01/10 16:22:18]

It looks easy to introduce codepaths where the stuff below may override the
data.action set above - is that intentional? The comment should mention that if
so (e.g. "Note the data.action set above may be overridden depending on the type
of |attribute|."). Otherwise, perhaps it would be better to move all the
[attribute isEqualToString] checks above, and just check [value isKindOfClass]
in the set of if statements here?

[Patti Lor, 2017/01/11 05:51:44]

Not intentional - I was trying to make a nice way to account for special cases
like the value (where you might potentially receive any possible type for the
same action) as well as the focus (where you need to know the attribute as well
as the type before setting the action).

I implemented your second suggestion, but it still needs a type check for
setting focus/blur actions, so the attribute/type checking isn't completely
separate. I'm not sure which way is preferable.

   if ([value isKindOfClass:[NSString class]]) {
     data.value = base::SysNSStringToUTF16(value);
-    if ([attribute isEqualToString:NSAccessibilityValueAttribute]) {
-      data.action = ui::AX_ACTION_SET_VALUE;
-    } else if ([attribute
-                   isEqualToString:NSAccessibilitySelectedTextAttribute]) {
+    if ([attribute isEqualToString:NSAccessibilitySelectedTextAttribute]) {
       data.action = ui::AX_ACTION_REPLACE_SELECTED_TEXT;
     }
   } else if ([value isKindOfClass:[NSNumber class]]) {
     if ([attribute isEqualToString:NSAccessibilityFocusedAttribute]) {
       data.action =
           [value boolValue] ? ui::AX_ACTION_FOCUS : ui::AX_ACTION_BLUR;
     }
   }
 
   if (data.action != ui::AX_ACTION_NONE)
@@ skipping 46 matching lines @@
                                     ui::AX_STATE_PROTECTED))
         return NSAccessibilitySecureTextFieldSubrole;
       break;
     default:
       break;
   }
   return [AXPlatformNodeCocoa nativeSubroleFromAXRole:role];
 }
 
 - (NSString*)AXRoleDescription {
+  switch (node_->GetData().role) {
+    case ui::AX_ROLE_TAB:
+      // There is no NSAccessibilityTabRole or similar (AXRadioButton is used
+      // instead). Do the same as NSTabView and put "tab" in the description.
+      return [l10n_util::GetNSStringWithFixup(IDS_ACCNAME_TAB_ROLE_DESCRIPTION)
+          lowercaseString];
+    default:
+      break;
+  }
   return NSAccessibilityRoleDescription([self AXRole], [self AXSubrole]);
 }
 
 - (NSValue*)AXSize {
   return [NSValue valueWithSize:self.boundsInScreen.size];
 }
 
 - (NSString*)AXTitle {
   return [self getStringAttribute:ui::AX_ATTR_NAME];
 }
 
-- (NSString*)AXValue {
+- (id)AXValue {
+  if (node_->GetData().role == ui::AX_ROLE_TAB)
+    return [self AXSelected];
   return [self getStringAttribute:ui::AX_ATTR_VALUE];
 }
 
 - (NSValue*)AXEnabled {
   return [NSNumber
       numberWithBool:!ui::AXNodeData::IsFlagSet(node_->GetData().state,
                                                 ui::AX_STATE_DISABLED)];
 }
 
 - (NSValue*)AXFocused {
@@ skipping 50 matching lines @@
   int beginSelectionIndex = (end > start && !isReversed) ? start : end;
   return [NSValue
       valueWithRange:NSMakeRange(beginSelectionIndex, abs(end - start))];
 }
 
 - (NSValue*)AXVisibleCharacterRange {
   return [NSValue
       valueWithRange:NSMakeRange(0, [[self AXNumberOfCharacters] intValue])];
 }
 
+// Misc NSAccessibility attributes.
+
+- (NSNumber*)AXSelected {
+  return [NSNumber
+      numberWithBool:node_->GetData().HasStateFlag(ui::AX_STATE_SELECTED)];
+}
+
 @end
 
 namespace ui {
 
 // static
 AXPlatformNode* AXPlatformNode::Create(AXPlatformNodeDelegate* delegate) {
   AXPlatformNodeBase* node = new AXPlatformNodeMac();
   node->Init(delegate);
   return node;
 }
@@ skipping 33 matching lines @@
   }
   NotifyMacEvent(native_node_, event_type);
 }
 
 int AXPlatformNodeMac::GetIndexInParent() {
   // TODO(dmazzoni): implement this.  http://crbug.com/396137
   return -1;
 }
 
 }  // namespace ui