Mus: Move InProcessCommandBuffer and GLInProcessContext to gpu/ipc

gpu/ipc/BUILD.gn

Index: gpu/ipc/BUILD.gn
diff --git a/gpu/ipc/BUILD.gn b/gpu/ipc/BUILD.gn
new file mode 100644
index 0000000000000000000000000000000000000000..477ebc14edc453d1e8b7896ec5928b10e3dc7986
--- /dev/null
+++ b/gpu/ipc/BUILD.gn
@@ -0,0 +1,60 @@
+# Copyright 2016 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//build/config/ui.gni")
+
+group("command_buffer") {
+  if (is_component_build) {
+    public_deps = [
+      "//gpu",
+    ]
+  } else {
+    public_deps = [
+      ":command_buffer_sources",
+    ]
+  }
+}
+
+source_set("command_buffer_sources") {
+  visibility = [ "//gpu/*" ]
+  sources = [
+    "in_process_command_buffer.cc",
+    "in_process_command_buffer.h",
+  ]
+
+  configs += [ "//gpu:gpu_implementation" ]
+
+  public_deps = [
+    "//base",
+    "//gpu/command_buffer/client:client_sources",
+    "//gpu/command_buffer/common:common_sources",
+    "//gpu/command_buffer/service:service_sources",
+    "//gpu/config:config_sources",
+    "//ui/gfx",
+    "//ui/gl",
+    "//ui/gl/init",
+  ]
+}
+
+component("gl_in_process_context") {
+  sources = [
+    "gl_in_process_context.cc",
+    "gl_in_process_context.h",
+    "gl_in_process_context_export.h",
+  ]
+
+  defines = [ "GL_IN_PROCESS_CONTEXT_IMPLEMENTATION" ]
+
+  public_deps = [
+    ":command_buffer",
+    "//base",
+    "//base/third_party/dynamic_annotations",
+    "//gpu",
+    "//gpu/command_buffer/client:gles2_implementation",
+    "//gpu/command_buffer/common:gles2_utils",
+    "//gpu/ipc:command_buffer",
+    "//ui/gfx/geometry",
+    "//ui/gl",
+  ]
+}