MacViews: TouchBar integration for toolkit-views dialogs.

ui/views/cocoa/bridged_content_view.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ui/views/cocoa/bridged_content_view.h"
 
 #include "base/logging.h"
 #import "base/mac/mac_util.h"
 #import "base/mac/scoped_nsobject.h"
 #import "base/mac/sdk_forward_declarations.h"
 #include "base/strings/sys_string_conversions.h"
 #include "skia/ext/skia_utils_mac.h"
 #include "ui/base/cocoa/cocoa_base_utils.h"
 #include "ui/base/dragdrop/drag_drop_types.h"
 #include "ui/base/dragdrop/os_exchange_data_provider_mac.h"
 #include "ui/base/ime/input_method.h"
 #include "ui/base/ime/text_edit_commands.h"
 #include "ui/base/ime/text_input_client.h"
+#include "ui/base/models/dialog_model.h"
 #include "ui/compositor/canvas_painter.h"
 #import "ui/events/cocoa/cocoa_event_utils.h"
 #include "ui/events/event_utils.h"
 #include "ui/events/keycodes/dom/dom_code.h"
 #import "ui/events/keycodes/keyboard_code_conversion_mac.h"
 #include "ui/gfx/canvas_paint_mac.h"
 #include "ui/gfx/decorated_text.h"
 #include "ui/gfx/geometry/rect.h"
 #import "ui/gfx/mac/coordinate_conversion.h"
 #include "ui/gfx/path.h"
 #import "ui/gfx/path_mac.h"
 #include "ui/gfx/scoped_ns_graphics_context_save_gstate_mac.h"
 #import "ui/views/cocoa/bridged_native_widget.h"
 #import "ui/views/cocoa/drag_drop_client_mac.h"
 #include "ui/views/controls/menu/menu_config.h"
 #include "ui/views/controls/menu/menu_controller.h"
 #include "ui/views/view.h"
 #include "ui/views/widget/native_widget_mac.h"
 #include "ui/views/widget/widget.h"
+#include "ui/views/widget/widget_delegate.h"
+#include "ui/views/window/dialog_delegate.h"
 #include "ui/views/word_lookup_client.h"
 
 using views::MenuController;
 
+@interface NSButton (SierraAPI)
+@property(nullable, copy) NSColor* bezelColor;
++ (instancetype)buttonWithTitle:(NSString*)title
+                         target:(id)target
+                         action:(SEL)action;
+@end
+
+#if !defined(MAC_OS_X_VERSION_10_12_1)
+
+typedef NSObject NSTouchBar;
+typedef NSObject NSTouchBarItem;
+typedef NSObject NSCustomTouchBarItem;
+typedef NSObject NSGroupTouchBarItem;
+typedef NSString* NSTouchBarItemIdentifier;
+
+@interface NSObject (FakeNSTouchBar)
+@property(copy) NSArray* defaultItemIdentifiers;
+@property(copy, nullable) NSTouchBarItemIdentifier principalItemIdentifier;
+@property(nullable, weak) id<NSTouchBarDelegate> delegate;
+@end
+
+@interface NSObject (FakeNSGroupTouchBarItem)
++ (NSGroupTouchBarItem*)groupItemWithIdentifier:
+                            (NSTouchBarItemIdentifier)identifier
+                                          items:(NSArray*)items;
+@end
+
+@interface NSObject (FakeNSCustomTouchBarItem)
+@property(readwrite, strong) NSView* view;
+@end
+
+#else
+
+@class NSTouchBar;
+@class NSTouchBarItem;
+@class NSCustomTouchBarItem;
+@class NSGroupTouchBarItem;
+
+#endif
+
 namespace {
 
 NSString* const kFullKeyboardAccessChangedNotification =
     @"com.apple.KeyboardUIModeDidChange";
+NSString* const kTouchBarDialogButtonsGroupId =
+    @"com.google.chrome-DIALOG-BUTTONS-GROUP";
+NSString* const kTouchBarOKId = @"com.google.chrome-OK";
+NSString* const kTouchBarCancelId = @"com.google.chrome-CANCEL";
 
 // Returns true if all four corners of |rect| are contained inside |path|.
 bool IsRectInsidePath(NSRect rect, NSBezierPath* path) {
   return [path containsPoint:rect.origin] &&
          [path containsPoint:NSMakePoint(rect.origin.x + rect.size.width,
                                          rect.origin.y)] &&
          [path containsPoint:NSMakePoint(rect.origin.x,
                                          rect.origin.y + rect.size.height)] &&
          [path containsPoint:NSMakePoint(rect.origin.x + rect.size.width,
                                          rect.origin.y + rect.size.height)];
@@ skipping 1355 matching lines @@
 }
 
 - (void)draggingSession:(NSDraggingSession*)session
            endedAtPoint:(NSPoint)screenPoint
               operation:(NSDragOperation)operation {
   views::DragDropClientMac* client = [self dragDropClient];
   if (client)
     client->EndDrag();
 }
 
+// TouchBar action.
+
+- (void)touchBarButtonAction:(id)sender {
+  if (!hostedView_)
+    return;
+
+  views::DialogDelegate* dialog =
+      hostedView_->GetWidget()->widget_delegate()->AsDialogDelegate();
+  DCHECK(dialog);
+
+  if ([sender tag] == ui::DIALOG_BUTTON_OK) {
+    dialog->Accept();
+    return;
+  }
+
+  DCHECK_EQ([sender tag], ui::DIALOG_BUTTON_CANCEL);
+  dialog->Cancel();
+}
+
+// NSTouchBarDelegate protocol implementation.
+
+- (NSTouchBarItem*)touchBar:(NSTouchBar*)touchBar
+      makeItemForIdentifier:(NSTouchBarItemIdentifier)identifier {
+  if (!hostedView_)
+    return nil;
+
+  if ([identifier isEqualToString:kTouchBarDialogButtonsGroupId]) {
+    NSMutableArray* items = [NSMutableArray arrayWithCapacity:2];
+    for (NSTouchBarItemIdentifier i : @[ kTouchBarCancelId, kTouchBarOKId ]) {
+      NSTouchBarItem* item = [self touchBar:touchBar makeItemForIdentifier:i];
+      if (item)
+        [items addObject:item];
+    }
+    if ([items count] == 0)
+      return nil;
+    return [NSGroupTouchBarItem groupItemWithIdentifier:identifier items:items];
+  }
+
+  ui::DialogButton type = ui::DIALOG_BUTTON_NONE;
+  if ([identifier isEqualToString:kTouchBarOKId])
+    type = ui::DIALOG_BUTTON_OK;
+  else if ([identifier isEqualToString:kTouchBarCancelId])
+    type = ui::DIALOG_BUTTON_CANCEL;
+  else
+    return nil;
+
+  ui::DialogModel* model =
+      hostedView_->GetWidget()->widget_delegate()->AsDialogDelegate();
+  if (!model || !(model->GetDialogButtons() & type))
+    return nil;
+
+  base::scoped_nsobject<NSCustomTouchBarItem> item([[NSClassFromString(
+      @"NSCustomTouchBarItem") alloc] initWithIdentifier:identifier]);
+  NSString* title = base::SysUTF16ToNSString(model->GetDialogButtonLabel(type));
+  NSButton* button =
+      [NSButton buttonWithTitle:title
+                         target:self
+                         action:@selector(touchBarButtonAction:)];
+  if (type == model->GetDefaultDialogButton()) {
+    [button setKeyEquivalent:@"\n"];

[tapted, 2016/11/02 09:28:57]

I'd hoped this would give the blue color, but actually I don't think this is
needed. -[NSButton setBezelColor] was introduced in 10.12.1 and is probably what
NSAlert is using. The color values... I just picked from what NSAlert shows up
as on the TouchBar simulator.

[Avi (use Gerrit), 2016/11/02 14:50:41]

Can we hopper up NSAlert and see what it's doing to achieve it?

[tapted, 2016/11/03 04:36:29]

Dumped my findings to http://crbug.com/661581 - it's using a lot of utility
classes that aren't exposed in the public headers :/

But I removed this line anyway -- just setting the bezel color below gives the
correct appearance. 

+    [button setBezelColor:[NSColor colorWithSRGBRed:0.168
+                                              green:0.51
+                                               blue:0.843
+                                              alpha:1.0]];
+  }
+  [button setEnabled:model->IsDialogButtonEnabled(type)];
+  [button setTag:type];
+  [item setView:button];
+  return item.autorelease();
+}
+
+// NSTouchBarProvider protocol implementation (via NSResonder category).
+
+- (NSTouchBar*)makeTouchBar {
+  if (!hostedView_)
+    return nil;
+
+  ui::DialogModel* model =
+      hostedView_->GetWidget()->widget_delegate()->AsDialogDelegate();
+  if (!model || !model->GetDialogButtons())
+    return nil;
+
+  base::scoped_nsobject<NSTouchBar> bar(
+      [[NSClassFromString(@"NSTouchBar") alloc] init]);
+  [bar setDelegate:self];
+  [bar setDefaultItemIdentifiers:@[ kTouchBarDialogButtonsGroupId ]];
+  [bar setPrincipalItemIdentifier:kTouchBarDialogButtonsGroupId];
+  return bar.autorelease();
+}
+
 // NSAccessibility informal protocol implementation.
 
 - (id)accessibilityAttributeValue:(NSString*)attribute {
   if ([attribute isEqualToString:NSAccessibilityChildrenAttribute]) {
     return @[ hostedView_->GetNativeViewAccessible() ];
   }
 
   return [super accessibilityAttributeValue:attribute];
 }
 
 - (id)accessibilityHitTest:(NSPoint)point {
   return [hostedView_->GetNativeViewAccessible() accessibilityHitTest:point];
 }
 
 - (id)accessibilityFocusedUIElement {
   if (!hostedView_)
     return nil;
   return [hostedView_->GetNativeViewAccessible() accessibilityFocusedUIElement];
 }
 
 @end