[Mac] Implement frame.[color|inactiveColor].

chrome/browser/ui/cocoa/apps/native_app_window_cocoa.mm

 // Copyright 2013 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "chrome/browser/ui/cocoa/apps/native_app_window_cocoa.h"
 
 #include "apps/app_shim/extension_app_shim_handler_mac.h"
 #include "base/command_line.h"
 #include "base/mac/mac_util.h"
 #include "base/strings/sys_string_conversions.h"
 #include "chrome/browser/profiles/profile.h"
 #include "chrome/browser/ui/cocoa/browser_window_utils.h"
 #import "chrome/browser/ui/cocoa/chrome_event_processing_window.h"
 #include "chrome/browser/ui/cocoa/extensions/extension_keybinding_registry_cocoa.h"
 #include "chrome/browser/ui/cocoa/extensions/extension_view_mac.h"
 #import "chrome/browser/ui/cocoa/nsview_additions.h"
 #include "chrome/common/chrome_switches.h"
 #include "content/public/browser/native_web_keyboard_event.h"
 #include "content/public/browser/render_widget_host_view.h"
 #include "content/public/browser/web_contents.h"
 #include "content/public/browser/web_contents_view.h"
 #include "extensions/common/extension.h"
+#include "skia/ext/skia_utils_mac.h"
 #include "third_party/skia/include/core/SkRegion.h"
 #include "ui/gfx/skia_util.h"
 
 // NOTE: State Before Update.
 //
 // Internal state, such as |is_maximized_|, must be set before the window
 // state is changed so that it is accurate when e.g. a resize results in a call
 // to |OnNativeWindowChanged|.
 
 // NOTE: Maximize and Zoom.
@@ skipping 180 matching lines @@
 - (CGFloat)roundedCornerRadius;
 @end
 
 // TODO(jamescook): Should these be AppNSWindow to match apps::AppWindow?
 // http://crbug.com/344082
 @interface ShellNSWindow : ChromeEventProcessingWindow
 @end
 @implementation ShellNSWindow
 @end
 
-@interface ShellCustomFrameNSWindow : ShellNSWindow
+@interface ShellCustomFrameNSWindow : ShellNSWindow {
+ @private
+  base::scoped_nsobject<NSColor> color_;
+  base::scoped_nsobject<NSColor> inactiveColor_;
+}
 
 - (void)drawCustomFrameRect:(NSRect)rect forView:(NSView*)view;
+- (void)setColor:(NSColor*)color
+   inactiveColor:(NSColor*)inactiveColor;

[tapted, 2014/04/29 00:43:29]

nit: indent should be minimum 4 spaces (even if it means colons don't align)

[jackhou1, 2014/04/29 02:57:50]

Done.

 
 @end
 
 @implementation ShellCustomFrameNSWindow
 
 - (void)drawCustomFrameRect:(NSRect)rect forView:(NSView*)view {
   [[NSBezierPath bezierPathWithRect:rect] addClip];
   [[NSColor clearColor] set];
   NSRectFill(rect);
 
   // Set up our clip.
   CGFloat cornerRadius = 4.0;
   if ([view respondsToSelector:@selector(roundedCornerRadius)])
     cornerRadius = [view roundedCornerRadius];
   [[NSBezierPath bezierPathWithRoundedRect:[view bounds]
                                    xRadius:cornerRadius
                                    yRadius:cornerRadius] addClip];
-  [[NSColor whiteColor] set];
+  if ([self isMainWindow] || [self isKeyWindow])
+    [color_ set];
+  else
+    [inactiveColor_ set];
   NSRectFill(rect);

[tapted, 2014/04/29 00:43:29]

I think ShellCustomFrameNSWindow is still used when has_frame == true and
has_frame_color == false, in which case |color_| and |inactiveColor_| will still
be `nil`. It won't crash here... but I think it will draw a rectangle with the
clearColor set above when [nil foo] becomes a no-op.

[jackhou1, 2014/04/29 02:57:50]

Around line 330, where we choose the subclass of NSWindow.
ShellCustomFrameNSWindow is only used when there is a frame color. ShellNSWindow
is used for native frame, and ShellFramelessNSWindow for no frame.

 }
 
+- (void)setColor:(NSColor*)color
+   inactiveColor:(NSColor*)inactiveColor {

[tapted, 2014/04/29 00:43:29]

nit: indent 1 more space

[jackhou1, 2014/04/29 02:57:50]

Done.

+  color_.reset([color retain]);
+  inactiveColor_.reset([inactiveColor retain]);
+}
+
 @end
 
 @interface ShellFramelessNSWindow : ShellCustomFrameNSWindow
-
 @end
 
 @implementation ShellFramelessNSWindow
 
 + (NSRect)frameRectForContentRect:(NSRect)contentRect
                         styleMask:(NSUInteger)mask {
   return contentRect;
 }
 
 + (NSRect)contentRectForFrameRect:(NSRect)frameRect
@@ skipping 35 matching lines @@
     const AppWindow::CreateParams& params)
     : app_window_(app_window),
       has_frame_(params.frame == AppWindow::FRAME_CHROME),
       is_hidden_(false),
       is_hidden_with_app_(false),
       is_maximized_(false),
       is_fullscreen_(false),
       is_resizable_(params.resizable),
       shows_resize_controls_(true),
       shows_fullscreen_controls_(true),
+      has_frame_color_(params.has_frame_color),
+      active_frame_color_(params.active_frame_color),
+      inactive_frame_color_(params.inactive_frame_color),
       attention_request_id_(0) {
   Observe(web_contents());
 
   base::scoped_nsobject<NSWindow> window;
   Class window_class;
   if (has_frame_) {
-    bool should_use_native_frame =
-        CommandLine::ForCurrentProcess()->HasSwitch(
-            switches::kAppsUseNativeFrame);
-    window_class = should_use_native_frame ?
-        [ShellNSWindow class] : [ShellCustomFrameNSWindow class];
+    window_class = has_frame_color_ ?
+        [ShellCustomFrameNSWindow class] : [ShellNSWindow class];

[tapted, 2014/04/29 00:43:29]

Does this mean any windows that are frame:true will be auto-upgraded to Native
(gray) borders? (is that a regression? i.e. should they stay white?)

[jackhou1, 2014/04/29 02:57:50]

Nope, native frames will become the default.

   } else {
     window_class = [ShellFramelessNSWindow class];

[tapted, 2014/04/29 00:43:29]

note I think this will also call drawCustomFrameRect

[jackhou1, 2014/04/29 02:57:50]

Changed ShellFramelessNSWindow to subclass ShellNSWindow.

   }
 
   // Estimate the initial bounds of the window. Once the frame insets are known,
   // the window bounds and constraints can be set precisely.
   NSRect cocoa_bounds = GfxToCocoaBounds(
       params.GetInitialWindowBounds(gfx::Insets()));
   window.reset([[window_class alloc]
       initWithContentRect:cocoa_bounds
                 styleMask:GetWindowStyleMask()
                   backing:NSBackingStoreBuffered
                     defer:NO]);
   [window setTitle:base::SysUTF8ToNSString(extension()->name())];
   [[window contentView] cr_setWantsLayer:YES];
+  if (has_frame_ && has_frame_color_) {
+    [static_cast<ShellCustomFrameNSWindow*>(window)

[tapted, 2014/04/29 00:43:29]

nit: use base::mac::ObjCCastStrict for objective C objects (it's basically a
static_cast that's checked in debug builds).

[jackhou1, 2014/04/29 02:57:50]

Done.

+             setColor:gfx::SkColorToSRGBNSColor(active_frame_color_)
+        inactiveColor:gfx::SkColorToSRGBNSColor(inactive_frame_color_)];
+  }
 
   if (base::mac::IsOSSnowLeopard() &&
       [window respondsToSelector:@selector(setBottomCornerRounded:)])
     [window setBottomCornerRounded:NO];
 
   if (params.always_on_top)
     [window setLevel:AlwaysOnTopWindowLevel()];
   InitCollectionBehavior(window);
 
   window_controller_.reset(
@@ skipping 28 matching lines @@
       window,
       extensions::ExtensionKeybindingRegistry::PLATFORM_APPS_ONLY,
       NULL));
 }
 
 NSUInteger NativeAppWindowCocoa::GetWindowStyleMask() const {
   NSUInteger style_mask = NSTitledWindowMask | NSClosableWindowMask |
                           NSMiniaturizableWindowMask;
   if (shows_resize_controls_)
     style_mask |= NSResizableWindowMask;
-  if (!has_frame_ ||
-      !CommandLine::ForCurrentProcess()->HasSwitch(
-          switches::kAppsUseNativeFrame)) {
+  if (!has_frame_)
     style_mask |= NSTexturedBackgroundWindowMask;
-  }
   return style_mask;
 }
 
 void NativeAppWindowCocoa::InstallView() {
   NSView* view = web_contents()->GetView()->GetNativeView();
   if (has_frame_) {
     [view setFrame:[[window() contentView] bounds]];
     [[window() contentView] addSubview:view];
     if (!shows_fullscreen_controls_)
       [[window() standardWindowButton:NSWindowZoomButton] setEnabled:NO];
@@ skipping 324 matching lines @@
 bool NativeAppWindowCocoa::IsFrameless() const {
   return !has_frame_;
 }
 
 bool NativeAppWindowCocoa::HasFrameColor() const {
   // TODO(benwells): Implement this.
   return false;
 }
 
 SkColor NativeAppWindowCocoa::ActiveFrameColor() const {
-  // TODO(benwells): Implement this.
-  return SkColor();
+  return active_frame_color_;
 }
 
 SkColor NativeAppWindowCocoa::InactiveFrameColor() const {
-  // TODO(benwells): Implement this.
-  return SkColor();
+  return inactive_frame_color_;
 }
 
 gfx::Insets NativeAppWindowCocoa::GetFrameInsets() const {
   if (!has_frame_)
     return gfx::Insets();
 
   // Flip the coordinates based on the main screen.
   NSInteger screen_height =
       NSHeight([[[NSScreen screens] objectAtIndex:0] frame]);
 
@@ skipping 196 matching lines @@
 }
 
 void NativeAppWindowCocoa::UpdateRestoredBounds() {
   if (IsRestored(*this))
     restored_bounds_ = [window() frame];
 }
 
 void NativeAppWindowCocoa::HideWithoutMarkingHidden() {
   [window() orderOut:window_controller_];
 }