Instrument setup.exe in the SyzyAsan builds.

chrome/installer/mini_installer/BUILD.gn

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/compiler/compiler.gni")
 import("//build/config/features.gni")
 import("//build/config/ui.gni")
 import("//chrome/process_version_rc_template.gni")
 import("//chrome/test/mini_installer/mini_installer_test.gni")
 import("//third_party/icu/config.gni")
@@ skipping 61 matching lines @@
   ]
   deps = [
     "//base",
     "//base/test:test_support",
     "//testing/gtest",
   ]
 }
 
 # The runtime deps are used to tell create_installer_archive what component
 # DLLs need to be packaged in a component build.
-chrome_runtime_deps = "$root_gen_dir/chrome_component.runtime_deps"
-setup_runtime_deps = "$root_gen_dir/setup.runtime_deps"
+chrome_runtime_deps_path = "$root_gen_dir/chrome_component.runtime_deps"
+setup_runtime_deps_path = "$root_gen_dir/setup.runtime_deps"
+setup_syzygy_runtime_deps_path = "$root_gen_dir/setup_syzygy.runtime_deps"
 
 group("chrome_runtime_deps") {
-  write_runtime_deps = chrome_runtime_deps
+  write_runtime_deps = chrome_runtime_deps_path
   data_deps = [
     "//chrome",
   ]
 }
 
 group("setup_runtime_deps") {
-  write_runtime_deps = setup_runtime_deps
+  write_runtime_deps = setup_runtime_deps_path
   data_deps = [
     "//chrome/installer/setup",
   ]
 }
 
+group("setup_syzygy_runtime_deps") {
+  write_runtime_deps = setup_syzygy_runtime_deps_path
+  deps = [
+    ":setup_runtime_deps",
+  ]
+  data_deps = [
+    "//build/win/syzygy:copy_syzyasan_runtime_binaries",
+  ]
+}
+
 # Generates a mini installer.
 #
-#   out_dir (required)
-#     The output directory out_dir where the mini_installer image should be
+#   output_dir (required)
+#     The output directory where the mini_installer image should be
 #     written.
 #
 #   chrome_dll_file (required)
 #     The path to the version of chrome.dll that should be included in the
 #     installer archive.
 #
 #   chrome_dll_target (required)
 #     The target that generated chrome_dll_file.
 #
-#   deps (required)
+#   setup_exe_file (required)
+#     The path to the version of setup.exe that should be included in the
+#     installer archive.
+#
+#   setup_exe_target (required)
+#     The target that generated setup_exe_file.
+#
+#   deps
 #     Normal meaning.
 template("generate_mini_installer") {
-  chrome_dll_file = invoker.chrome_dll_file
-  chrome_dll_target = invoker.chrome_dll_target
-  output_dir = invoker.out_dir
-
+  forward_variables_from(invoker,
+                         [
+                           "output_dir",
+                           "chrome_dll_file",
+                           "chrome_dll_target",
+                           "setup_exe_file",
+                           "setup_exe_target",
+                           "setup_runtime_deps",
+                         ])
   packed_files_rc_file = "$target_gen_dir/$target_name/packed_files.rc"
   archive_name = target_name + "_archive"
   staging_dir = "$target_gen_dir/$target_name"
 
   action(archive_name) {
+    forward_variables_from(invoker, [ "deps" ])
     script = "//chrome/tools/build/win/create_installer_archive.py"
 
     release_file = "chrome.release"
 
     inputs = [
       "$chrome_dll_file",
+      "$setup_exe_file",
       "$root_out_dir/chrome.exe",
       "$root_out_dir/locales/en-US.pak",
-      "$root_out_dir/setup.exe",
       release_file,
     ]
 
     outputs = [
       # See also chrome.packed.7z conditionally added below.
       "$output_dir/chrome.7z",
       "$output_dir/setup.ex_",
       packed_files_rc_file,
     ]
     args = [
       "--build_dir",
       rebase_path(root_out_dir, root_build_dir),
       "--staging_dir",
       rebase_path(staging_dir, root_build_dir),
       "--input_file",
       rebase_path(release_file, root_build_dir),
       "--resource_file_path",
       rebase_path(packed_files_rc_file, root_build_dir),
       "--target_arch=$current_cpu",
       "--distribution=_google_chrome",
       "--output_dir",
       rebase_path(output_dir, root_build_dir),
       "--chrome_runtime_deps",
-      rebase_path(chrome_runtime_deps, root_build_dir),
+      rebase_path(chrome_runtime_deps_path, root_build_dir),
       "--setup_runtime_deps",
       rebase_path(setup_runtime_deps, root_build_dir),
 
       # Optional arguments to generate diff installer.
       #'--last_chrome_installer=C:/Temp/base',
       #'--setup_exe_format=DIFF',
       #'--diff_algorithm=COURGETTE',
 
       # Optional argument for verbose archiving output.
       #'--verbose',
     ]
 
-    deps = [
+    if (!defined(deps)) {
+      deps = []
+    }
+    deps += [
       ":chrome_runtime_deps",
-      ":setup_runtime_deps",
       "//chrome",
       "//chrome/browser/extensions/default_extensions",
-      "//chrome/installer/setup",
       "//third_party/icu:icudata",
       chrome_dll_target,
+      setup_exe_target,
     ]
 
     if (enable_hidpi) {
       args += [ "--enable_hidpi=1" ]
     }
     if (is_component_build) {
       args += [ "--component_build=1" ]
     } else {
       outputs += [ "$output_dir/chrome.packed.7z" ]
     }
@@ skipping 70 matching lines @@
       ":$archive_name",
       ":lib",
       ":version",
       "//build/config/sanitizers:deps",
       "//build/win:default_exe_manifest",
     ]
   }
 }
 
 generate_mini_installer("mini_installer") {
-  out_dir = root_out_dir
+  output_dir = root_out_dir
   chrome_dll_file = "$root_out_dir/chrome.dll"
   chrome_dll_target = "//chrome:main_dll"
+  setup_exe_file = "$root_out_dir/setup.exe"
+  setup_exe_target = "//chrome/installer/setup"
+  setup_runtime_deps = setup_runtime_deps_path
+  deps = [
+    ":setup_runtime_deps",
+  ]
 }
 
 if (is_syzyasan) {
   generate_mini_installer("mini_installer_syzygy") {
-    out_dir = "$root_out_dir/syzygy/"
+    output_dir = "$root_out_dir/syzygy/"
     chrome_dll_file = "$root_out_dir/syzygy/chrome.dll"
     chrome_dll_target = "//chrome/tools/build/win/syzygy:chrome_dll_syzygy"
+    setup_exe_file = "$root_out_dir/syzygy/setup.exe"
+    setup_exe_target = "//chrome/tools/build/win/syzygy:setup_syzygy"
+    setup_runtime_deps = setup_syzygy_runtime_deps_path
+    deps = [
+      ":setup_syzygy_runtime_deps",
+    ]
   }
 }
 
 # next_version_mini_installer.exe can't be generated in an x86 Debug component
 # build because it requires too much memory.
 if (!(is_component_build && is_debug && target_cpu == "x86")) {
   action("next_version_mini_installer") {
     script = "generate_next_version_mini_installer.py"
     testonly = true
     inputs = [
       "$root_out_dir/alternate_version_generator.exe",
       "$root_out_dir/mini_installer.exe",
     ]
     outputs = [
       "$root_out_dir/$target_name.exe",
     ]
     args = [
       "--out",
       "$target_name.exe",
     ]
     deps = [
       ":mini_installer",
       "//chrome/installer/test:alternate_version_generator",
     ]
   }
 }