Record the initial state of the Physical Web at startup

ios/chrome/browser/physical_web/start_physical_web_discovery.mm

 // Copyright 2016 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "ios/chrome/browser/physical_web/start_physical_web_discovery.h"
 
 #import <CoreLocation/CoreLocation.h>
 
 #include "components/physical_web/data_source/physical_web_data_source.h"
 #include "ios/chrome/browser/application_context.h"
 #import "ios/chrome/browser/experimental_flags.h"
 #import "ios/chrome/browser/geolocation/omnibox_geolocation_config.h"
 #include "ios/chrome/browser/physical_web/physical_web_constants.h"
+#import "ios/chrome/browser/physical_web/physical_web_initial_state_recorder.h"
 #include "ios/chrome/browser/pref_names.h"
 #include "url/gurl.h"
 
 void StartPhysicalWebDiscovery(PrefService* pref_service, bool is_incognito) {
   // Do not scan if the Physical Web feature is disabled by a command line flag
   // or Chrome Variations experiment.
   if (!experimental_flags::IsPhysicalWebEnabled()) {
     return;
   }
 
   // If the preference is in the default state, check if conditions allow us to
   // auto-enable it. The preference can be auto-enabled if the omnibox would
   // send the X-Geo geolocation header in search queries to www.google.com.
   int preference_state =
       pref_service->GetInteger(prefs::kIosPhysicalWebEnabled);
+
+  // Check that Location Services is enabled.
+  bool location_services_enabled = [CLLocationManager locationServicesEnabled];
+
+  // Check that the user has authorized Chrome to use location.
+  CLAuthorizationStatus auth_status = [CLLocationManager authorizationStatus];
+  bool location_authorized =
+      auth_status == kCLAuthorizationStatusAuthorizedWhenInUse ||
+      auth_status == kCLAuthorizationStatusAuthorizedAlways;
+
+  // Record the initial state of Bluetooth, location, and the Physical Web
+  // preference the first time discovery is started.
+  static dispatch_once_t once_token;
+  dispatch_once(&once_token, ^{
+    [[[PhysicalWebInitialStateRecorder alloc]
+        initWithPreferenceState:preference_state
+        locationServicesEnabled:location_services_enabled
+             locationAuthorized:location_authorized] autorelease];

[mattreynolds, 2016/10/27 23:56:04]

Not sure if this is kosher. The idea is to let the
PhysicalWebInitialStateRecorder take ownership of itself so it can self-destruct
once the asynchronous Bluetooth check is complete and the histogram is recorded.

[rohitrao (ping after 24h), 2016/10/31 19:41:08]

I think this works, but I don't really like it.  This feels like it will be way
too easy for someone to accidentally turn into a leak or a crash in the future.

[mattreynolds, 2016/11/01 17:17:17]

Agreed, I'd rather not leave it like this. The reason I designed it this way is
because I couldn't figure out how else to get the preference state and the
bluetooth enabled state in the same place. The bluetooth check is async, so we
need someone to hold a reference to the bluetooth delegate until it gets its
response. To get the preference, we need a valid PrefService.

I think I could move this into the PhysicalWebDataSource if I could get the
PrefService from a global context. Is that possible, or do I need a
BrowserState?

+  });
+
   if (preference_state == physical_web::kPhysicalWebOnboarding) {
-    // Check that Location Services is enabled.
-    bool location_services_enabled =
-        [CLLocationManager locationServicesEnabled];
-
-    // Check that the user has authorized Chrome to use location.
-    CLAuthorizationStatus auth_status = [CLLocationManager authorizationStatus];
-    bool location_authorized =
-        auth_status == kCLAuthorizationStatusAuthorizedWhenInUse ||
-        auth_status == kCLAuthorizationStatusAuthorizedAlways;
-
     // Check that the user has not revoked the geolocation permission for
     // Google.
     bool geolocation_eligible = [[OmniboxGeolocationConfig sharedInstance]
         URLHasEligibleDomain:GURL("https://www.google.com")];
 
     if (!is_incognito && location_services_enabled && location_authorized &&
         geolocation_eligible) {
       pref_service->SetInteger(prefs::kIosPhysicalWebEnabled,
                                physical_web::kPhysicalWebOn);
       preference_state =
           pref_service->GetInteger(prefs::kIosPhysicalWebEnabled);
     }
   }
 
   // Scan only if the feature is enabled.
   if (preference_state == physical_web::kPhysicalWebOn) {
     GetApplicationContext()->GetPhysicalWebDataSource()->StartDiscovery(true);
   } else {
     GetApplicationContext()->GetPhysicalWebDataSource()->StopDiscovery();
   }
 }