Add incremental_apk_by_default GN arg.

build/config/android/rules.gni

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 # Do not add any imports to non-//build directories here.
 # Some projects (e.g. V8) do not have non-build directories DEPS'ed in.
 import("//build/config/android/config.gni")
 import("//build/config/android/internal_rules.gni")
 import("//build/config/compiler/compiler.gni")
 import("//build/config/dcheck_always_on.gni")
@@ skipping 1381 matching lines @@
   #     all other asset files.
   #   requires_sdk_api_level_23: If defined and true, the apk is intended for
   #     installation only on Android M or later. In these releases the system
   #     linker does relocation unpacking, so we can enable it unconditionally.
   #   secondary_native_libs (deprecated): The path of native libraries for secondary
   #     app abi.
   #   run_findbugs_override: Forces run_findbugs on or off. If undefined, the
   #     default will use the build arg run_findbugs.
   #   proguard_jar_path: The path to proguard.jar you wish to use. If undefined,
   #     the proguard used will be the checked in one in //third_party/proguard.
+  #   never_incremental: If true, |incremental_apk_by_default| will be ignored.

[agrieve, 2016/12/14 15:53:03]

Just realized - we should set this for monochrome_apk as well (with a comment
pointing to http://crbug.com/663492)

[estevenson, 2016/12/14 22:26:03]

Done.

   #
   # Example
   #   android_apk("foo_apk") {
   #     android_manifest = "AndroidManifest.xml"
   #     java_files = [
   #       "android/org/chromium/foo/FooApplication.java",
   #       "android/org/chromium/foo/FooActivity.java",
   #     ]
   #     deps = [
   #       ":foo_support_java"
@@ skipping 44 matching lines @@
         process_file_template([ _final_apk_path ],
                               "{{source_dir}}/{{source_name_part}}")
     _final_apk_path_no_ext = _final_apk_path_no_ext_list[0]
     assert(_final_apk_path_no_ext != "")  # Mark as used.
 
     _install_script_name = "install_$_template_name"
     if (defined(invoker.install_script_name)) {
       _install_script_name = invoker.install_script_name
     }
     _incremental_install_script_path =
-        "${root_out_dir}/bin/${_install_script_name}_incremental"
+        "${root_out_dir}/bin/${_install_script_name}"
+    if (!incremental_apk_by_default) {
+      _incremental_install_script_path =
+          "${_incremental_install_script_path}_incremental"
+    }
 
     _version_code = android_default_version_code
     if (defined(invoker.version_code)) {
       _version_code = invoker.version_code
     }
 
     _version_name = android_default_version_name
     if (defined(invoker.version_name)) {
       _version_name = invoker.version_name
     }
@@ skipping 713 matching lines @@
       }
       if (_create_language_splits) {
         args += [ "--split=${_rebased_apk_path_no_ext}-language-*.apk" ]
       }
       if (_load_library_from_apk) {
         args += [ "--dont-even-try=Incremental builds do not work with load_library_from_apk. Try setting is_component_build=true in your GN args." ]
       }
     }
 
     group(target_name) {
-      forward_variables_from(invoker,
-                             [
-                               "data",
-                               "data_deps",
-                             ])
-      public_deps = _final_deps
+      _incremental_allowed =
+          !(defined(invoker.never_incremental) && invoker.never_incremental)
+      if (_incremental_allowed && incremental_apk_by_default) {
+        deps = [
+          ":${target_name}_incremental",
+        ]
+      } else {
+        forward_variables_from(invoker,
+                               [
+                                 "data",
+                                 "data_deps",
+                               ])
+        public_deps = _final_deps
 
-      # Make the proguard .mapping file easy to find by putting it beside the .apk.
-      if (_proguard_enabled) {
-        deps = [
-          ":$_copy_proguard_mapping_target",
-        ]
+        # Make the proguard .mapping file easy to find by putting it beside the .apk.
+        if (_proguard_enabled) {
+          deps = [
+            ":$_copy_proguard_mapping_target",
+          ]
+        }
       }
     }
     group("${target_name}_incremental") {

[agrieve, 2016/12/14 15:53:03]

Realized too - we should not define this target when never_incremental is set.

[estevenson, 2016/12/14 22:26:03]

Done.

       forward_variables_from(invoker,
                              [
                                "data",
                                "data_deps",
                              ])
       if (!defined(data_deps)) {
         data_deps = []
       }
 
       # device/commands is used by the installer script to push files via .zip.
@@ skipping 50 matching lines @@
   #     ]
   #   }
   template("instrumentation_test_apk") {
     assert(defined(invoker.apk_name))
     testonly = true
     _apk_target_name = "${target_name}__apk"
     _test_runner_target_name = "${target_name}__test_runner_script"
     _install_script_name = "install_$target_name"
     _dist_ijar_path =
         "$root_build_dir/test.lib.java/" + invoker.apk_name + ".jar"
+    _incremental_test_runner_target_name =
+        "${_test_runner_target_name}_incremental"
+    _incremental_test_name = "${invoker.target_name}_incremental"
+    if (incremental_apk_by_default) {
+      _incremental_test_runner_target_name = _test_runner_target_name
+      _incremental_test_name = invoker.target_name
+    }
 
-    test_runner_script(_test_runner_target_name) {
+    if (!incremental_apk_by_default) {
+      test_runner_script(_test_runner_target_name) {
+        forward_variables_from(invoker,
+                               [
+                                 "additional_apks",
+                                 "apk_under_test",
+                                 "data",
+                                 "data_deps",
+                                 "deps",
+                                 "ignore_all_data_deps",
+                                 "public_deps",
+                               ])
+        test_name = invoker.target_name
+        test_type = "instrumentation"
+        apk_target = ":$_apk_target_name"
+        test_jar = _dist_ijar_path
+      }
+    }
+    test_runner_script(_incremental_test_runner_target_name) {
       forward_variables_from(invoker,
                              [
                                "additional_apks",
-                               "apk_under_test",
-                               "data",
-                               "data_deps",
-                               "deps",
-                               "ignore_all_data_deps",
-                               "public_deps",
-                             ])
-      test_name = invoker.target_name
-      test_type = "instrumentation"
-      apk_target = ":$_apk_target_name"
-      test_jar = _dist_ijar_path
-    }
-
-    test_runner_script("${_test_runner_target_name}_incremental") {
-      forward_variables_from(invoker,
-                             [
-                               "additional_apks",
                                "apk_under_test",
                                "data",
                                "data_deps",
                                "deps",
                                "ignore_all_data_deps",
                                "public_deps",
                              ])
-      test_name = "${invoker.target_name}_incremental"
+      test_name = _incremental_test_name
       test_type = "instrumentation"
       apk_target = ":$_apk_target_name"
       test_jar = _dist_ijar_path
       incremental_install = true
     }
 
     android_apk(_apk_target_name) {
       deps = []
       data_deps = []
       forward_variables_from(invoker, "*")
@@ skipping 22 matching lines @@
 
       dist_ijar_path = _dist_ijar_path
       if (defined(invoker.run_findbugs_override)) {
         # Only allow findbugs when there are java files.
         run_findbugs_override =
             invoker.run_findbugs_override && defined(invoker.java_files)
       }
     }
 
     group(target_name) {
-      public_deps = [
-        ":$_apk_target_name",
-        ":$_test_runner_target_name",
+      if (incremental_apk_by_default) {
+        deps = [
+          ":${target_name}_incremental",
+        ]
+      } else {
+        public_deps = [
+          ":$_apk_target_name",
+          ":$_test_runner_target_name",
 
-        # Required by test runner to enumerate test list.
-        ":${_apk_target_name}_dist_ijar",
-      ]
-      if (defined(invoker.apk_under_test)) {
-        public_deps += [ invoker.apk_under_test ]
+          # Required by test runner to enumerate test list.
+          ":${_apk_target_name}_dist_ijar",
+        ]
+        if (defined(invoker.apk_under_test)) {
+          public_deps += [ invoker.apk_under_test ]
+        }
       }
     }
 
     # TODO: Delete once recipes no longer use this target.
     group("${target_name}_run") {
       public_deps = [
         ":${invoker.target_name}",
       ]
     }
     group("${target_name}_incremental") {
       public_deps = [
+        ":$_incremental_test_runner_target_name",
         ":${_apk_target_name}_dist_ijar",
         ":${_apk_target_name}_incremental",
-        ":${_test_runner_target_name}_incremental",
       ]
       if (defined(invoker.apk_under_test)) {
         public_deps += [ "${invoker.apk_under_test}_incremental" ]
       }
     }
   }
 
   # Declare an Android gtest apk
   #
   # This target creates an Android apk for running gtest-based unittests.
@@ skipping 392 matching lines @@
         # because in practice they seem to contain classes required to be in the
         # classpath.
         deps += _subjar_targets
       }
       if (defined(_res_target_name)) {
         deps += [ ":$_res_target_name" ]
       }
     }
   }
 }