Add support for generating PkgInfo for application bundle on iOS.

build/config/ios/rules.gni

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/ios/ios_sdk.gni")
 import("//build/config/mac/base_rules.gni")
 import("//build/config/mac/symbols.gni")
 import("//build/toolchain/toolchain.gni")
 
 # Invokes lipo on multiple arch-specific binaries to create a fat binary.
@@ skipping 402 matching lines @@
 #       default to ios_enable_code_signing if not defined.
 #
 # For more information, see "gn help executable".
 template("ios_app_bundle") {
   _output_name = target_name
   _target_name = target_name
   if (defined(invoker.output_name)) {
     _output_name = invoker.output_name
   }
 
+  # TODO(sdefresne): some target downstream manually pack an PkgInfo, so
+  # allow controlling the generation of the PkgInfo file via an undocumented
+  # parameter until they are fixed.
+  _write_pkg_info = false
+  if (defined(invoker.write_pkg_info)) {
+    _write_pkg_info = invoker.write_pkg_info
+  }
+
+  assert(_write_pkg_info || !_write_pkg_info,
+         "prevents 'Assignment had no effect.' errors")
+
   _arch_executable_source = _target_name + "_arch_executable_sources"
   _arch_executable_target = _target_name + "_arch_executable"
   _lipo_executable_target = _target_name + "_executable"
 
   source_set(_arch_executable_source) {
     forward_variables_from(invoker,
                            "*",
                            [
                              "bundle_deps",
                              "bundle_deps_filter",
@@ skipping 194 matching lines @@
 
       sources = get_target_outputs(":$_generate_info_plist")
       outputs = [
         "{{bundle_root_dir}}/Info.plist",
       ]
       public_deps = [
         ":$_generate_info_plist",
       ]
     }
 
+    if (_write_pkg_info) {
+      _create_pkg_info = target_name + "_pkg_info"
+      action(_create_pkg_info) {
+        forward_variables_from(invoker, [ "testonly" ])
+        script = "//build/config/mac/write_pkg_info.py"
+        sources = get_target_outputs(":$_generate_info_plist")
+        outputs = [
+          "$target_gen_dir/$target_name",

[rohitrao (ping after 24h), 2016/12/09 12:14:42]

Why is the output of this step not a file named PkgInfo?

[sdefresne, 2016/12/09 13:50:19]

$target_gen_dir does not depends on the current target name (only on the path to
the BUILD.gn file containing the target). It means that if two separate target
in the same BUILD.gn file use the ios_app_bundle target, they will both try to
generate the same file named PkgInfo.

If I change the line to "$target_gen_dir/PkfInfo", I get the following error
while running "gn gen":

Two or more targets generate the same output:
  gen/base/PkgInfo

This is can often be fixed by changing one of the target names, or by 
setting an output_name on one of them.

Collisions:
  //base:base_i18n_perftests_pkg_info
  //base:base_perftests_pkg_info
  //base:base_unittests_pkg_info

Since the target _bundle_data_pkg_info rename the file to PkgInfo while copying
to the bundle, there is not really a need to name the file PkgInfo while
creating it. If you really care about that, I can change this to
"$target_gen_dir/$target_name/PkgInfo" though.

[rohitrao (ping after 24h), 2016/12/09 13:51:51]

Nope, it was just unexpected.  Perhaps summarize what you just wrote into a
short comment?

+        ]
+        args = [ "--plist" ] + rebase_path(sources, root_build_dir) +
+               [ "--output" ] + rebase_path(outputs, root_build_dir)
+        deps = [
+          ":$_generate_info_plist",
+        ]
+      }
+
+      _bundle_data_pkg_info = target_name + "_bundle_data_pkg_info"
+      bundle_data(_bundle_data_pkg_info) {
+        forward_variables_from(invoker, [ "testonly" ])
+        sources = get_target_outputs(":$_create_pkg_info")
+        outputs = [
+          "{{bundle_resources_dir}}/PkgInfo",
+        ]
+        public_deps = [
+          ":$_create_pkg_info",
+        ]
+      }
+    }
+
     create_signed_bundle(_target_name) {
       forward_variables_from(invoker,
                              [
                                "bundle_deps",
                                "bundle_deps_filter",
                                "bundle_extension",
                                "data_deps",
                                "deps",
                                "enable_code_signing",
                                "entitlements_path",
                                "entitlements_target",
                                "extra_system_frameworks",
                                "product_type",
                                "public_configs",
                                "public_deps",
                                "testonly",
                                "visibility",
                              ])
 
       output_name = _output_name
       bundle_binary_target = ":$_lipo_executable_target"
       bundle_binary_output = _output_name
 
       if (!defined(bundle_deps)) {
         bundle_deps = []
       }
       bundle_deps += [ ":$_bundle_data_info_plist" ]
+      if (_write_pkg_info) {
+        bundle_deps += [ ":$_bundle_data_pkg_info" ]
+      }
 
       if (use_ios_simulator) {
         if (!defined(data_deps)) {
           data_deps = []
         }
         data_deps += [ "//testing/iossim" ]
       }
 
       if (!defined(product_type)) {
         product_type = "com.apple.product-type.application"
@@ skipping 739 matching lines @@
       "-rpath",
       "-Xlinker",
       "@loader_path/Frameworks",
     ]
   }
 }
 
 set_defaults("ios_xctest_test") {
   configs = default_executable_configs
 }