Save favicon during reading list distillation

ios/chrome/browser/dom_distiller/favicon_web_state_dispatcher_impl.mm

Index: ios/chrome/browser/dom_distiller/favicon_web_state_dispatcher_impl.mm
diff --git a/ios/chrome/browser/dom_distiller/favicon_web_state_dispatcher_impl.mm b/ios/chrome/browser/dom_distiller/favicon_web_state_dispatcher_impl.mm
new file mode 100644
index 0000000000000000000000000000000000000000..e74431d1131a5fd217ba6be43f62e666d3eda330
--- /dev/null
+++ b/ios/chrome/browser/dom_distiller/favicon_web_state_dispatcher_impl.mm
@@ -0,0 +1,77 @@
+// Copyright 2016 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#include "ios/chrome/browser/dom_distiller/favicon_web_state_dispatcher_impl.h"
+
+#include "components/favicon/ios/web_favicon_driver.h"
+#include "components/keyed_service/core/service_access_type.h"
+#include "ios/chrome/browser/bookmarks/bookmark_model_factory.h"
+#include "ios/chrome/browser/browser_state/chrome_browser_state.h"
+#include "ios/chrome/browser/favicon/favicon_service_factory.h"
+#include "ios/chrome/browser/history/history_service_factory.h"
+#import "ios/web/public/web_state/web_state.h"
+
+namespace {
+// Default delay to download the favicon when the WebState is handed back.
+const int64_t kDefaultDelayFaviconSecond = 10;
+}
+
+namespace dom_distiller {
+
+FaviconWebStateDispatcherImpl::FaviconWebStateDispatcherImpl(
+    web::BrowserState* browser_state,
+    int64_t keep_alive_second)
+    : FaviconWebStateDispatcher(),
+      browser_state_(browser_state),
+      keep_alive_second_(keep_alive_second),
+      weak_ptr_factory_(this) {
+  if (keep_alive_second_ < 0)
+    keep_alive_second_ = kDefaultDelayFaviconSecond;
+}
+
+FaviconWebStateDispatcherImpl::~FaviconWebStateDispatcherImpl() {}
+
+web::WebState* FaviconWebStateDispatcherImpl::RequestWebState() {
+  const web::WebState::CreateParams web_state_create_params(browser_state_);
+  std::unique_ptr<web::WebState> web_state_unique =
+      web::WebState::Create(web_state_create_params);
+  web::WebState* web_state = web_state_unique.get();
+
+  web_states_.push_back(std::move(web_state_unique));
+
+  ios::ChromeBrowserState* original_browser_state =
+      ios::ChromeBrowserState::FromBrowserState(browser_state_);
+
+  favicon::WebFaviconDriver::CreateForWebState(
+      web_state,
+      ios::FaviconServiceFactory::GetForBrowserState(
+          original_browser_state, ServiceAccessType::EXPLICIT_ACCESS),
+      ios::HistoryServiceFactory::GetForBrowserState(
+          original_browser_state, ServiceAccessType::EXPLICIT_ACCESS),
+      ios::BookmarkModelFactory::GetForBrowserState(original_browser_state));
+
+  return web_state;
+}
+
+void FaviconWebStateDispatcherImpl::ReturnWebState(web::WebState* web_state) {
+  base::WeakPtr<FaviconWebStateDispatcherImpl> weak_this =
+      weak_ptr_factory_.GetWeakPtr();
+  dispatch_after(
+      dispatch_time(DISPATCH_TIME_NOW, keep_alive_second_ * NSEC_PER_SEC),
+      dispatch_get_main_queue(), ^{
+        FaviconWebStateDispatcherImpl* web_state_dispatcher = weak_this.get();
+        if (web_state_dispatcher) {
+          auto it = find_if(
+              web_state_dispatcher->web_states_.begin(),
+              web_state_dispatcher->web_states_.end(),
+              [web_state](std::unique_ptr<web::WebState>& unique_web_state) {
+                return unique_web_state.get() == web_state;
+              });
+          if (it != web_state_dispatcher->web_states_.end())
+            web_state_dispatcher->web_states_.erase(it);
+        }
+      });
+}
+
+}  // namespace dom_distiller