Added AVFoundation Glue and Device Monitoring for Mac.

media/video/capture/mac/avfoundation_glue.mm

+// Copyright 2013 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "media/video/capture/mac/avfoundation_glue.h"
+
+#include <dlfcn.h>
+
+#include "base/mac/mac_util.h"
+
+BOOL AVFoundationGlue::IsAVFoundationSupported() {
+  return (base::mac::IsOSLionOrLater() &&
+          [AvFoundationBundle() load]);
+}
+
+NSBundle const* AVFoundationGlue::AvFoundationBundle() {
+  static NSBundle* bundle = [NSBundle
+      bundleWithPath:@"/System/Library/Frameworks/AVFoundation.framework"];
+  return bundle;
+}
+
+void* AVFoundationGlue::AvFoundationLibraryHandle() {
+  const char* library_path = [[AvFoundationBundle()
+      executablePath] fileSystemRepresentation];
+  if (library_path == NULL) {
+    DCHECK(false);
+    return NULL;
+  }
+  static void* library_handle = dlopen(library_path, RTLD_LAZY | RTLD_LOCAL);
+  DCHECK(library_handle) << dlerror();
+  return library_handle;
+}
+
+NSString* AVFoundationGlue::AvCaptureDeviceWasConnectedNotification() {
+  return ReadNSStringPtr("AVCaptureDeviceWasConnectedNotification",
+      AvFoundationLibraryHandle());
+}
+
+NSString* AVFoundationGlue::AvCaptureDeviceWasDisconnectedNotification() {
+  return ReadNSStringPtr("AVCaptureDeviceWasDisconnectedNotification",
+      AvFoundationLibraryHandle());
+}
+
+NSString* AVFoundationGlue::AvMediaTypeVideo() {
+  return ReadNSStringPtr("AVMediaTypeVideo", AvFoundationLibraryHandle());
+}
+
+NSString* AVFoundationGlue::AvMediaTypeAudio() {
+  return ReadNSStringPtr("AVMediaTypeAudio", AvFoundationLibraryHandle());
+}
+
+NSString* AVFoundationGlue::AvMediaTypeMuxed() {
+  return ReadNSStringPtr("AVMediaTypeMuxed", AvFoundationLibraryHandle());
+}
+
+NSString* AVFoundationGlue::ReadNSStringPtr(char const* const symbol,
+                                            void* const handle) {
+  NSString** stringPointer = (NSString**)dlsym(handle, symbol);
+  DCHECK(stringPointer) << dlerror();
+  return *stringPointer;
+}
+
+@implementation AVCaptureDeviceGlue
+
++ (NSArray*)devices {
+  Class avcClass =
+      [AVFoundationGlue::AvFoundationBundle() classNamed:@"AVCaptureDevice"];
+  SEL selectorDevices = NSSelectorFromString(@"devices");
+  if ([avcClass respondsToSelector:selectorDevices]) {
+    return [avcClass performSelector:selectorDevices];
+  }
+  return nil;
+}
+
++ (BOOL)hasMediaType:(NSString*)mediaType
+    forCaptureDevice:(CrAVCaptureDevice const*)device {
+  SEL selectorHasMediaType = NSSelectorFromString(@"hasMediaType:");
+  if ([device respondsToSelector:selectorHasMediaType]) {
+    return [device hasMediaType:mediaType];
+  }
+  return NO;
+}
+
++ (NSString*)uniqueID:(CrAVCaptureDevice const*)device {
+  SEL selectorUniqueID = NSSelectorFromString(@"uniqueID");
+  if ([device respondsToSelector:selectorUniqueID]) {
+    return [device uniqueID];
+  }
+  return nil;
+}
+
+@end  // @implementation AVCaptureDevice