CC Animation: Make cc/animation an independent GN component.

cc/cc.gni

Index: cc/cc.gni
diff --git a/cc/cc.gni b/cc/cc.gni
new file mode 100644
index 0000000000000000000000000000000000000000..945ab75997713df1a9ad05beb7c93ff054a8aa87
--- /dev/null
+++ b/cc/cc.gni
@@ -0,0 +1,33 @@
+# Copyright 2016 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+cc_remove_configs = []
+cc_add_configs = []
+
+if (!is_debug && (is_win || is_android)) {
+  cc_remove_configs += [ "//build/config/compiler:default_optimization" ]
+  cc_add_configs += [ "//build/config/compiler:optimize_max" ]
+}
+
+template("cc_source_set") {
+  source_set(target_name) {
+    forward_variables_from(invoker, "*", [ "configs" ])
+    if (defined(invoker.configs)) {
+      configs += invoker.configs
+    }
+    configs -= cc_remove_configs
+    configs += cc_add_configs
+  }
+}
+
+template("cc_component") {
+  component(target_name) {
+    forward_variables_from(invoker, "*", [ "configs" ])
+    if (defined(invoker.configs)) {
+      configs += invoker.configs
+    }
+    configs -= cc_remove_configs
+    configs += cc_add_configs
+  }
+}