Add gdb macro to find assertion scopes on the stack.

tools/gdbinit

 # Copyright 2014 the V8 project authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 # Print HeapObjects.
 define job
 call _v8_internal_Print_Object((void*)($arg0))
 end
 document job
 Print a v8 JavaScript object
@@ skipping 50 matching lines @@
 set $js_entry_sp=v8::internal::Isolate::Current()->thread_local_top()->js_entry_sp_
 set $rbp=*(void**)$js_entry_sp
 set $rsp=$js_entry_sp + 2*sizeof(void*)
 set $pc=*(void**)($js_entry_sp+sizeof(void*))
 end
 document jss
 Skip the jitted stack on x64 to where we entered JS last.
 Usage: jss
 end
 
+# Print stack trace with assertion scopes.
+define bta
+python
+import re
+frame_re = re.compile("^#(\d+).* in (\S+) .+ at (.+)")
+assert_re = re.compile("^\s*(\S+) = .+<v8::internal::Per\w+AssertType::(\w+)_ASSERT, (false|true)>")
+btl = gdb.execute("backtrace full", to_string = True).splitlines()
+for l in btl:
+  match = frame_re.match(l)
+  if match:
+    print("[%-2s] %-60s %-40s" % (match.group(1), match.group(2), match.group(3)))
+  match = assert_re.match(l)
+  if match:
+    if match.group(3) == "false":
+      prefix = "Disallow"
+      color = "\033[91m"
+    else:
+      prefix = "Allow"
+      color = "\033[92m"
+    print("%s -> %s %s (%s)\033[0m" % (color, prefix, match.group(2), match.group(1)))
+end
+document bta
+Print stack trace with assertion scopes
+Usage: bta
+end
+
 set disassembly-flavor intel
 set disable-randomization off