Handle storyboards in GN.

build/config/mac/base_rules.gni

 # Copyright 2016 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 # This file contains rules that are shared between Mac and iOS.
 
 import("//build/toolchain/toolchain.gni")
 import("//build/config/mac/symbols.gni")
 
 if (is_mac) {
@@ skipping 184 matching lines @@
       "PRODUCT_NAME=$executable_name",
       "XCODE_BUILD=$xcode_build",
       "XCODE_VERSION=$xcode_version",
     ]
     if (defined(invoker.extra_substitutions)) {
       substitutions += invoker.extra_substitutions
     }
   }
 }
 
-# Template to combile .xib or .storyboard files.
+# Template to compile .xib files.
 #
 # Arguments
 #
 #     sources:
 #         list of string, sources to compile
 #
 #     ibtool_flags:
 #         (optional) list of string, additional flags to pass to the ibtool
 template("compile_xibs") {

[sdefresne, 2016/12/09 15:27:15]

There is only one difference between compile_xibs and compile_storyboards (the
extension of the output) and I think we would be better factoring this out than
duplicating the code.

What about:

# Template to combile .xib or .storyboard files.
#
# Arguments
#
#     sources:
#         list of string, sources to compile
#
#     output_extensions:
#         string, extension of the compiled files
#
#     ibtool_flags:
#         (optional) list of string, additional flags to pass to the ibtool
template("compile_ib_files") {
  action_foreach(target_name) {
    forward_variables_from(invoker,
                           [
                             "testonly",
                             "visibility",
                           ])
    assert(defined(invoker.sources),
           "Sources must be specified for $target_name")
    assert(defined(invoker.output_extension),
           "output_extension must be specified for $target_name")

    ibtool_flags = []
    if (defined(invoker.ibtool_flags)) {
      ibtool_flags = invoker.ibtool_flags
    }

    _output_extension = invoker.output_extension

    script = "//build/config/mac/compile_xib.py"
    sources = invoker.sources
    outputs = [
      "$target_gen_dir/$target_name/{{source_name_part}}.$_output_extension",
    ]
    args = [
      "--input",
      "{{source}}",
      "--output",
    ] + rebase_path(outputs, root_build_dir)
    if (!use_system_xcode) {
      args += [
        "--developer_dir",
        hermetic_xcode_path,
      ]
    }
    args += ibtool_flags
  }
}

[lpromero, 2016/12/09 15:44:49]

Right, I tried to factor out. invoker.output_extension is definitely
interesting, but there is one thing I don't understand.

invoker.sources means there could be several files, right? So I don't understand
what invoker.output_extension returns, especially if there are several sources
files with different extensions.

   action_foreach(target_name) {
     forward_variables_from(invoker,
                            [
                              "testonly",
                              "visibility",
                            ])
     assert(defined(invoker.sources),
            "Sources must be specified for $target_name")
 
     ibtool_flags = []
     if (defined(invoker.ibtool_flags)) {
       ibtool_flags = invoker.ibtool_flags
     }
 
-    script = "//build/config/mac/compile_xib.py"
+    script = "//build/config/mac/compile_ib_files.py"
     sources = invoker.sources
     outputs = [
       "$target_gen_dir/$target_name/{{source_name_part}}.nib",
     ]
     args = [
       "--input",
       "{{source}}",
       "--output",
       rebase_path("$target_gen_dir/$target_name/{{source_name_part}}.nib"),
     ]
     if (!use_system_xcode) {
       args += [
         "--developer_dir",
         hermetic_xcode_path,
       ]
     }
     args += ibtool_flags
   }
 }
+
+# Template to compile .storyboard files.
+#
+# Arguments
+#
+#     sources:
+#         list of string, sources to compile
+#
+#     ibtool_flags:
+#         (optional) list of string, additional flags to pass to the ibtool
+template("compile_storyboards") {
+  action_foreach(target_name) {
+    forward_variables_from(invoker,
+                           [
+                             "testonly",
+                             "visibility",
+                           ])
+    assert(defined(invoker.sources),
+           "Sources must be specified for $target_name")
+
+    ibtool_flags = []
+    if (defined(invoker.ibtool_flags)) {
+      ibtool_flags = invoker.ibtool_flags
+    }
+
+    script = "//build/config/mac/compile_ib_files.py"
+    sources = invoker.sources
+    outputs = [
+      "$target_gen_dir/$target_name/{{source_name_part}}.storyboardc",
+    ]
+    args = [
+      "--input",
+      "{{source}}",
+      "--output",
+      rebase_path(
+          "$target_gen_dir/$target_name/{{source_name_part}}.storyboardc"),
+    ]
+    if (!use_system_xcode) {
+      args += [
+        "--developer_dir",
+        hermetic_xcode_path,
+      ]
+    }
+    args += ibtool_flags
+  }
+}