[Mac/GN] Re-do framework packaging to fix framework versioning.

build/config/mac/rules.gni

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/mac/base_rules.gni")
 
 # Generates Info.plist files for Mac apps and frameworks.
 #
 # Arguments
 #
@@ skipping 125 matching lines @@
 #     output_name:
 #         (optional) string, name of the generated framework without the
 #         .framework suffix. If omitted, defaults to target_name.
 #
 #     framework_version:
 #         (optional) string, version of the framework. Typically this is a
 #         single letter, like "A". If omitted, the Versions/ subdirectory
 #         structure will not be created, and build output will go directly
 #         into the framework subdirectory.
 #
+#     framework_contents:
+#         (optional) list of string, top-level items in the framework. For
+#         frameworks with a framework_version, this is the list of symlinks to
+#         create in the .framework directory that link into Versions/Current/.
+#
 #     extra_substitutions:
 #         (optional) string array, 'key=value' pairs for extra fields which are
 #         specified in a source Info.plist template.
 #
 # This template provides two targets for the resulting framework bundle. The
 # link-time behavior varies depending on which of the two targets below is
 # added as a dependency:
 #   - $target_name only adds a build-time dependency. Targets that depend on
 #     it will not link against the framework.
 #   - $target_name+link adds a build-time and link-time dependency. Targets
@@ skipping 53 matching lines @@
 # Note that the framework is still copied to the app's bundle, but dyld will
 # load this library when the app is launched because it uses the "+link"
 # target as a dependency. This also requires that the framework set its
 # install_name so that dyld can locate it.
 #
 # See "gn help shared_library" for more information on arguments supported
 # by shared library target.
 template("mac_framework_bundle") {
   assert(defined(invoker.deps),
          "Dependencies must be specified for $target_name")
+  assert(!defined(invoker.framework_contents) ||
+             defined(invoker.framework_version),
+         "framework_contents requres a versioned framework")
 
   _info_plist_target = target_name + "_info_plist"
 
   mac_info_plist(_info_plist_target) {
     executable_name = target_name
     if (defined(invoker.output_name)) {
       executable_name = invoker.output_name
     }
     forward_variables_from(invoker,
                            [
@@ skipping 16 matching lines @@
       ":$_info_plist_target",
     ]
   }
 
   _target_name = target_name
   _output_name = target_name
   if (defined(invoker.output_name)) {
     _output_name = invoker.output_name
   }
 
-  # If the framework is unversioned, the final _target_name will be the
-  # create_bundle(_framework_target), otherwise an action with the name
-  # _target_name will depends on the the create_bundle() in order to prepare
-  # the versioned directory structure.
+  # Create a file to track the build dependency on the framework_version and
+  # framework_contents variables.
+  _framework_toc = []
+  if (defined(invoker.framework_version)) {
+    _framework_toc += [
+      "Version=" + invoker.framework_version,
+      _output_name,
+    ]
+    _framework_contents = [ _output_name ]
+  }
+  if (defined(invoker.framework_contents)) {
+    _framework_toc += invoker.framework_contents
+    _framework_contents += invoker.framework_contents
+  }
+  _framework_toc_file = "$target_out_dir/${target_name}.toc"
+  write_file(_framework_toc_file, _framework_toc)
+
+  # Create local variables for referencing different parts of the bundle.
   _framework_target = _target_name
   _framework_name = _output_name + ".framework"
   _framework_base_dir = "$root_out_dir/$_framework_name"
   if (defined(invoker.framework_version) && invoker.framework_version != "") {
     _framework_version = invoker.framework_version
     _framework_root_dir = _framework_base_dir + "/Versions/$_framework_version"
-    _framework_target = _target_name + "_create_bundle"
   } else {
     _framework_root_dir = _framework_base_dir
   }
 
+  # Clean the entire framework if the framework_version changes.
+  _version_arg = "''"
+  if (defined(invoker.framework_version)) {
+    _version_arg = _framework_version
+  }
+  _version_file = "$target_out_dir/${target_name}_version"
+  exec_script("//build/config/mac/prepare_framework_version.py",
+              [
+                rebase_path(_version_file),
+                rebase_path(_framework_base_dir),
+                _version_arg,
+              ])
+
+  # Create the symlinks.
+  _framework_package_target = target_name + "_package"
+  action(_framework_package_target) {
+    script = "//build/config/mac/package_framework.py"
+
+    # The TOC file never needs to be read, since its contents are the values
+    # of GN variables. It is only used to trigger this rule when the values
+    # change.
+    inputs = [
+      _framework_toc_file,
+    ]
+
+    _stamp_file = "$target_out_dir/run_${_framework_package_target}.stamp"
+    outputs = [
+      _stamp_file,
+    ]
+
+    visibility = [ ":$_framework_target" ]
+
+    args = [
+      "--framework",
+      rebase_path(_framework_base_dir, root_build_dir),
+      "--stamp",
+      rebase_path(_stamp_file, root_build_dir),
+    ]
+
+    if (defined(invoker.framework_version)) {
+      outputs += [ "$_framework_base_dir/Versions/Current" ]
+      args += [
+                "--version",
+                invoker.framework_version,
+                "--contents",
+              ] + _framework_contents
+
+      # It is not possible to list _framework_contents as outputs, since
+      # ninja does not properly stat symbolic links. The exception is the
+      # "Current" symlink, since package_framework.py will ensure that
+      # directory exists so the resolved-symlink mtime will be up-to-date.
+      # https://github.com/ninja-build/ninja/issues/1186
+    }
+  }
+
   _link_shared_library_target = target_name + "_shared_library"
   _shared_library_bundle_data = target_name + "_shared_library_bundle_data"
 
   shared_library(_link_shared_library_target) {
     forward_variables_from(invoker,
                            "*",
                            [
                              "assert_no_deps",
                              "bundle_deps",
                              "code_signing_enabled",
@@ skipping 17 matching lines @@
       "$target_out_dir/$_link_shared_library_target/$_output_name",
     ]
     outputs = [
       "{{bundle_executable_dir}}/$_output_name",
     ]
     public_deps = [
       ":$_link_shared_library_target",
     ]
   }
 
-  # Clean the entire framework if the framework_version changes.
-  _version_arg = ""
-  if (defined(_framework_version)) {
-    _version_arg = _framework_version
-  }
-  _version_file = "$target_out_dir/${target_name}_version"
-  exec_script("//build/config/mac/prepare_framework_version.py",
-              [
-                rebase_path(_version_file),
-                rebase_path(_framework_base_dir),
-                "'$_version_arg'",
-              ])
-
   _framework_public_config = _target_name + "_public_config"
   config(_framework_public_config) {
     # TODO(sdefresne): should we have a framework_dirs similar to lib_dirs
     # and include_dirs to avoid duplicate values on the command-line.
     visibility = [ ":$_framework_target" ]
     ldflags = [
       "-F",
       rebase_path("$root_out_dir/.", root_build_dir),
     ]
     lib_dirs = [ root_out_dir ]
     libs = [ _framework_name ]
   }
 
   create_bundle(_framework_target) {
     forward_variables_from(invoker,
                            [
                              "data_deps",
                              "deps",
                              "public_deps",
                              "testonly",
                            ])
 
-    if (defined(_framework_version)) {
-      visibility = [ ":$_target_name" ]
-    } else {
-      if (defined(invoker.visibility)) {
-        visibility = invoker.visibility
-        visibility += [ ":$_target_name+link" ]
-      }
+    if (defined(invoker.visibility)) {
+      visibility = invoker.visibility
+      visibility += [ ":$_target_name+link" ]
     }
 
     if (!defined(deps)) {
       deps = []
     }
     deps += [ ":$_info_plist_bundle_data" ]
 
     if (defined(invoker.bundle_deps)) {
       deps += invoker.bundle_deps
     }
 
     if (!defined(public_deps)) {
       public_deps = []
     }
-    public_deps += [ ":$_shared_library_bundle_data" ]
+    public_deps += [
+      ":$_framework_package_target",
+      ":$_shared_library_bundle_data",
+    ]
 
     bundle_root_dir = _framework_root_dir
     bundle_resources_dir = "$bundle_root_dir/Resources"
     bundle_executable_dir = "$bundle_root_dir"
   }
 
-  if (defined(_framework_version)) {
-    action(_target_name) {
-      forward_variables_from(invoker, [ "testonly" ])
-
-      if (defined(invoker.visibility)) {
-        visibility = invoker.visibility
-        visibility += [ ":$_target_name+link" ]
-      }
-
-      script = "//build/config/mac/package_framework.py"
-      outputs = [
-        "$root_out_dir/$_framework_name/Versions/Current",
-      ]
-      args = [
-        "$_framework_name",
-        "$_framework_version",
-      ]
-      public_deps = [
-        ":$_framework_target",
-      ]
-    }
-  }
-
   group(_target_name + "+link") {
     forward_variables_from(invoker,
                            [
                              "public_configs",
                              "testonly",
                              "visibility",
                            ])
     public_deps = [
       ":$_target_name",
     ]
@@ skipping 244 matching lines @@
                            ])
     if (!defined(deps)) {
       deps = []
     }
     deps += [ ":$_loadable_module_bundle_data" ]
 
     bundle_root_dir = "$root_out_dir/$_output_name.plugin/Contents"
     bundle_executable_dir = "$bundle_root_dir/MacOS"
   }
 }