Cronet smoke tests

components/cronet/android/BUILD.gn

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/buildflag_header.gni")
 import("//build/config/android/config.gni")
 import("//build/config/android/rules.gni")
 import("//build/util/process_version.gni")
 import("//build/util/version.gni")
 import("//testing/test.gni")
@@ skipping 533 matching lines @@
   # version tags.
   configs -= [ "//build/config/android:hide_native_jni_exports" ]
 
   if (cronet_enable_data_reduction_proxy_support) {
     deps += [ "//components/data_reduction_proxy/core/browser:browser_small" ]
   }
 }
 
 android_resources("cronet_test_apk_resources") {
   testonly = true
-  resource_dirs = [ "test/res" ]
+  resource_dirs = [
+    "test/res",
+    "test/smoketests/res/quic",
+  ]
   android_manifest = "test/AndroidManifest.xml"
 }
 
 android_library("cronet_test_apk_java") {
   testonly = true
 
   java_files = [
     "test/src/org/chromium/net/CronetTestApplication.java",
     "test/src/org/chromium/net/CronetTestFramework.java",
     "test/src/org/chromium/net/CronetTestUtil.java",
@@ skipping 14 matching lines @@
     "//base:base_java",
     "//base:base_java_test_support",
     "//net/android:net_java_test_support",
     "//third_party/netty-tcnative:netty-tcnative_java",
     "//third_party/netty4:netty_all_java",
   ]
 
   run_findbugs_override = true
 }
 
+java_only_smoke_test_common_srcs = [

[mef, 2016/12/08 23:17:18]

naming nit: maybe start all those with cronet_smoketest like
'cronet_smoketest_java_only_common_srcs'?

[kapishnikov, 2016/12/19 19:31:10]

Done.

+  "test/smoketests/src/org/chromium/net/smoke/TestSupport.java",
+  "test/smoketests/src/org/chromium/net/smoke/ChromiumJavaOnlyTestSupport.java",
+  "test/smoketests/src/org/chromium/net/smoke/HttpTestServer.java",
+  "test/smoketests/src/org/chromium/net/smoke/CronetTestBase.java",

[mef, 2016/12/08 23:17:18]

nit: I'm not sure whether smoke_test or smoketests is better, but would like
some consistency.

[kapishnikov, 2016/12/19 19:31:10]

Renamed everywhere to smoketests.

+  "test/smoketests/src/org/chromium/net/smoke/TestUrlRequestCallback.java",
+]
+
+quic_smoke_test_common_srcs = java_only_smoke_test_common_srcs + [

[mef, 2016/12/08 23:17:18]

maybe add java_only_smoke_test_common_srcs explicitly to java_files below?

[kapishnikov, 2016/12/19 19:31:10]

quic_smoke_test_common_srcs depends on java_only_smoke_test_common_srcs, i.e. it
won't compile without it. Somebody may add quic_smoke_test_common_srcs but
forget java_only_smoke_test_common_srcs.

+                                "test/smoketests/src/org/chromium/net/smoke/NativeCronetTestBase.java",
+                                "test/smoketests/src/org/chromium/net/smoke/ChromiumNativeTestSupport.java",
+                              ]
+
+android_library("cronet_quic_smoke_test_java") {
+  testonly = true
+  java_files = [
+                 "test/smoketests/src/org/chromium/net/smoke/QuicTest.java",
+                 "test/smoketests/src/org/chromium/net/smoke/H2Test.java",
+               ] + quic_smoke_test_common_srcs
+
+  deps = [
+    ":cronet_api_java",
+    ":cronet_test_apk_java",
+    "//base:base_java",
+    "//third_party/netty4:netty_all_java",

[mef, 2016/12/08 23:17:18]

hrm, netty4 is for h2, why do we need it for quic?

[kapishnikov, 2016/12/19 19:31:10]

netty is required to compile ChromiumNativeTestSupport.java

+  ]
+}
+
 android_assets("cronet_test_apk_assets") {
   testonly = true
 
   # Need to use renaming_sources to maintain subdirectories.
   renaming_sources = [
     "test/assets/test/cacheable.txt",
     "test/assets/test/cacheable.txt.mock-http-headers",
     "test/assets/test/content_length_mismatch.html",
     "test/assets/test/content_length_mismatch.html.mock-http-headers",
     "test/assets/test/datareductionproxysuccess.txt",
@@ skipping 31 matching lines @@
   testonly = true
   apk_name = "CronetTest"
   android_manifest = "test/AndroidManifest.xml"
   shared_libraries = [
     ":cronet",
     ":cronet_tests",
   ]
   loadable_modules = [ "$root_out_dir/libnetty-tcnative.so" ]
 
   deps = [
+    ":cronet_combine_proguard_flags",
     ":cronet_test_apk_assets",
-    ":cronet_test_apk_java",
     ":cronet_test_apk_resources",
     "//base:base_java",
     "//third_party/netty-tcnative:netty-tcnative-so",
   ]
 
+  proguard_enabled = true
+
+  proguard_configs = [
+    "$target_gen_dir/cronet_impl_native_proguard.cfg",
+    "cronet_impl_common_proguard.cfg",
+    "cronet_impl_platform_proguard.cfg",
+  ]
+
   run_findbugs_override = true
 }
 
 android_library("cronet_javatests") {
   testonly = true
 
   java_files = [
     "test/javatests/src/org/chromium/net/BidirectionalStreamQuicTest.java",
     "test/javatests/src/org/chromium/net/BidirectionalStreamTest.java",
     "test/javatests/src/org/chromium/net/Criteria.java",
@@ skipping 43 matching lines @@
 
 instrumentation_test_apk("cronet_test_instrumentation_apk") {
   apk_name = "CronetTestInstrumentation"
   apk_under_test = ":cronet_test_apk"
   android_manifest = "test/javatests/AndroidManifest.xml"
 
   deps = [
     ":cronet_api_java",
     ":cronet_impl_all_java",
     ":cronet_javatests",
+    ":cronet_quic_smoke_test_java",
     ":cronet_test_apk_java",
     "//base:base_java",
     "//base:base_java_test_support",
     "//net/android:net_java",
     "//net/android:net_java_test_support",
   ]
   additional_apks = [ "//net/android:net_test_support_apk" ]
 
   data_deps = [
     "//net:test_support",
   ]
 
+  proguard_enabled = true
+
+  proguard_configs = [
+    "test/smoketests/proguard.cfg",
+    "//base/android/proguard/chromium_apk.flags",

[mef, 2016/12/08 23:17:18]

This feels wrong. Why would cronet test depend on chromium apk proguard flags?
Should this be "$target_gen_dir/cronet_impl_native_proguard.cfg" instead?

[kapishnikov, 2016/12/19 19:31:10]

Only the test APK (i.e. not the instrumentation APK) should include the proguard
configs that are included by the embedder apps (cronet_impl_native_proguard.cfg
in this particular case). The instrumentation APK should only include configs
that are needed for the testing purpose. In particular, we would like to
preserve Netty server classes, test support classes and the source file / line
number table for easier debugging.

I changed test/smoketests/proguard.cfg to keep SourceFile & LineNumberTable and
removed the dependency on chromium_apk.flags from the Java Only test. However,
the native tests failing without chromium_apk.flags. I will investigate the
reason.

[kapishnikov, 2016/12/19 23:33:41]

//base/android/proguard/chromium_apk.flags is disabling
"class/merging/horizontal" proguard optimization. Enabling the optimization
causes some static methods be removed. That is why the native tests didn't pass.
I have updated the proguard files and got rid of
//base/android/proguard/chromium_apk.flags.

+  ]
+
   run_findbugs_override = true
 }
 
+android_resources("cronet_java_only_smoke_test_apk_resources") {
+  testonly = true
+  resource_dirs = [ "test/smoketests/res/java_only" ]
+  android_manifest = "test/AndroidManifest.xml"
+}
+
+android_library("cronet_java_only_smoke_test_java") {
+  testonly = true
+  java_files =
+      [ "test/smoketests/src/org/chromium/net/smoke/JavaOnlyEngineTest.java" ] +
+      java_only_smoke_test_common_srcs
+  deps = [
+    ":cronet_api_java",
+    "//third_party/netty4:netty_all_java",
+  ]
+}
+
+android_apk("cronet_java_only_smoke_tests_apk") {
+  testonly = true
+  apk_name = "JavaOnlyEngineSmokeTest"
+  android_manifest = "test/AndroidManifest.xml"
+  java_files = [ "test/src/org/chromium/net/CronetTestApplication.java" ]
+
+  proguard_enabled = true
+  proguard_configs = [
+    "cronet_impl_common_proguard.cfg",
+    "cronet_impl_platform_proguard.cfg",
+  ]
+
+  deps = [
+    ":cronet_api_java",
+    ":cronet_impl_common_java",
+    ":cronet_impl_platform_java",
+    ":cronet_java_only_smoke_test_apk_resources",
+  ]
+  run_findbugs_override = true
+}
+
+instrumentation_test_apk("cronet_java_only_smoke_tests_instrumentation_apk") {
+  apk_name = "JavaOnlyEngineSmokeTestInstrumentation"
+  apk_under_test = ":cronet_java_only_smoke_tests_apk"
+  android_manifest = "test/javatests/AndroidManifest.xml"
+  deps = [
+    ":cronet_java_only_smoke_test_java",
+  ]
+
+  proguard_enabled = true
+
+  proguard_configs = [
+    "test/smoketests/proguard.cfg",
+    "//base/android/proguard/chromium_apk.flags",
+  ]
+  run_findbugs_override = true
+}
+
+android_library("cronet_broken_native_library_smoke_test_java") {
+  testonly = true
+  java_files = [ "test/smoketests/src/org/chromium/net/smoke/BrokenNativeLibraryTest.java" ] + quic_smoke_test_common_srcs
+  deps = [
+    ":cronet_api_java",
+    ":cronet_test_apk_java",
+    "//base:base_java",
+    "//third_party/netty4:netty_all_java",
+  ]
+}
+
+android_apk("cronet_broken_native_library_smoke_tests_apk") {
+  testonly = true
+  apk_name = "BrokenNativeLibrarySmokeTest"
+  android_manifest = "test/AndroidManifest.xml"
+  deps = [
+    ":cronet_api_java",
+    ":cronet_combine_proguard_flags",
+    ":cronet_impl_common_java",
+    ":cronet_impl_platform_java",
+    ":cronet_test_apk_resources",
+  ]
+
+  proguard_enabled = true
+  proguard_configs = [
+    "$target_gen_dir/cronet_impl_native_proguard.cfg",
+    "cronet_impl_common_proguard.cfg",
+    "cronet_impl_platform_proguard.cfg",
+  ]
+
+  run_findbugs_override = true
+}
+
+instrumentation_test_apk(
+    "cronet_broken_native_library_smoke_tests_instrumentation_apk") {
+  apk_name = "BrokenNativeLibrarySmokeTestInstrumentation"
+  apk_under_test = ":cronet_broken_native_library_smoke_tests_apk"
+  android_manifest = "test/javatests/AndroidManifest.xml"
+
+  deps = [
+    ":cronet_broken_native_library_smoke_test_java",
+  ]
+
+  proguard_enabled = true
+
+  proguard_configs = [
+    "test/smoketests/proguard.cfg",
+    "//base/android/proguard/chromium_apk.flags",
+  ]
+
+  run_findbugs_override = true
+}
+
 android_library("cronet_perf_test_apk_java") {
   testonly = true
   java_files =
       [ "test/javaperftests/src/org/chromium/net/CronetPerfTestActivity.java" ]
 
   deps = [
     ":cronet_api_java",
     ":cronet_impl_all_java",
     ":cronet_javatests",
     ":cronet_test_apk_java",
@@ skipping 388 matching lines @@
       ":jar_cronet_impl_native_java_source",
       ":jar_cronet_impl_platform_java_source",
       ":jar_cronet_sample_source",
       ":repackage_extracted_jars",
     ]
     if (current_cpu == "arm" && arm_version == 7) {
       deps += [ ":enforce_no_neon" ]
     }
   }
 }