[ObjC ARC] Converts ios/chrome/browser/passwords:unit_tests to ARC.

ios/chrome/browser/passwords/password_controller_unittest.mm

 // Copyright 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/passwords/password_controller.h"
 
 #import <Foundation/Foundation.h>
 
 #include <memory>
 #include <utility>
 
 #include "base/json/json_reader.h"
 #include "base/mac/bind_objc_block.h"
-#import "base/mac/scoped_nsobject.h"
 #include "base/memory/ptr_util.h"
 #include "base/memory/ref_counted.h"
 #include "base/strings/sys_string_conversions.h"
 #include "base/strings/utf_string_conversions.h"
 #import "base/test/ios/wait_util.h"
 #include "base/values.h"
 #include "components/autofill/core/common/password_form_fill_data.h"
 #include "components/password_manager/core/browser/log_manager.h"
 #include "components/password_manager/core/browser/mock_password_store.h"
 #include "components/password_manager/core/browser/stub_password_manager_client.h"
 #include "components/password_manager/core/common/password_manager_pref_names.h"
 #include "components/prefs/pref_registry_simple.h"
 #include "components/prefs/testing_pref_service.h"
 #import "ios/chrome/browser/autofill/form_input_accessory_view_controller.h"
 #import "ios/chrome/browser/autofill/form_suggestion_controller.h"
 #include "ios/chrome/browser/browser_state/test_chrome_browser_state.h"
 #import "ios/chrome/browser/passwords/js_password_manager.h"
 #import "ios/web/public/web_state/web_state.h"
 #import "ios/web/public/test/web_test_with_web_state.h"
 #import "ios/web/public/test/test_web_state.h"
 #include "testing/gmock/include/gmock/gmock.h"
 #include "testing/gtest/include/gtest/gtest.h"
 #include "testing/gtest_mac.h"
 #import "third_party/ocmock/OCMock/OCMock.h"
 #import "third_party/ocmock/OCMock/OCPartialMockObject.h"
 #include "url/gurl.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 using autofill::PasswordForm;
 using autofill::PasswordFormFillData;
 using testing::Return;
 
 namespace {
 
 class MockWebState : public web::TestWebState {
  public:
   MOCK_CONST_METHOD0(GetBrowserState, web::BrowserState*(void));
 };
@@ skipping 26 matching lines @@
 
   // Methods not important for testing.
   void OnLogRouterAvailabilityChanged(bool router_can_be_used) override {}
   void SetSuspended(bool suspended) override {}
 };
 
 // Creates PasswordController with the given |web_state| and a mock client
 // using the given |store|. If not null, |weak_client| is filled with a
 // non-owning pointer to the created client. The created controller is
 // returned.
-base::scoped_nsobject<PasswordController> CreatePasswordController(
+PasswordController* CreatePasswordController(
     web::WebState* web_state,
     password_manager::PasswordStore* store,
     MockPasswordManagerClient** weak_client) {
   auto client = base::MakeUnique<MockPasswordManagerClient>(store);
   if (weak_client)
     *weak_client = client.get();
-  return base::scoped_nsobject<PasswordController>([[PasswordController alloc]
-         initWithWebState:web_state
-      passwordsUiDelegate:nil
-                   client:std::move(client)]);
+  return [[PasswordController alloc] initWithWebState:web_state
+                                  passwordsUiDelegate:nil
+                                               client:std::move(client)];
 }
 
 }  // namespace
 
 @interface PasswordController (
     Testing)<CRWWebStateObserver, FormSuggestionProvider>
 
 - (void)findPasswordFormsWithCompletionHandler:
     (void (^)(const std::vector<PasswordForm>&))completionHandler;
 
@@ skipping 13 matching lines @@
 @property(readonly) JsPasswordManager* passwordJsManager;
 
 @end
 
 // Real FormSuggestionController is wrapped to register the addition of
 // suggestions.
 @interface PasswordsTestSuggestionController : FormSuggestionController
 
 @property(nonatomic, copy) NSArray* suggestions;
 
-- (void)dealloc;
-
 @end
 
 @implementation PasswordsTestSuggestionController
 
 @synthesize suggestions = _suggestions;
 
 - (void)updateKeyboardWithSuggestions:(NSArray*)suggestions {
   self.suggestions = suggestions;
 }
 
-- (void)dealloc {
-  [_suggestions release];
-  [super dealloc];
-}
 
 @end
 
 class PasswordControllerTest : public web::WebTestWithWebState {
  public:
   PasswordControllerTest()
       : store_(new testing::NiceMock<password_manager::MockPasswordStore>()) {}
 
   ~PasswordControllerTest() override { store_->ShutdownOnUIThread(); }
 
   void SetUp() override {
     web::WebTestWithWebState::SetUp();
     passwordController_ =
         CreatePasswordController(web_state(), store_.get(), nullptr);
     @autoreleasepool {
       // Make sure the temporary array is released after SetUp finishes,
       // otherwise [passwordController_ suggestionProvider] will be retained
       // until PlatformTest teardown, at which point all Chrome objects are
       // already gone and teardown may access invalid memory.
-      suggestionController_.reset([[PasswordsTestSuggestionController alloc]
+      suggestionController_ = [[PasswordsTestSuggestionController alloc]
           initWithWebState:web_state()
-                 providers:@[ [passwordController_ suggestionProvider] ]]);
-      accessoryViewController_.reset([[FormInputAccessoryViewController alloc]
+                 providers:@[ [passwordController_ suggestionProvider] ]];
+      accessoryViewController_ = [[FormInputAccessoryViewController alloc]
           initWithWebState:web_state()
-                 providers:@[ [suggestionController_ accessoryViewProvider] ]]);
+                 providers:@[ [suggestionController_ accessoryViewProvider] ]];
     }
   }
 
  protected:
   // Helper method for PasswordControllerTest.DontFillReadonly. Tries to load
   // |html| and find and fill there a form with hard-coded form data. Returns
   // YES on success, NO otherwise.
   BOOL BasicFormFill(NSString* html);
 
   // Retrieve the current suggestions from suggestionController_ sorted in
@@ skipping 28 matching lines @@
         [OCMockObject partialMockForObject:original_manager];
     __block int failure_count = 0;
     void (^fail_invocation)(NSInvocation*) = ^(NSInvocation* invocation) {
       if (failure_count >= target_failure_count) {
         [failing_manager stop];
         [invocation invokeWithTarget:original_manager];
       } else {
         ++failure_count;
         // Fetches the completion handler from |invocation| and calls it with
         // failure status.
-        void (^completionHandler)(BOOL);
+        __unsafe_unretained void (^completionHandler)(BOOL);

[Eugene But (OOO till 7-30), 2016/12/07 18:21:35]

Should this be __weal?

[stkhapugin, 2016/12/08 10:15:46]

Actually, no - grabbing arguments from NSInvocation is unsafe and memory
semantics do not apply, so ARC enforces __unsafe_unretained. It is assumed that
the argument is properly memory managed when the invocation is valid, which is
the case here as the invocation argument is retrieved during the invocation
dispatch. 

         const NSInteger kArgOffset = 1;
         const NSInteger kCompletionHandlerArgIndex = 4;
         [invocation getArgument:&completionHandler
                         atIndex:(kCompletionHandlerArgIndex + kArgOffset)];
         ASSERT_TRUE(completionHandler);
         completionHandler(NO);
       }
     };
     [[[failing_manager stub] andDo:fail_invocation]
          fillPasswordForm:[OCMArg any]
              withUsername:[OCMArg any]
                  password:[OCMArg any]
         completionHandler:[OCMArg any]];
   }
 
   // SuggestionController for testing.
-  base::scoped_nsobject<PasswordsTestSuggestionController>
-      suggestionController_;
+  PasswordsTestSuggestionController* suggestionController_;
 
   // FormInputAccessoryViewController for testing.
-  base::scoped_nsobject<FormInputAccessoryViewController>
-      accessoryViewController_;
+  FormInputAccessoryViewController* accessoryViewController_;
 
   // PasswordController for testing.
-  base::scoped_nsobject<PasswordController> passwordController_;
+  PasswordController* passwordController_;
 
   scoped_refptr<password_manager::PasswordStore> store_;
 };
 
 struct PasswordFormTestData {
   const char* const page_location;
   const char* const json_string;
   const char* const expected_origin;
   const char* const expected_action;
   const char* const expected_username_element;
@@ skipping 1002 matching lines @@
 // The test case below does not need the heavy fixture from above, but it
 // needs to use MockWebState.
 TEST(PasswordControllerTestSimple, SaveOnNonHTMLLandingPage) {
   TestChromeBrowserState::Builder builder;
   std::unique_ptr<TestChromeBrowserState> browser_state(builder.Build());
   MockWebState web_state;
   ON_CALL(web_state, GetBrowserState())
       .WillByDefault(testing::Return(browser_state.get()));
 
   MockPasswordManagerClient* weak_client = nullptr;
-  base::scoped_nsobject<PasswordController> passwordController =
+  PasswordController* passwordController =
       CreatePasswordController(&web_state, nullptr, &weak_client);
   static_cast<TestingPrefServiceSimple*>(weak_client->GetPrefs())
       ->registry()
       ->RegisterBooleanPref(
           password_manager::prefs::kPasswordManagerSavingEnabled, true);
 
   // Use a mock LogManager to detect that OnPasswordFormsRendered has been
   // called. TODO(crbug.com/598672): this is a hack, we should modularize the
   // code better to allow proper unit-testing.
   MockLogManager log_manager;
   EXPECT_CALL(log_manager, IsLoggingActive()).WillRepeatedly(Return(true));
   EXPECT_CALL(log_manager,
               LogSavePasswordProgress(
                   "Message: \"PasswordManager::OnPasswordFormsRendered\"\n"));
   EXPECT_CALL(log_manager,
               LogSavePasswordProgress(testing::Ne(
                   "Message: \"PasswordManager::OnPasswordFormsRendered\"\n")))
       .Times(testing::AnyNumber());
   EXPECT_CALL(*weak_client, GetLogManager())
       .WillRepeatedly(Return(&log_manager));
 
   web_state.SetContentIsHTML(false);
   web_state.SetCurrentURL(GURL("https://example.com"));
   [passwordController webStateDidLoadPage:&web_state];
 }