[ObjC ARC] Converts ios/chrome/browser/ui/alert_coordinator:alert_coordinator to ARC.

ios/chrome/browser/ui/alert_coordinator/alert_coordinator.mm

 // Copyright 2016 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/ui/alert_coordinator/alert_coordinator.h"
 
-#import "base/ios/weak_nsobject.h"
-#import "base/mac/scoped_block.h"
-#import "base/mac/scoped_nsobject.h"
+#include "base/logging.h"
 #include "ui/base/l10n/l10n_util.h"
 #include "ui/strings/grit/ui_strings.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 @interface AlertCoordinator () {
-  // Variables backing properties of the same name.
-  base::scoped_nsobject<UIAlertController> _alertController;
-  base::scoped_nsobject<NSString> _message;
-  base::mac::ScopedBlock<ProceduralBlock> _cancelAction;
-  base::mac::ScopedBlock<ProceduralBlock> _startAction;
-  base::mac::ScopedBlock<ProceduralBlock> _noInteractionAction;
-  base::mac::ScopedBlock<ProceduralBlock> _rawCancelAction;
-
+  // Variable backing properties of the same name.

[noyau (Ping after 24h), 2016/12/12 15:55:58]

This comment is not true anymore.

[stkhapugin, 2016/12/12 16:39:50]

It is true, the property is just in a category so it cannot be synthesized and
has to be manually declared here.

+  UIAlertController* _alertController;
   // Title for the alert.
-  base::scoped_nsobject<NSString> _title;
+  NSString* _title;
 }
 
 // Redefined to readwrite.
 @property(nonatomic, readwrite, getter=isVisible) BOOL visible;
 
 // Cancel action passed using the public API.
 // It will called from the overridden block stored in the |cancelAction|
 // property.
 @property(nonatomic, copy) ProceduralBlock rawCancelAction;
 
 // Called when the alert is dismissed to perform cleanup.
 - (void)alertDismissed;
 
 - (UIAlertController*)alertControllerWithTitle:(NSString*)title
                                        message:(NSString*)message;
 @end
 
 @implementation AlertCoordinator
 
 @synthesize visible = _visible;
 @synthesize cancelButtonAdded = _cancelButtonAdded;
+@synthesize cancelAction = _cancelAction;
+@synthesize startAction = _startAction;
+@synthesize noInteractionAction = _noInteractionAction;
+@synthesize rawCancelAction = _rawCancelAction;
+@synthesize message = _message;
 
 - (instancetype)initWithBaseViewController:(UIViewController*)viewController {
   NOTREACHED();
   return nil;
 }
 
 - (instancetype)initWithBaseViewController:(UIViewController*)viewController
                                      title:(NSString*)title
                                    message:(NSString*)message {
   self = [super initWithBaseViewController:viewController];
   if (self) {
-    _title.reset([title copy]);
-    _message.reset([message copy]);
+    _title = [title copy];
+    _message = [message copy];
   }
   return self;
 }
 
 #pragma mark - Public Methods.
 
 - (void)addItemWithTitle:(NSString*)title
                   action:(ProceduralBlock)actionBlock
                    style:(UIAlertActionStyle)style {
   if (self.visible ||
       (style == UIAlertActionStyleCancel && self.cancelButtonAdded)) {
     return;
   }
 
   if (style == UIAlertActionStyleCancel)
     _cancelButtonAdded = YES;
 
-  base::WeakNSObject<AlertCoordinator> weakSelf(self);
+  __weak AlertCoordinator* weakSelf = self;
 
   UIAlertAction* alertAction =
       [UIAlertAction actionWithTitle:title
                                style:style
                              handler:^(UIAlertAction*) {
                                [weakSelf setNoInteractionAction:nil];
                                if (actionBlock)
                                  actionBlock();
                                [weakSelf alertDismissed];
                              }];
@@ skipping 27 matching lines @@
     self.startAction();
 
   [self.baseViewController presentViewController:self.alertController
                                         animated:YES
                                       completion:nil];
   self.visible = YES;
 }
 
 - (void)stop {
   if (_noInteractionAction) {
-    _noInteractionAction.get()();
-    _noInteractionAction.reset();
+    _noInteractionAction();
+    _noInteractionAction = nil;
   }
   [[_alertController presentingViewController]
       dismissViewControllerAnimated:NO
                          completion:nil];
   [self alertDismissed];
 }
 
 #pragma mark - Property Implementation.
 
 - (UIAlertController*)alertController {
   if (!_alertController) {
     UIAlertController* alert =
         [self alertControllerWithTitle:_title message:_message];
 
     if (alert)
-      _alertController.reset([alert retain]);
+      _alertController = alert;
   }
   return _alertController;
 }
 
 - (NSString*)message {
   return _message;
 }
 
-- (void)setMessage:(NSString*)message {
-  _message.reset([message copy]);
-}
-
-- (ProceduralBlock)cancelAction {
-  return _cancelAction;
-}
-
 - (void)setCancelAction:(ProceduralBlock)cancelAction {
-  base::WeakNSObject<AlertCoordinator> weakSelf(self);
+  __weak AlertCoordinator* weakSelf = self;
 
   self.rawCancelAction = cancelAction;
 
-  _cancelAction.reset([^{
-    base::scoped_nsobject<AlertCoordinator> strongSelf([weakSelf retain]);
+  _cancelAction = [^{
+    AlertCoordinator* strongSelf = weakSelf;
     [strongSelf setNoInteractionAction:nil];
     if ([strongSelf rawCancelAction]) {
       [strongSelf rawCancelAction]();
     }
-  } copy]);
-}
-
-- (ProceduralBlock)startAction {
-  return _startAction;
-}
-
-- (void)setStartAction:(ProceduralBlock)startAction {
-  _startAction.reset([startAction copy]);
-}
-
-- (ProceduralBlock)noInteractionAction {
-  return _noInteractionAction;
-}
-
-- (void)setNoInteractionAction:(ProceduralBlock)noInteractionAction {
-  _noInteractionAction.reset([noInteractionAction copy]);
-}
-
-- (ProceduralBlock)rawCancelAction {
-  return _rawCancelAction;
-}
-
-- (void)setRawCancelAction:(ProceduralBlock)rawCancelAction {
-  _rawCancelAction.reset([rawCancelAction copy]);
+  } copy];
 }
 
 #pragma mark - Private Methods.
 
 - (void)alertDismissed {
   self.visible = NO;
   _cancelButtonAdded = NO;
-  _alertController.reset();
-  _cancelAction.reset();
-  _noInteractionAction.reset();
+  _alertController = nil;
+  _cancelAction = nil;
+  _noInteractionAction = nil;
 }
 
 - (UIAlertController*)alertControllerWithTitle:(NSString*)title
                                        message:(NSString*)message {
   return
       [UIAlertController alertControllerWithTitle:title
                                           message:message
                                    preferredStyle:UIAlertControllerStyleAlert];
 }
 
 @end