Enable precompiled headers for Blink on Windows.

third_party/WebKit/Source/platform/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/features.gni")
 import("//build/config/ui.gni")
 import("//testing/libfuzzer/fuzzer_test.gni")
 import("//testing/test.gni")
 import("//third_party/WebKit/public/public_features.gni")
 import("//third_party/WebKit/Source/build/scripts/scripts.gni")
@@ skipping 182 matching lines @@
   public_deps = [
     ":blink_common",
     ":character_data",
     ":color_data",
     ":font_family_names",
     ":http_names",
     ":runtime_enabled_features",
   ]
 }
 
+import("//build/config/pch.gni")
+
+config("blink_platform_pch") {
+  if (!disable_precompiled_headers) {
+    if (is_win) {
+      # This is a string rather than a file GN knows about. It has to match
+      # exactly what's in the /FI flag below, and what might appear in the
+      # source code in quotes for an #include directive.
+      precompiled_header =
+          rebase_path("win/Precompile-platform.h", root_build_dir)
+
+      # This is a file that GN will compile with the above header. It will be
+      # implicitly added to the sources (potentially multiple times, with one
+      # variant for each language used in the target).
+      precompiled_source =
+          "//third_party/WebKit/Source/platform/win/Precompile-platform.cpp"
+
+      # Force include the header.
+      cflags = [ "/FI$precompiled_header" ]
+
+      # Disable warning for "this file was empty after preprocessing". This
+      # error is generated only in C mode for ANSI compatibility. It conflicts
+      # with precompiled headers since the source file that's "compiled" for
+      # making the precompiled header is empty.
+      #
+      # This error doesn't happen every time. In VS2013, it seems if the .pch
+      # file doesn't exist, no error will be generated (probably MS tested this
+      # case but forgot the other one?). To reproduce this error, do a build,
+      # then delete the precompile.c.obj file, then build again.
+      cflags_c = [ "/wd4206" ]
+    }
+  }
+}
+
 component("platform") {
   visibility = []  # Allow re-assignment of list.
   visibility = [
     "//third_party/WebKit/*",
     "//url/mojo:url_mojom_origin_blink_cpp_sources",
     "//url/mojo:url_mojom_gurl_blink_cpp_sources",
   ]
   output_name = "blink_platform"
 
   sources = [
@@ skipping 1159 matching lines @@
   # Add in the generated files.
   sources += get_target_outputs(":character_data") +
              get_target_outputs(":color_data") +
              get_target_outputs(":font_family_names") +
              get_target_outputs(":http_names") +
              get_target_outputs(":runtime_enabled_features")
 
   configs += [
     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
     "//build/config/compiler:no_size_t_to_int_warning",
+    ":blink_platform_pch",
     "//third_party/WebKit/Source:config",
     "//third_party/WebKit/Source:non_test_config",
   ]
 
   defines = [
     "BLINK_PLATFORM_IMPLEMENTATION=1",
     "INSIDE_BLINK",
   ]
 
   include_dirs = [
@@ skipping 191 matching lines @@
     "testing/UnitTestHelpers.h",
     "testing/WebLayerTreeViewImplForTesting.cpp",
     "testing/WebLayerTreeViewImplForTesting.h",
     "testing/weburl_loader_mock.cc",
     "testing/weburl_loader_mock.h",
     "testing/weburl_loader_mock_factory_impl.cc",
     "testing/weburl_loader_mock_factory_impl.h",
   ]
 
   configs += [
+    ":blink_platform_pch",
     "//third_party/WebKit/Source:config",
     "//third_party/WebKit/Source:inside_blink",
     "//third_party/WebKit/Source:non_test_config",
   ]
 
   public_deps = [
     ":platform",
     "//cc",
     "//cc:test_support",
     "//cc/blink",
@@ skipping 184 matching lines @@
     sources += [ "scroll/ScrollAnimatorTest.cpp" ]
   }
 
   if (use_default_render_theme) {
     sources += [ "scroll/ScrollbarThemeAuraTest.cpp" ]
   }
 
   sources += [ "testing/RunAllTests.cpp" ]
 
   configs += [
+    ":blink_platform_pch",
     "//third_party/WebKit/Source/wtf:wtf_config",
     "//third_party/WebKit/Source:config",
   ]
 
   deps = [
     ":blink_common",
     ":platform",
     ":test_support",
     "//base",
     "//base/test:test_support",
@@ skipping 50 matching lines @@
 test("blink_platform_perftests") {
   sources = [
     "scheduler/base/task_queue_manager_delegate_for_test.cc",
     "scheduler/base/task_queue_manager_delegate_for_test.h",
     "scheduler/base/task_queue_manager_perftest.cc",
   ]
 
   configs += [
     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
     "//build/config/compiler:no_size_t_to_int_warning",
+    "//third_party/WebKit/Source:blink_pch",

[Nico, 2016/11/21 15:42:25]

why blink_pch instead of blink_platform_pch?

[sof, 2016/11/21 19:24:58]

The sources aren't exercising Blink platform APIs much (=> Oilpan), but I don't
think it is merited to use precompiled headers for this small set. Removed.

     "//third_party/WebKit/Source/wtf:wtf_config",
     "//third_party/WebKit/Source:config",
   ]
 
   deps = [
     ":blink_common",
     ":platform",
     "//base",
     "//base/test:test_support",
     "//base/test:test_support_perf",
@@ skipping 138 matching lines @@
     "graphics/ImageDecodingStoreTest.cpp",
     "graphics/ImageFrameGeneratorTest.cpp",
     "graphics/ImageLayerChromiumTest.cpp",
     "graphics/gpu/DrawingBufferSoftwareRenderingTest.cpp",
     "graphics/test/FakeGLES2Interface.h",
     "graphics/test/FakeWebGraphicsContext3DProvider.h",
     "graphics/test/MockImageDecoder.h",
   ]
 
   configs += [
+    ":blink_platform_pch",
     "//third_party/WebKit/Source:config",
     "//third_party/WebKit/Source:inside_blink",
   ]
 
   deps = [
     ":test_support",
     "//cc/surfaces:surface_id",
     "//testing/gmock",
     "//testing/gtest",
   ]
 }