Close the ntp during startup when opening a link on Mac.

chrome/browser/app_controller_mac_browsertest.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
+#import <Carbon/Carbon.h>
 #import <Cocoa/Cocoa.h>
+#import <Foundation/Foundation.h>
+#import <Foundation/NSAppleEventDescriptor.h>
+#import <objc/message.h>
+#import <objc/runtime.h>
 
 #include "apps/app_window_registry.h"
 #include "base/command_line.h"
 #include "base/mac/scoped_nsobject.h"
 #include "base/prefs/pref_service.h"
 #include "chrome/app/chrome_command_ids.h"
 #import "chrome/browser/app_controller_mac.h"
 #include "chrome/browser/apps/app_browsertest_util.h"
 #include "chrome/browser/browser_process.h"
 #include "chrome/browser/extensions/extension_test_message_listener.h"
 #include "chrome/browser/profiles/profile_manager.h"
 #include "chrome/browser/ui/browser.h"
 #include "chrome/browser/ui/browser_list.h"
 #include "chrome/browser/ui/browser_window.h"
 #import "chrome/browser/ui/cocoa/profiles/user_manager_mac.h"
 #include "chrome/browser/ui/host_desktop.h"
 #include "chrome/browser/ui/tabs/tab_strip_model.h"
 #include "chrome/common/chrome_constants.h"
 #include "chrome/common/chrome_switches.h"
 #include "chrome/common/pref_names.h"
+#include "chrome/common/url_constants.h"
 #include "chrome/test/base/in_process_browser_test.h"
 #include "chrome/test/base/ui_test_utils.h"
 #include "content/public/browser/web_contents.h"
 #include "extensions/common/extension.h"
+#include "net/test/embedded_test_server/embedded_test_server.h"
 
 namespace {
 
+GURL open_shortcut_url = GURL::EmptyGURL();

[Alexei Svitkine (slow), 2014/04/25 14:47:08]

Nit: g_open_shortcut_url

+
+}  // namespace
+
+@interface TestOpenShortcutOnStartup : NSObject
+- (void)applicationWillFinishLaunching:(NSNotification*)notification;
+@end
+
+@implementation TestOpenShortcutOnStartup
+
+- (void)applicationWillFinishLaunching:(NSNotification*)notification {
+  if (!open_shortcut_url.is_valid())
+    return;
+
+  AppController* controller = (AppController*)[NSApp delegate];

[Alexei Svitkine (slow), 2014/04/25 14:47:08]

Use ObjCCast() from foundation_util.h instead, which does a isKindOfClass:
check.

+  Method getUrl = class_getInstanceMethod([controller class],
+      @selector(getUrl:withReply:));
+
+  if (getUrl == nil)
+    return;
+
+  base::scoped_nsobject<NSAppleEventDescriptor> shortcutEvent(
+      [[NSAppleEventDescriptor alloc]
+          initWithEventClass:kASAppleScriptSuite
+                     eventID:kASSubroutineEvent
+            targetDescriptor:nil
+                    returnID:kAutoGenerateReturnID
+               transactionID:kAnyTransactionID]);
+  NSString* url =
+      [NSString stringWithUTF8String:open_shortcut_url.spec().c_str()];
+  [shortcutEvent setParamDescriptor:
+      [NSAppleEventDescriptor descriptorWithString:url]
+                                        forKeyword:keyDirectObject];

[Alexei Svitkine (slow), 2014/04/25 14:47:08]

Nit: Sorry, maybe my previous comment was confusing. The actual style guide rule
is to align :'s with a single call. So forKeyword: should be aligned with the :
of setParamDescriptor:

[Alexei Svitkine (slow), 2014/04/25 14:47:54]

*within a single call, rather

+
+  method_invoke(controller, getUrl, shortcutEvent.get(), NULL);
+}
+
+@end
+
+namespace {
+
 class AppControllerPlatformAppBrowserTest
     : public extensions::PlatformAppBrowserTest {
  protected:
   AppControllerPlatformAppBrowserTest()
       : active_browser_list_(BrowserList::GetInstance(
                                 chrome::GetActiveDesktop())) {
   }
 
   virtual void SetUpCommandLine(CommandLine* command_line) OVERRIDE {
     PlatformAppBrowserTest::SetUpCommandLine(command_line);
@@ skipping 177 matching lines @@
   BOOL result = [ac applicationShouldHandleReopen:NSApp hasVisibleWindows:NO];
   EXPECT_FALSE(result);
 
   base::RunLoop().RunUntilIdle();
 
   EXPECT_EQ(1u, active_browser_list_->size());
   EXPECT_TRUE(UserManagerMac::IsShowing());
   UserManagerMac::Hide();
 }
 
+class AppControllerOpenShortcutBrowserTest : public InProcessBrowserTest {
+ protected:
+  AppControllerOpenShortcutBrowserTest() {
+  }
+
+  virtual void SetUpInProcessBrowserTestFixture() OVERRIDE {
+    // In order to mimic opening shortcut during browser startup, we need to
+    // send the event before -applicationDidFinishLaunching is called, but
+    // after AppController is loaded.
+    //
+    // Since -applicationWillFinishLaunching does nothing now, we swizzle it to
+    // our function to send the event. We need to do this early before running
+    // the main message loop.
+    //
+    // NSApp does not exist yet. We need to get the AppController using
+    // reflection.
+    Class appControllerClass = NSClassFromString(@"AppController");
+    Class openShortcutClass = NSClassFromString(@"TestOpenShortcutOnStartup");
+
+    ASSERT_TRUE(appControllerClass != nil && openShortcutClass != nil);

[Alexei Svitkine (slow), 2014/04/25 14:47:08]

Nit: Can you split these into separate ASSERT lines? This would make it easier
to debug when the test fails. Same for below.

+
+    SEL targetMethod = @selector(applicationWillFinishLaunching:);
+    Method original = class_getInstanceMethod(appControllerClass,
+        targetMethod);
+    Method destination = class_getInstanceMethod(openShortcutClass,
+        targetMethod);
+
+    ASSERT_TRUE(original != NULL && destination != NULL);
+
+    method_exchangeImplementations(original, destination);
+
+    ASSERT_TRUE(embedded_test_server()->InitializeAndWaitUntilReady());
+    open_shortcut_url = embedded_test_server()->GetURL("/simple.html");
+  }
+
+  virtual void SetUpCommandLine(CommandLine* command_line) OVERRIDE {
+    // If the arg is empty, PrepareTestCommandLine() after this function will
+    // append about:blank as default url.
+    command_line->AppendArg(chrome::kChromeUINewTabURL);
+  }
+};
+
+IN_PROC_BROWSER_TEST_F(AppControllerOpenShortcutBrowserTest,
+                       OpenShortcutOnStartup) {
+  EXPECT_EQ(1, browser()->tab_strip_model()->count());
+  EXPECT_EQ(open_shortcut_url,
+      browser()->tab_strip_model()->GetActiveWebContents()
+          ->GetLastCommittedURL());
+}
+
 }  // namespace