Add remaining items to Chrome App menus. (Mac)

chrome/browser/ui/cocoa/apps/app_shim_menu_controller_mac.mm

 // Copyright 2013 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/apps/app_shim_menu_controller_mac.h"
 
 #include "apps/app_shim/extension_app_shim_handler_mac.h"
 #include "apps/shell_window.h"
 #include "apps/shell_window_registry.h"
 #include "base/strings/sys_string_conversions.h"
@@ skipping 152 matching lines @@
   }
   return self;
 }
 
 - (void)dealloc {
   [[NSNotificationCenter defaultCenter] removeObserver:self];
   [super dealloc];
 }
 
 - (void)buildAppMenuItems {
+  aboutDoppelganger_.reset([[DoppelgangerMenuItem alloc]
+      initWithController:self
+                 menuTag:IDC_CHROME_MENU
+                 itemTag:IDC_ABOUT
+              resourceId:IDS_ABOUT_MAC
+                  action:nil
+           keyEquivalent:@""]);

[Nico, 2013/09/20 16:18:49]

I'm wondering if there's some way to do this that doesn't duplicate quite a few
menu items from the xib file in code. Maybe the tag could have a high bit set if
the entry should have a duplicate – but I guess that's kind of messy too.

[jackhou1, 2013/09/21 00:53:05]

I don't think that encodes enough information about the duplicate's behaviour.
It might make sense to add another xib file for app menus. I don't expect to add
any more items after this CL though, so maybe it's not necessary.

   hideDoppelganger_.reset([[DoppelgangerMenuItem alloc]
       initWithController:self
                  menuTag:IDC_CHROME_MENU
                  itemTag:IDC_HIDE_APP
               resourceId:IDS_HIDE_APP_MAC
                   action:@selector(hideCurrentPlatformApp)
            keyEquivalent:@"h"]);
   quitDoppelganger_.reset([[DoppelgangerMenuItem alloc]
       initWithController:self
                  menuTag:IDC_CHROME_MENU
                  itemTag:IDC_EXIT
               resourceId:IDS_EXIT_MAC
                   action:@selector(quitCurrentPlatformApp)
            keyEquivalent:@"q"]);
+  newDoppelganger_.reset([[DoppelgangerMenuItem alloc]
+      initWithController:self
+                 menuTag:IDC_FILE_MENU
+                 itemTag:IDC_NEW_WINDOW
+              resourceId:0
+                  action:nil
+           keyEquivalent:@"n"]);
+  // For apps, the "Window" part of "New Window" is dropped to match the default
+  // menu set given to Cocoa Apps.
+  [[newDoppelganger_ menuItem] setTitle:l10n_util::GetNSString(IDS_NEW_MAC)];
+  openDoppelganger_.reset([[DoppelgangerMenuItem alloc]
+      initWithController:self
+                 menuTag:IDC_FILE_MENU
+                 itemTag:IDC_OPEN_FILE
+              resourceId:0
+                  action:nil
+           keyEquivalent:@"o"]);
   allToFrontDoppelganger_.reset([[DoppelgangerMenuItem alloc]
       initWithController:self
                  menuTag:IDC_WINDOW_MENU
                  itemTag:IDC_ALL_WINDOWS_FRONT
               resourceId:0
                   action:@selector(focusCurrentPlatformApp)
            keyEquivalent:@""]);
 
   // The app's menu.
   appMenuItem_.reset([[NSMenuItem alloc] initWithTitle:@""
                                                 action:nil
                                          keyEquivalent:@""]);
   base::scoped_nsobject<NSMenu> appMenu([[NSMenu alloc] initWithTitle:@""]);
   [appMenuItem_ setSubmenu:appMenu];
   [appMenu setAutoenablesItems:NO];
 
+  [appMenu addItem:[aboutDoppelganger_ menuItem]];
+  [[aboutDoppelganger_ menuItem] setEnabled:NO];  // Not implemented yet.
+  [appMenu addItem:[NSMenuItem separatorItem]];
   [appMenu addItem:[hideDoppelganger_ menuItem]];
   [appMenu addItem:[NSMenuItem separatorItem]];
   [appMenu addItem:[quitDoppelganger_ menuItem]];
 
   // File menu.
   fileMenuItem_.reset([NewTopLevelItemFrom(IDC_FILE_MENU) retain]);
+  [[fileMenuItem_ submenu] addItem:[newDoppelganger_ menuItem]];
+  [[fileMenuItem_ submenu] addItem:[openDoppelganger_ menuItem]];
+  [[fileMenuItem_ submenu] addItem:[NSMenuItem separatorItem]];
   AddDuplicateItem(fileMenuItem_, IDC_FILE_MENU, IDC_CLOSE_WINDOW);
 
-  // Edit menu. This is copied entirely.
+  // Edit menu. This copies the menu entirely and removes
+  // "Paste and Match Style" and "Find". This is because the last two items,

[tapted, 2013/09/20 06:48:00]

no-op/optional: also I'd consider the sentence "This is because.." an optional
addition. Copying the whole menu and removing two items is probably more elegant
anyway. So, up to you if you want to keep it.

+  // "Start Dictation" and "Special Characters" are added by OSX, so we can't
+  // copy them explicitly.
   editMenuItem_.reset([[[NSApp mainMenu] itemWithTag:IDC_EDIT_MENU] copy]);
+  NSMenu* editMenu = [editMenuItem_ submenu];
+  [editMenu removeItem:[editMenu
+      itemWithTag:IDC_CONTENT_CONTEXT_PASTE_AND_MATCH_STYLE]];
+  [editMenu removeItem:[editMenu itemWithTag:IDC_FIND_MENU]];
 
   // Window menu.
   windowMenuItem_.reset([NewTopLevelItemFrom(IDC_WINDOW_MENU) retain]);
   AddDuplicateItem(windowMenuItem_, IDC_WINDOW_MENU, IDC_MINIMIZE_WINDOW);
   AddDuplicateItem(windowMenuItem_, IDC_WINDOW_MENU, IDC_MAXIMIZE_WINDOW);
   [[windowMenuItem_ submenu] addItem:[NSMenuItem separatorItem]];
   [[windowMenuItem_ submenu] addItem:[allToFrontDoppelganger_ menuItem]];
 }
 
 - (void)registerEventHandlers {
@@ skipping 47 matching lines @@
     return;
 
   [self removeMenuItems:appId_];
   appId_.reset([appId copy]);
 
   // Hide Chrome menu items.
   NSMenu* mainMenu = [NSApp mainMenu];
   for (NSMenuItem* item in [mainMenu itemArray])
     [item setHidden:YES];
 
+  [aboutDoppelganger_ enableForApp:app];
   [hideDoppelganger_ enableForApp:app];
   [quitDoppelganger_ enableForApp:app];
+  [newDoppelganger_ enableForApp:app];
+  [openDoppelganger_ enableForApp:app];
 
   [appMenuItem_ setTitle:appId];
   [[appMenuItem_ submenu] setTitle:title];
 
   [mainMenu addItem:appMenuItem_];
   [mainMenu addItem:fileMenuItem_];
   [mainMenu addItem:editMenuItem_];
   [mainMenu addItem:windowMenuItem_];
 }
 
 - (void)removeMenuItems:(NSString*)appId {
   if (![appId_ isEqualToString:appId])
     return;
 
   appId_.reset();
 
   NSMenu* mainMenu = [NSApp mainMenu];
   [mainMenu removeItem:appMenuItem_];
   [mainMenu removeItem:fileMenuItem_];
   [mainMenu removeItem:editMenuItem_];
   [mainMenu removeItem:windowMenuItem_];
 
   // Restore the Chrome main menu bar.
   for (NSMenuItem* item in [mainMenu itemArray])
     [item setHidden:NO];
 
+  [aboutDoppelganger_ disable];
   [hideDoppelganger_ disable];
   [quitDoppelganger_ disable];
+  [newDoppelganger_ disable];
+  [openDoppelganger_ disable];
 }
 
 - (void)quitCurrentPlatformApp {
   apps::ShellWindow* shellWindow =
       apps::ShellWindowRegistry::GetShellWindowForNativeWindowAnyProfile(
           [NSApp keyWindow]);
   if (shellWindow)
     apps::ExtensionAppShimHandler::QuitAppForWindow(shellWindow);
 }
 
 - (void)hideCurrentPlatformApp {
   apps::ShellWindow* shellWindow =
       apps::ShellWindowRegistry::GetShellWindowForNativeWindowAnyProfile(
           [NSApp keyWindow]);
   if (shellWindow)
     apps::ExtensionAppShimHandler::HideAppForWindow(shellWindow);
 }
 
 - (void)focusCurrentPlatformApp {
   apps::ShellWindow* shellWindow =
       apps::ShellWindowRegistry::GetShellWindowForNativeWindowAnyProfile(
           [NSApp keyWindow]);
   if (shellWindow)
     apps::ExtensionAppShimHandler::FocusAppForWindow(shellWindow);
 }
 
 @end