Merge more Kernel infrastructure from kernel_sdk SDK fork.

runtime/vm/BUILD.gn

 # Copyright (c) 2014, the Dart project authors.  Please see the AUTHORS file
 # for details. All rights reserved. Use of this source code is governed by a
 # BSD-style license that can be found in the LICENSE file.
 
 config("libdart_vm_config") {
   if (defined(is_fuchsia) && is_fuchsia) {
     libs = [
       "magenta",
     ]
   } else if (is_win) {
@@ skipping 42 matching lines @@
 }
 
 
 vm_sources_list = exec_script("../../tools/gypi_to_gn.py",
                               [rebase_path("vm_sources.gypi")],
                               "scope",
                               ["vm_sources.gypi"])
 
 
 static_library("libdart_vm") {
+  deps = [":patched_sdk"]

[zra, 2016/10/21 21:34:43]

Why is this dependency here, but not on the analogous target in the .gyp file?

[zra, 2016/10/21 21:34:43]

Also, we tend to put 'deps' below 'configs'.

[Vyacheslav Egorov (Google), 2016/10/24 13:35:10]

Done.

   configs += ["..:dart_config",
               "..:dart_maybe_product_config",
               "..:dart_maybe_precompiled_runtime_config"]
   public_configs = [":libdart_vm_config"]
   set_sources_assignment_filter(["*_test.cc", "*_test.h"])
   sources = vm_sources_list.sources
   include_dirs = [
     "..",
   ]
 }
@@ skipping 20 matching lines @@
   public_configs = [":libdart_vm_config"]
   set_sources_assignment_filter(["*_test.cc", "*_test.h"])
   sources = vm_sources_list.sources
   include_dirs = [
     "..",
   ]
 }
 
 
 static_library("libdart_vm_nosnapshot") {
+  deps = [":patched_sdk"]
   configs += ["..:dart_config",
               "..:dart_maybe_product_config",
               "..:dart_maybe_precompiled_runtime_config",
               "..:dart_no_snapshot_config",]
   public_configs = [":libdart_vm_config"]
   set_sources_assignment_filter(["*_test.cc", "*_test.h"])
   sources = vm_sources_list.sources
   include_dirs = [
     "..",
   ]
 }
 
 
 static_library("libdart_vm_nosnapshot_precompiled_runtime") {
   configs += ["..:dart_config",
               "..:dart_maybe_product_config",
               "..:dart_precompiled_runtime_config",
               "..:dart_no_snapshot_config",]
   public_configs = [":libdart_vm_config"]
   set_sources_assignment_filter(["*_test.cc", "*_test.h"])
   sources = vm_sources_list.sources
   include_dirs = [
     "..",
   ]
 }
 
 
 static_library("libdart_vm_nosnapshot_with_precompiler") {
+  deps = [":patched_sdk"]
   configs += ["..:dart_config",
               "..:dart_maybe_product_config",
               "..:dart_precompiler_config",
               "..:dart_no_snapshot_config",]
   public_configs = [":libdart_vm_config"]
   set_sources_assignment_filter(["*_test.cc", "*_test.h"])
   sources = vm_sources_list.sources
   include_dirs = [
     "..",
   ]
@@ skipping 151 matching lines @@
     ["developer", "developer", true, "../../sdk/lib/developer", "../lib"],
     ["_internal", "internal", true, "../../sdk/lib/internal", "../lib"],
     ["isolate", "isolate", true, "../../sdk/lib/isolate", "../lib"],
     ["math", "math", true, "../../sdk/lib/math", "../lib"],
     ["mirrors", "mirrors", true, "../../sdk/lib/mirrors", "../lib"],
     ["profiler", "profiler", false, "../../sdk/lib/profiler"],
     ["typed_data", "typed_data", false, "../lib"],
     ["_vmservice", "vmservice", true, "../../sdk/lib/vmservice", "../lib"],
   ]
 }
+
+group("patched_sdk") {
+  template("concatenate_patch") {

[zra, 2016/10/21 21:34:43]

Optional: templates can use each other. Are there enough similarities between
this template and generate_library_source above that it would make sense to pull
out the common parts?

[Vyacheslav Egorov (Google), 2016/10/24 13:35:10]

I have rewritten this code.

+    assert(defined(invoker.libname), "Need a name in $target_name")
+    assert(defined(invoker.dir), "Need a dir in $target_name")
+    assert(defined(invoker.output), "Need a output in $target_name")

[zra, 2016/10/21 21:34:43]

an

[Vyacheslav Egorov (Google), 2016/10/24 13:35:10]

Done.

+
+    action(target_name) {
+      visibility = [ ":*" ]
+      output = invoker.output
+      dir = invoker.dir
+      libname = invoker.libname
+      sources_gypi = "../${dir}/${libname}_sources.gypi"
+
+      lib_sources_gypi =
+          exec_script("../../tools/gypi_to_gn.py",
+                      [rebase_path(sources_gypi)],
+                      "scope",
+                      [sources_gypi])
+      lib_sources =
+          rebase_path(lib_sources_gypi.sources, ".", "../${dir}")
+
+      script = "../tools/concatenate_patches.py"
+
+      inputs = [ script, sources_gypi ]
+      inputs += lib_sources
+
+      outputs = [ output ]
+
+      args = [ "--output", rebase_path(output, root_build_dir)]
+      args += rebase_path(lib_sources, root_build_dir)
+    }
+  }
+
+  vm_libraries = [ "async", "collection", "convert", "core", "developer",

[zra, 2016/10/21 21:34:43]

I would re-structure this as a template that takes a list of pairs as a
parameter, similar to 'generate_core_libraries' above, e.g.:

template("generate_patched_sdk") {
}

generate_patched_sdk("patched_sdk") {
  sources = [
    ["async", "lib"],
    ...,
    ["io", "bin"],
  ]
}

Then we can avoid the slightly un-idiomatic structure here of having templates
and actions inside a "group". (Typically, "groups" just have deps = [ ... ]")

[Vyacheslav Egorov (Google), 2016/10/24 13:35:10]

Done.

+                   "internal", "isolate", "math", "mirrors", "profiler",
+                   "vmservice" ]
+  concatenation_target_names = []
+  concatenation_files = []
+
+  # Concatenate vm library patches.

[zra, 2016/10/21 21:34:43]

Then you can de-dup the invocation of concatenate_patch for vm_libraries and io
below.

[Vyacheslav Egorov (Google), 2016/10/24 13:35:10]

Done.

+  foreach(name, vm_libraries) {
+    target_name = "concatenate_${name}_patch"
+    target_output = "$target_gen_dir/patches/${name}_patch.dart"
+    concatenate_patch(target_name) {
+      libname = name
+      output = target_output
+      dir = "lib"
+    }
+    concatenation_target_names += [ ":${target_name}" ]
+    concatenation_files += [ target_output ]
+  }
+
+  # Concatenate io library patches.
+  name = "io"
+  target_name = "concatenate_${name}_patch"
+  target_output = "$target_gen_dir/patches/${name}_patch.dart"
+  concatenate_patch(target_name) {
+    libname = name
+    output = target_output
+    dir = "bin"
+  }
+  concatenation_target_names += [ ":concatenate_io_patch" ]
+  concatenation_files += [ target_output ]
+
+  # Build the patched sdk out of the concatenated patches and the special
+  # "runtime/bin/{builtin,nativewrappers}.dart" libraries".
+  action("generate_patched_sdk") {
+    deps = concatenation_target_names
+
+    patches_dir = "$target_gen_dir/patches"
+    patched_sdk_dir = "$target_gen_dir/patched_sdk"
+
+    script = "../../tools/patch_sdk.py"
+
+    # We list all files which make up the sdk (modulo patches) and get them back
+    # as a GN list object.
+    shared_sdk_sources = exec_script(
+        "../../tools/list_files.py", ["dart\$", "../../sdk/lib"], "list lines")

[zra, 2016/10/21 21:34:43]

If you only want .dart files, then tools/list_dart_files.py should be a lot
faster.

[Vyacheslav Egorov (Google), 2016/10/24 13:35:10]

Done.

+
+    # We list the `patch_sdk.dart` tool here because the [script] (which is
+    # implicitly an input) will call it.
+    inputs = [ "../../tools/patch_sdk.dart" ]
+    # These three are not patches, they will not be in [concatenation_files] but
+    # the `patch_sdk.dart` script will copy them into the patched sdk.
+    inputs += [
+      "../lib/typed_data.dart",
+      "../bin/builtin.dart",
+      "../bin/nativewrappers.dart",
+      "../bin/vmservice/vmservice_io.dart",
+      "../bin/vmservice/loader.dart",
+      "../bin/vmservice/server.dart",
+    ]
+    # Add all the normal sdk sources.
+    inputs += shared_sdk_sources
+    # Add all the concatenated patch files.
+    inputs += concatenation_files
+
+    outputs = [
+      # Instead of listing all outputs we list a single well-known one.
+      "${patched_sdk_dir}/lib/core/core.dart",
+    ]
+
+    args = [
+        "vm",
+        rebase_path("../../sdk"),
+        rebase_path(patches_dir, root_build_dir),
+        rebase_path(patched_sdk_dir, root_build_dir),
+    ]
+  }
+}