[ObjC ARC] Converts the rest of ios/web to ARC.

ios/web/web_state/wk_web_view_security_util.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/web/web_state/wk_web_view_security_util.h"
 
 #include "base/mac/scoped_cftyperef.h"
 #include "base/strings/sys_string_conversions.h"
 #include "net/cert/x509_certificate.h"
 #include "net/ssl/ssl_info.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 namespace web {
 
 // These keys were determined by inspecting userInfo dict of an SSL error.
 NSString* const kNSErrorPeerCertificateChainKey =
     @"NSErrorPeerCertificateChainKey";
 NSString* const kNSErrorFailingURLKey = @"NSErrorFailingURLKey";
 }
 
 namespace {
 
@@ skipping 20 matching lines @@
 }  // namespace
 
 
 namespace web {
 
 scoped_refptr<net::X509Certificate> CreateCertFromChain(NSArray* certs) {
   if (certs.count == 0)
     return nullptr;
   net::X509Certificate::OSCertHandles intermediates;
   for (NSUInteger i = 1; i < certs.count; i++) {
-    intermediates.push_back(reinterpret_cast<SecCertificateRef>(certs[i]));
+    intermediates.push_back((__bridge SecCertificateRef)certs[i]);
   }
   return net::X509Certificate::CreateFromHandle(
-      reinterpret_cast<SecCertificateRef>(certs[0]), intermediates);
+      (__bridge SecCertificateRef)certs[0], intermediates);
 }
 
 scoped_refptr<net::X509Certificate> CreateCertFromTrust(SecTrustRef trust) {
   if (!trust)
     return nullptr;
 
   CFIndex cert_count = SecTrustGetCertificateCount(trust);
   if (cert_count == 0) {
     // At the moment there is no API which allows trust creation w/o certs.
     return nullptr;
   }
 
   net::X509Certificate::OSCertHandles intermediates;
   for (CFIndex i = 1; i < cert_count; i++) {
     intermediates.push_back(SecTrustGetCertificateAtIndex(trust, i));
   }
   return net::X509Certificate::CreateFromHandle(
       SecTrustGetCertificateAtIndex(trust, 0), intermediates);
 }
 
 base::ScopedCFTypeRef<SecTrustRef> CreateServerTrustFromChain(NSArray* certs,
                                                               NSString* host) {
   base::ScopedCFTypeRef<SecTrustRef> scoped_result;
   if (certs.count == 0)
     return scoped_result;
 
   base::ScopedCFTypeRef<SecPolicyRef> policy(
       SecPolicyCreateSSL(TRUE, static_cast<CFStringRef>(host)));
   SecTrustRef ref_result = nullptr;
-  if (SecTrustCreateWithCertificates(certs, policy, &ref_result) ==
-      errSecSuccess) {
+  if (SecTrustCreateWithCertificates((__bridge CFArrayRef)certs, policy,
+                                     &ref_result) == errSecSuccess) {
     scoped_result.reset(ref_result);
   }
   return scoped_result;
 }
 
 void EnsureFutureTrustEvaluationSucceeds(SecTrustRef trust) {
   base::ScopedCFTypeRef<CFDataRef> exceptions(SecTrustCopyExceptions(trust));
   SecTrustSetExceptions(trust, exceptions);
 }
 
@@ skipping 47 matching lines @@
     // kSecTrustResultConfirm was deprecated in iOS7, but leads to a compile
     // error if used with newer SDKs.  Remove the default clause once this
     // switch statement successfully compiles without kSecTrustResultConfirm.
     default:
       NOTREACHED();
       return SECURITY_STYLE_UNKNOWN;
   }
 }
 
 }  // namespace web