[ObjC ARC] Converts ios/chrome/browser:browser to ARC.

ios/chrome/browser/installation_notifier.mm

 // Copyright 2013 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/installation_notifier.h"
 
 #import <UIKit/UIKit.h>
 #include <stdint.h>
 
 #include <memory>
 
-#include "base/ios/weak_nsobject.h"
 #include "base/logging.h"
-#include "base/mac/scoped_nsobject.h"
 #include "base/metrics/histogram.h"
 #include "ios/web/public/web_thread.h"
 #include "net/base/backoff_entry.h"
 #include "url/gurl.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 namespace {
 const net::BackoffEntry::Policy kPollingBackoffPolicy = {
     0,          // Number of errors to ignore.
     1 * 1000,   // Initial delay in milliseconds.
     1.5,        // Multiply factor.
     0.1,        // Jitter factor.
     60 * 1000,  // Maximum backoff in milliseconds.
     -1,         // Entry lifetime.
     false       // Always use initial delay.
 };
@@ skipping 27 matching lines @@
 @interface InstallationNotifier (Testing)
 // Sets the dispatcher.
 - (void)setDispatcher:(id<DispatcherProtocol>)dispatcher;
 // Sets the UIApplication used to determine if a scheme can be opened by an
 // application.
 - (void)setSharedApplication:(UIApplication*)sharedApplication;
 @end
 
 @implementation InstallationNotifier {
   std::unique_ptr<net::BackoffEntry> _backoffEntry;
-  base::scoped_nsprotocol<id<DispatcherProtocol>> _dispatcher;
+  id<DispatcherProtocol> _dispatcher;
   // Dictionary mapping URL schemes to mutable sets of observers.
-  base::scoped_nsobject<NSMutableDictionary> _installedAppObservers;
-  NSNotificationCenter* _notificationCenter;  // Weak.
+  NSMutableDictionary* _installedAppObservers;
+  __weak NSNotificationCenter* _notificationCenter;
 
   // This object can be a fake application in unittests.
-  UIApplication* sharedApplication_;  // Weak.
+  __weak UIApplication* sharedApplication_;
 }
 
 @synthesize lastCreatedBlockId = lastCreatedBlockId_;
 
 + (InstallationNotifier*)sharedInstance {
   static InstallationNotifier* instance = [[InstallationNotifier alloc] init];
   return instance;
 }
 
 - (instancetype)init {
   self = [super init];
   if (self) {
     lastCreatedBlockId_ = 0;
-    _dispatcher.reset([[DefaultDispatcher alloc] init]);
-    _installedAppObservers.reset([[NSMutableDictionary alloc] init]);
+    _dispatcher = [[DefaultDispatcher alloc] init];
+    _installedAppObservers = [[NSMutableDictionary alloc] init];
     _notificationCenter = [NSNotificationCenter defaultCenter];
     sharedApplication_ = [UIApplication sharedApplication];
     _backoffEntry.reset(new net::BackoffEntry([self backOffPolicy]));
   }
   return self;
 }
 
 - (void)registerForInstallationNotifications:(id)observer
                                 withSelector:(SEL)notificationSelector
                                    forScheme:(NSString*)scheme {
@@ skipping 11 matching lines @@
   if (![scheme length])
     return;
   DCHECK([observer respondsToSelector:notificationSelector]);
   DCHECK([scheme rangeOfString:@":"].location == NSNotFound);
   // A strong reference would prevent the observer from unregistering itself
   // from its dealloc method, because the dealloc itself would never be called.
   NSValue* weakReferenceToObserver =
       [NSValue valueWithNonretainedObject:observer];
   NSMutableSet* observers = [_installedAppObservers objectForKey:scheme];
   if (!observers)
-    observers = [[[NSMutableSet alloc] init] autorelease];
+    observers = [[NSMutableSet alloc] init];
   if ([observers containsObject:weakReferenceToObserver])
     return;
   [observers addObject:weakReferenceToObserver];
   [_installedAppObservers setObject:observers forKey:scheme];
   [_notificationCenter addObserver:observer
                           selector:notificationSelector
                               name:scheme
                             object:self];
   _backoffEntry->Reset();
   if (poll)
@@ skipping 23 matching lines @@
   _backoffEntry->Reset();
   [self pollForTheInstallationOfApps];
 }
 
 - (void)dispatchInstallationNotifierBlock {
   DCHECK_CURRENTLY_ON(web::WebThread::UI);
   int blockId = ++lastCreatedBlockId_;
   _backoffEntry->InformOfRequest(false);
   int64_t delayInNSec =
       _backoffEntry->GetTimeUntilRelease().InMicroseconds() * NSEC_PER_USEC;
-  base::WeakNSObject<InstallationNotifier> weakSelf(self);
+  __weak InstallationNotifier* weakSelf = self;
   [_dispatcher dispatchAfter:delayInNSec
                    withBlock:^{
                      DCHECK_CURRENTLY_ON(web::WebThread::UI);
-                     base::scoped_nsobject<InstallationNotifier> strongSelf(
-                         [weakSelf retain]);
+                     InstallationNotifier* strongSelf = weakSelf;
                      if (blockId == [strongSelf lastCreatedBlockId]) {
                        [strongSelf pollForTheInstallationOfApps];
                      }
                    }];
 }
 
 - (void)pollForTheInstallationOfApps {
   DCHECK_CURRENTLY_ON(web::WebThread::UI);
   __block BOOL keepPolling = NO;
   NSMutableSet* keysToDelete = [NSMutableSet set];
@@ skipping 25 matching lines @@
 }
 
 - (net::BackoffEntry::Policy const*)backOffPolicy {
   return &kPollingBackoffPolicy;
 }
 
 #pragma mark -
 #pragma mark Testing setters
 
 - (void)setDispatcher:(id<DispatcherProtocol>)dispatcher {
-  _dispatcher.reset(dispatcher);
+  _dispatcher = dispatcher;
 }
 
 - (void)setSharedApplication:(id)sharedApplication {
   // Verify that the test application object responds to all the selectors that
   // will be called on it.
   CHECK([sharedApplication respondsToSelector:@selector(canOpenURL:)]);
   sharedApplication_ = (UIApplication*)sharedApplication;
 }
 
 @end