Added AVFoundation Glue and Device Monitoring for Mac.

media/video/capture/mac/avfoundation_glue.mm

+// Copyright (c) 2013 The Chromium Authors. All rights reserved.

[Mark Mentovai, 2013/10/01 18:53:23]

no (c) necessary. You didn’t use it in your other new file.

[mcasas, 2013/10/02 14:10:39]

Done.

+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "media/video/capture/mac/avfoundation_glue.h"
+
+#include "base/mac/mac_util.h"
+
+@implementation AVFoundationGlue
+
++ (BOOL)isAVFoundationSupported {
+  return (base::mac::IsOSLionOrLater() &&
+     [[AVFoundationGlue avFoundationBundle] load]);
+}
+
++ (NSBundle*)avFoundationBundle {
+  static NSBundle* bundle = [NSBundle
+      bundleWithPath:@"/System/Library/Frameworks/AVFoundation.framework"];
+  return bundle;
+}
+
++ (NSString *const)avCaptureDeviceWasConnectedNotification{
+  return @"AVCaptureDeviceWasConnectedNotification";

[Mark Mentovai, 2013/10/01 18:53:23]

OK, the right thing to do here is to do a dlsym to get the symbol by name from
the library. NSBundle doesn’t have a great interface for that, so once the
bundle is loaded, you should dlopen it too. Then you’ll have two open handles to
the same library: one for the NSBundle interface and one for the libdl-family
interface. You can call dlopen on -[[NSBundle executablePath]
fileSystemRepresentation]. Same for all of the other things that the library
exposes as ordinary C data as opposed to Objective-C classes or selectors.

[mcasas, 2013/10/02 14:10:39]

Done. 

I think (?) that the dlopen does not need to be corresponded with a dlclose
since the DeviceMonitorMac is a singleton living as long as Chrome, so we would
only need to tear down the library handle on chrome destruction and that happens
by default anyway, right?

[Mark Mentovai, 2013/10/02 14:24:34]

miguelao wrote:
Right, since you never release the NSBundle, you wouldn’t need to perform the
analogous operation, dlclosing the handle from dlopen.

+}
+
++ (NSString *const)avCaptureDeviceWasDisconnectedNotification{
+  return @"AVCaptureDeviceWasDisconnectedNotification";
+}
+
++ (NSString *const)avMediaTypeVideo{
+  return @"vide";
+}
+
++ (NSString *const)avMediaTypeAudio{
+  return @"soun";
+}
+
++ (NSString *const)avMediaTypeMuxed{
+  return @"muxx";
+}
+
+@end  // @implementation AVFoundationGlue
+
+
+@implementation AVCaptureDeviceGlue
+
++ (NSArray*)devices {
+  Class avcClass = [[AVFoundationGlue avFoundationBundle]
+      classNamed:@"AVCaptureDevice"];
+  SEL selectorDevices = NSSelectorFromString(@"devices");
+  if ([avcClass respondsToSelector:selectorDevices]){
+    return [avcClass performSelector:selectorDevices];
+  }
+  return nil;
+}
+
++ (BOOL)hasMediaType:(NSString *)mediaType
+               forId:(id)device{

[Mark Mentovai, 2013/10/01 18:53:23]

Is there no better generic type than id?

If you’ve done this because the type declaration is in the SDK which you can’t
use, the right thing to do here is to declare your own similar class. For
example, if the real one is named AVCaptureDevice, you can write

@interface CrAVCaptureDevice
- (BOOL)hasMediaType:(NSString*)mediaType
@end

That will let you use CrAVCaptureDevice* as a type as a proxy for the real
thing, and if you have a CrAVCaptureDevice*, you can call -hasMediaType: on it.
You still want to check -respondsToSelector:, but you don’t need to go through
the NSInvocation hoops. Much easier this way.

[mcasas, 2013/10/02 14:10:39]

Much appreciated tip thanks!
Done.

+  BOOL returnValueHasMediaType = NO;
+  SEL selectorHasMediaType = NSSelectorFromString(@"hasMediaType:");
+  // To retrieve the return value of a dynamically found method inside a class
+  // that we don't know the interface, we have to get a |SEL| and invoke it.
+  if ([device respondsToSelector:selectorHasMediaType]) {
+    NSInvocation *invocation = [NSInvocation invocationWithMethodSignature:
+      [[device class] instanceMethodSignatureForSelector:selectorHasMediaType]];
+    [invocation setSelector:selectorHasMediaType];
+    [invocation setTarget:device];
+    // First argument's index is 2 :S -- counterintuitive
+    [invocation setArgument:&mediaType atIndex:2];
+    [invocation invoke];
+    [invocation getReturnValue:&returnValueHasMediaType];
+  }
+  return returnValueHasMediaType;
+}
+
+@end  // @implementation AVCaptureDevice