Removes WeakNSObject in ARC files in ios/web.

ios/web/net/crw_ssl_status_updater.mm

 // Copyright 2016 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/web/net/crw_ssl_status_updater.h"
 
-#import "base/ios/weak_nsobject.h"
 #import "base/mac/scoped_nsobject.h"
 #import "base/strings/sys_string_conversions.h"
 #import "ios/web/public/navigation_item.h"
 #import "ios/web/public/navigation_manager.h"
 #include "ios/web/public/ssl_status.h"
 #import "ios/web/web_state/wk_web_view_security_util.h"
 #include "net/cert/x509_certificate.h"
 #include "url/gurl.h"
 
 #if !defined(__has_feature) || !__has_feature(objc_arc)
 #error "This file requires ARC support."
 #endif
 
 using base::ScopedCFTypeRef;
 using net::CertStatus;
 using web::SecurityStyle;
 
 @interface CRWSSLStatusUpdater () {
   // DataSource for CRWSSLStatusUpdater.
-  base::WeakNSProtocol<id<CRWSSLStatusUpdaterDataSource>> _dataSource;
-  // Backs up property of the same name.
-  base::WeakNSProtocol<id<CRWSSLStatusUpdaterDelegate>> _delegate;
+  __weak id<CRWSSLStatusUpdaterDataSource> _dataSource;
 }
 
 // Unowned pointer to web::NavigationManager.
 @property(nonatomic, readonly) web::NavigationManager* navigationManager;
 
 // Updates |security_style| and |cert_status| for the NavigationItem with ID
 // |navigationItemID|, if URL and certificate chain still match |host| and
 // |certChain|.
 - (void)updateSSLStatusForItemWithID:(int)navigationItemID
                                trust:(ScopedCFTypeRef<SecTrustRef>)trust
                                 host:(NSString*)host
                    withSecurityStyle:(SecurityStyle)style
                           certStatus:(CertStatus)certStatus;
 
 // Asynchronously obtains SSL status from given |secTrust| and |host| and
 // updates current navigation item. Before scheduling update changes SSLStatus'
 // cert_status and security_style to default.
 - (void)scheduleSSLStatusUpdateUsingTrust:(ScopedCFTypeRef<SecTrustRef>)trust
                                      host:(NSString*)host;
 
 // Notifies delegate about SSLStatus change.
 - (void)didChangeSSLStatusForNavigationItem:(web::NavigationItem*)navItem;
 
 @end
 
 @implementation CRWSSLStatusUpdater
 @synthesize navigationManager = _navigationManager;
+@synthesize delegate = _delegate;
 
 #pragma mark - Public
 
 - (instancetype)initWithDataSource:(id<CRWSSLStatusUpdaterDataSource>)dataSource
                  navigationManager:(web::NavigationManager*)navigationManager {
   DCHECK(dataSource);
   DCHECK(navigationManager);
   if (self = [super init]) {
-    _dataSource.reset(dataSource);
+    _dataSource = dataSource;
     _navigationManager = navigationManager;
   }
   return self;
 }
 
-- (id<CRWSSLStatusUpdaterDelegate>)delegate {
-  return _delegate.get();
-}
-
-- (void)setDelegate:(id<CRWSSLStatusUpdaterDelegate>)delegate {
-  _delegate.reset(delegate);
-}
-
 - (void)updateSSLStatusForNavigationItem:(web::NavigationItem*)item
                             withCertHost:(NSString*)host
                                    trust:(ScopedCFTypeRef<SecTrustRef>)trust
                     hasOnlySecureContent:(BOOL)hasOnlySecureContent {
   web::SSLStatus previousSSLStatus = item->GetSSL();
 
   // Starting from iOS9 WKWebView blocks active mixed content, so if
   // |hasOnlySecureContent| returns NO it means passive content.
   item->GetSSL().content_status =
       hasOnlySecureContent ? web::SSLStatus::NORMAL_CONTENT
@@ skipping 72 matching lines @@
   }
 }
 
 - (void)scheduleSSLStatusUpdateUsingTrust:(ScopedCFTypeRef<SecTrustRef>)trust
                                      host:(NSString*)host {
   // Use Navigation Item's unique ID to locate requested item after
   // obtaining cert status asynchronously.
   int itemID = _navigationManager->GetLastCommittedItem()->GetUniqueID();
 
   DCHECK(_dataSource);
-  base::WeakNSObject<CRWSSLStatusUpdater> weakSelf(self);
+  __weak CRWSSLStatusUpdater* weakSelf = self;
   [_dataSource SSLStatusUpdater:self
          querySSLStatusForTrust:trust
                            host:host
               completionHandler:^(SecurityStyle style, CertStatus certStatus) {
                 [weakSelf updateSSLStatusForItemWithID:itemID
                                                  trust:std::move(trust)
                                                   host:host
                                      withSecurityStyle:style
                                             certStatus:certStatus];
               }];
 }
 
 - (void)didChangeSSLStatusForNavigationItem:(web::NavigationItem*)navItem {
   if ([_delegate respondsToSelector:
           @selector(SSLStatusUpdater:didChangeSSLStatusForNavigationItem:)]) {
     [_delegate SSLStatusUpdater:self
         didChangeSSLStatusForNavigationItem:navItem];
   }
 }
 
 @end