Split //ios/chrome/browser in multiple targets.

ios/chrome/browser/webp_transcode/BUILD.gn

+# Copyright 2016 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+source_set("webp_transcode") {
+  sources = [
+    "webp_decoder.h",
+    "webp_decoder.mm",
+  ]
+  deps = [
+    "//base",
+    "//third_party/libwebp:libwebp_dec",
+  ]
+}
+
+source_set("unit_tests") {
+  testonly = true
+  sources = [
+    "webp_decoder_unittest.mm",
+  ]
+  deps = [
+    ":webp_transcode",
+    ":webp_transcode_unit_tests_bundle_data",
+    "//base",
+    "//testing/gmock",
+    "//testing/gtest",
+  ]
+  libs = [ "CoreGraphics.framework" ]
+}
+
+bundle_data("webp_transcode_unit_tests_bundle_data") {
+  visibility = [ ":unit_tests" ]
+  testonly = true
+  sources = [
+    "//ios/chrome/test/data/webp_transcode/test.jpg",

[rohitrao (ping after 24h), 2016/10/25 19:48:53]

This part feels a little weird.  Should this rule be in
ios/chrome/test/data/BUILD.gn instead?  I think we're better off having the
testdata rule live next to the unit_test rule, but having to use absolute paths
for the files seems unfortunate.

[sdefresne, 2016/10/25 21:10:23]

I have the same feeling, but I prefer having the bundle_data in the same
location as the code depending on it. Maybe we can move the files themselves to
ios/chrome/browser/webp_transcode/test_data in a followup CL?

+    "//ios/chrome/test/data/webp_transcode/test.webp",
+    "//ios/chrome/test/data/webp_transcode/test_alpha.png",
+    "//ios/chrome/test/data/webp_transcode/test_alpha.webp",
+    "//ios/chrome/test/data/webp_transcode/test_small.tiff",
+    "//ios/chrome/test/data/webp_transcode/test_small.webp",
+  ]
+  outputs = [
+    "{{bundle_resources_dir}}/{{source_root_relative_dir}}/" +
+        "{{source_file_part}}",
+  ]
+}