Convert NaCl renderer-browser messages to mojo.

components/nacl/common/BUILD.gn

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/features.gni")
 import("//mojo/public/tools/bindings/mojom.gni")
 
 if (enable_nacl) {
   # This is separate so it can be used by ../broker:nacl64.
   static_library("minimal") {
     sources = [
       "nacl_cmd_line.cc",
       "nacl_cmd_line.h",
       "nacl_constants.cc",
       "nacl_constants.h",
       "nacl_messages.cc",
       "nacl_messages.h",
       "nacl_process_type.h",
       "nacl_sandbox_type.h",
       "nacl_service.cc",
       "nacl_service.h",
       "nacl_types.cc",
       "nacl_types.h",
       "nacl_types_param_traits.cc",
       "nacl_types_param_traits.h",
+      "pnacl_types.cc",
+      "pnacl_types.h",
     ]
 
     public_deps = [
       ":minimal_content_dummy",
       ":switches",
     ]
 
     deps = [
       ":nacl_error_code",
       "//base",
       "//base:base_static",
       "//content/public/common:service_names",
       "//ipc",
       "//ipc:mojom",
       "//mojo/edk/system",
       "//services/service_manager/public/cpp",
+      "//url/ipc:url_ipc",
     ]
   }
 
   # This exists just to make 'gn check' happy with :minimal.  It can't
   # depend on //content/public/common or anything like that, because that
   # would bring in lots more than counts as "minimal" (stuff that should
   # not be in the nacl64.exe build).
   source_set("minimal_content_dummy") {
     check_includes = false
     sources = [
       "//content/public/common/content_descriptors.h",
       "//content/public/common/content_switches.h",
       "//content/public/common/mojo_channel_switches.h",
       "//content/public/common/process_type.h",
       "//content/public/common/sandbox_type.h",
     ]
 
     # Deps required by the above headers.
     deps = [
       "//media:media_features",
     ]
   }
 
   static_library("common") {
     sources = [
-      "nacl_host_messages.cc",
-      "nacl_host_messages.h",
       "nacl_nonsfi_util.cc",
       "nacl_nonsfi_util.h",
-      "pnacl_types.cc",
-      "pnacl_types.h",
     ]
 
     public_deps = [
       ":minimal",
       ":mojo_bindings",
       ":switches",
     ]
 
     deps = [
       "//base",
@@ skipping 26 matching lines @@
   source_set("nacl_error_code") {
     sources = [
       "//native_client/src/trusted/service_runtime/nacl_error_code.h",
     ]
   }
 
   mojom("mojo_bindings") {
     sources = [
       "nacl.mojom",
     ]
+    public_deps = [
+      "//mojo/common:common_custom_types",
+      "//url/mojo:url_mojom_gurl",
+    ]
   }
 }
 
 # Depending on this allows targets to unconditionally include
 # nacl_process_type.h without testing whether nacl is enabled.
 source_set("process_type") {
   public = [
     "nacl_process_type.h",
   ]
 
   deps = [
     "//content/public/common",
   ]
 }
 
 static_library("switches") {
   sources = [
     "nacl_switches.cc",
     "nacl_switches.h",
   ]
 }