Work around an AppKit bug that can crash Chrome after using the client certificate prompt.

chrome/browser/ui/cocoa/ssl_client_certificate_selector_cocoa.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/ssl_client_certificate_selector_cocoa.h"
 
 #import <SecurityInterface/SFChooseIdentityPanel.h>
 #include <stddef.h>
 
 #include <utility>
@@ skipping 87 matching lines @@
   SSLClientCertificateSelectorCocoa* selector =
       [[SSLClientCertificateSelectorCocoa alloc]
           initWithBrowserContext:contents->GetBrowserContext()
                  certRequestInfo:cert_request_info
                         delegate:std::move(delegate)];
   [selector displayForWebContents:contents];
 }
 
 }  // namespace chrome
 
+namespace {
+
+// These ClearTableViewDataSources... functions help work around a bug in macOS
+// 10.12 where SFChooseIdentityPanel leaks a window and some views, including
+// an NSTableView. Future events may make cause the table view to query its
+// dataSource, which will have been deallocated.
+//
+// NSTableView.dataSource becomes a zeroing weak reference starting in 10.11,
+// so this workaround can be removed once we're on the 10.11 SDK.
+//
+// See https://crbug.com/653093 and rdar://29409207 for more information.
+
+#if !defined(MAC_OS_X_VERSION_10_11) || \
+    MAC_OS_X_VERSION_MAX_ALLOWED < MAC_OS_X_VERSION_10_11
+
+void ClearTableViewDataSources(NSView* view) {
+  if (auto table_view = base::mac::ObjCCast<NSTableView>(view)) {
+    table_view.dataSource = nil;
+  } else {
+    for (NSView* subview in view.subviews) {
+      ClearTableViewDataSources(subview);
+    }
+  }
+}
+
+void ClearTableViewDataSourcesIfWindowStillExists(NSWindow* leaked_window) {
+  for (NSWindow* window in [NSApp windows]) {
+    // If the window is still in the window list...
+    if (window == leaked_window) {
+      // ...search it for table views.
+      ClearTableViewDataSources(window.contentView);
+      break;
+    }
+  }
+}
+
+void ClearTableViewDataSourcesIfNeeded(NSWindow* leaked_window) {
+  // Let the autorelease pool drain before deciding if the window was leaked.
+  base::ThreadTaskRunnerHandle::Get()->PostTask(
+      FROM_HERE, base::Bind(ClearTableViewDataSourcesIfWindowStillExists,
+                            base::Unretained(leaked_window)));
+}
+
+#else
+
+void ClearTableViewDataSourcesIfNeeded(NSWindow*) {}
+
+#endif  // MAC_OS_X_VERSION_10_11
+
+}  // namespace
+
 @implementation SSLClientCertificateSelectorCocoa
 
 - (id)initWithBrowserContext:(const content::BrowserContext*)browserContext
              certRequestInfo:(net::SSLCertRequestInfo*)certRequestInfo
                     delegate:
                         (std::unique_ptr<content::ClientCertificateDelegate>)
                             delegate {
   DCHECK(browserContext);
   DCHECK(certRequestInfo);
   if ((self = [super init])) {
     observer_.reset(new SSLClientAuthObserverCocoaBridge(
         browserContext, certRequestInfo, std::move(delegate), self));
   }
   return self;
 }
 
-- (void)sheetDidEnd:(NSWindow*)parent
+- (void)sheetDidEnd:(NSWindow*)sheet
          returnCode:(NSInteger)returnCode
             context:(void*)context {
   net::X509Certificate* cert = NULL;
   if (returnCode == NSFileHandlingPanelOKButton) {
     CFRange range = CFRangeMake(0, CFArrayGetCount(identities_));
     CFIndex index =
         CFArrayGetFirstIndexOfValue(identities_, range, [panel_ identity]);
     if (index != -1)
       cert = certificates_[index].get();
     else
       NOTREACHED();
   }
 
+  // See comment at definition; this works around a 10.12 bug.
+  ClearTableViewDataSourcesIfNeeded(sheet);
+
   if (!closePending_) {
     // If |closePending_| is already set, |closeSheetWithAnimation:| was called
     // already to cancel the selection rather than continue with no
     // certificate. Otherwise, tell the backend which identity (or none) the
     // user selected.
     userResponded_ = YES;
     observer_->CertificateSelected(cert);
 
     constrainedWindow_->CloseWebContentsModalDialog();
   }
@@ skipping 122 matching lines @@
 }
 
 - (void)onConstrainedWindowClosed {
   observer_->StopObserving();
   panel_.reset();
   constrainedWindow_.reset();
   [self release];
 }
 
 @end