[Mac] Preserve original selection when suggesting completions with diacritics

chrome/browser/ui/cocoa/location_bar/autocomplete_text_field_editor.mm

 // Copyright (c) 2011 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/location_bar/autocomplete_text_field_editor.h"
 
+#include "base/i18n/break_iterator.h"
+#include "base/mac/foundation_util.h"
+#include "base/mac/scoped_nsobject.h"
 #include "base/mac/sdk_forward_declarations.h"
 #include "base/strings/string_util.h"
 #include "base/strings/sys_string_conversions.h"
 #include "chrome/app/chrome_command_ids.h"  // IDC_*
 #include "chrome/browser/themes/theme_service.h"
 #include "chrome/browser/ui/browser_list.h"
 #import "chrome/browser/ui/cocoa/browser_window_controller.h"
 #import "chrome/browser/ui/cocoa/location_bar/autocomplete_text_field.h"
 #import "chrome/browser/ui/cocoa/location_bar/autocomplete_text_field_cell.h"
 #import "chrome/browser/ui/cocoa/toolbar/toolbar_controller.h"
@@ skipping 25 matching lines @@
 BOOL ThePasteboardIsTooDamnBig() {
   NSPasteboard* pb = [NSPasteboard generalPasteboard];
   NSString* type =
       [pb availableTypeFromArray:[NSArray arrayWithObject:NSStringPboardType]];
   if (!type)
     return NO;
 
   return [[pb stringForType:type] length] > kMaxPasteLength;
 }
 
+NSRange VisualSelectedRangeFromRange(NSRange range, NSString* string) {
+  if (range.location >= string.length)
+    return range;
+  base::string16 text = base::SysNSStringToUTF16(string);
+  base::i18n::BreakIterator grapheme_iterator(
+      text, base::i18n::BreakIterator::BREAK_CHARACTER);
+  if (!grapheme_iterator.Init())
+    return range;
+  // This works because NSString uses UTF-16 code units.
+  while (range.location < text.length() &&
+         !grapheme_iterator.IsGraphemeBoundary(
+             static_cast<size_t>(range.location))) {
+    range.location++;
+    if (range.length > 0)
+      range.length--;
+  }
+  return range;
+}
+
 }  // namespace
 
+// Method exposed for the purpose of overriding.
+// Used to restore model's selection range when the view doesn't
+// match the model due to combining characters.
+//
+// In some cases, (completing 'y' to 'ÿour', for example), the autocomplete
+// system requests a selection range that begins on a combining character.
+// setSelectedRange: and friends document that the range passed to them
+// "must begin and end on glyph boundaries and not split base glyphs and
+// their nonspacing marks". If passed such a range, the selection is
+// expanded to include the original user input, preventing the user
+// from being able to type other words beginning with that letter.
+//
+// To resolve this, the field editor modifies the selection to start
+// on the next glyph boundary, then keeps track of the original and
+// modified selections, substituting the original when the user takes
+// actions that operate on the selection. Since there are many methods
+// in NSResponder (for example deleteToBeginningOfLine:) that operate
+// on the selection, rather than shimming them all, we override this
+// private method that they're implemented in terms of.
+//
+@interface NSTextView (PrivateTextEditing)
+- (void)_userReplaceRange:(NSRange)range withString:(NSString*)string;
+@end
+
 @interface AutocompleteTextFieldEditor ()<NSDraggingSource>
 @end
 
 @implementation AutocompleteTextFieldEditor
 
+@synthesize actualSelectedRange = actualSelectedRange_;
+
 - (BOOL)shouldDrawInsertionPoint {
   return [super shouldDrawInsertionPoint] &&
          ![[[self delegate] cell] hideFocusState];
 }
 
 - (id)initWithFrame:(NSRect)frameRect {
   if ((self = [super initWithFrame:frameRect])) {
     dropHandler_.reset([[URLDropTargetHandler alloc] initWithView:self]);
 
     forbiddenCharacters_.reset([[NSCharacterSet controlCharacterSet] retain]);
@@ skipping 324 matching lines @@
 // (URLDropTarget protocol)
 - (void)draggingExited:(id<NSDraggingInfo>)sender {
   return [dropHandler_ draggingExited:sender];
 }
 
 // (URLDropTarget protocol)
 - (BOOL)performDragOperation:(id<NSDraggingInfo>)sender {
   return [dropHandler_ performDragOperation:sender];
 }
 
+- (void)_userReplaceRange:(NSRange)range withString:(NSString*)string {
+  if (NSEqualRanges(visualSelectedRange_, range) &&
+      !NSEqualRanges(visualSelectedRange_, actualSelectedRange_)) {
+    range = actualSelectedRange_;
+  }
+  [super _userReplaceRange:range withString:string];
+}
+
 // Prevent control characters from being entered into the Omnibox.
 // This is invoked for keyboard entry, not for pasting.
 - (void)insertText:(id)aString {
   AutocompleteTextFieldObserver* observer = [self observer];
   if (observer)
     observer->OnInsertText();
 
   // Repeatedly remove control characters.  The loop will only ever
   // execute at all when the user enters control characters (using
   // Ctrl-Alt- or Ctrl-Q).  Making this generally efficient would
@@ skipping 11 matching lines @@
   } else {
     NSRange range = [aString rangeOfCharacterFromSet:forbiddenCharacters_];
     while (range.location != NSNotFound) {
       aString =
           [aString stringByReplacingCharactersInRange:range withString:@""];
       range = [aString rangeOfCharacterFromSet:forbiddenCharacters_];
     }
     DCHECK_EQ(range.length, 0U);
   }
 
-  // NOTE: If |aString| is empty, this intentionally replaces the
-  // selection with empty.  This seems consistent with the case where
-  // the input contained a mixture of characters and the string ended
-  // up not empty.
-  [super insertText:aString];
+  if (!NSEqualRanges(visualSelectedRange_, actualSelectedRange_)) {
+    [super replaceCharactersInRange:actualSelectedRange_ withString:aString];
+  } else {
+    // NOTE: If |aString| is empty, this intentionally replaces the
+    // selection with empty.  This seems consistent with the case where
+    // the input contained a mixture of characters and the string ended
+    // up not empty.
+    [super insertText:aString];
+  }
 }
 
 - (NSRange)selectionRangeForProposedRange:(NSRange)proposedSelRange
                               granularity:(NSSelectionGranularity)granularity {
   AutocompleteTextFieldObserver* observer = [self observer];
   NSRange modifiedRange = [super selectionRangeForProposedRange:proposedSelRange
                                                     granularity:granularity];
   if (observer)
     return observer->SelectionRangeForProposedRange(modifiedRange);
   return modifiedRange;
 }
 
 - (void)setSelectedRange:(NSRange)charRange
                 affinity:(NSSelectionAffinity)affinity
           stillSelecting:(BOOL)flag {
   [super setSelectedRange:charRange affinity:affinity stillSelecting:flag];
 
   // We're only interested in selection changes directly caused by keyboard
   // input from the user.
   if (interpretingKeyEvents_)
     textChangedByKeyEvents_ = YES;
 }
 
+- (void)setSelectedRanges:(NSArray*)ranges
+                 affinity:(NSSelectionAffinity)affinity
+           stillSelecting:(BOOL)flag {
+  DCHECK(ranges.count > 0);
+  base::scoped_nsobject<NSMutableArray> mutableRanges([ranges mutableCopy]);
+  // |ranges| is sorted, and empirically, the first range passed is returned
+  // as selectedRange.
+  NSRange firstRange = [base::mac::ObjCCastStrict<NSValue>(
+      [mutableRanges firstObject]) rangeValue];
+  actualSelectedRange_ = firstRange;
+  visualSelectedRange_ =
+      VisualSelectedRangeFromRange(firstRange, [self string]);
+  NSValue* boxedVisualRange = [NSValue valueWithRange:visualSelectedRange_];
+  [mutableRanges replaceObjectAtIndex:0 withObject:boxedVisualRange];
+
+  [super setSelectedRanges:mutableRanges affinity:affinity stillSelecting:flag];
+}
+
 - (void)interpretKeyEvents:(NSArray *)eventArray {
   DCHECK(!interpretingKeyEvents_);
   interpretingKeyEvents_ = YES;
   textChangedByKeyEvents_ = NO;
   AutocompleteTextFieldObserver* observer = [self observer];
 
   if (observer)
     observer->OnBeforeChange();
 
   [super interpretKeyEvents:eventArray];
@@ skipping 85 matching lines @@
   [textStorage setAttributedString:aString];
 
   // The text has been changed programmatically. The observer should know
   // this change, so setting |textChangedByKeyEvents_| to NO to
   // prevent its OnDidChange() method from being called unnecessarily.
   textChangedByKeyEvents_ = NO;
 }
 
 - (BOOL)validateMenuItem:(NSMenuItem*)item {
   if ([item action] == @selector(copyToFindPboard:))
-    return [self selectedRange].length > 0;
+    return actualSelectedRange_.length > 0;
   if ([item action] == @selector(pasteAndGo:)) {
     // TODO(rohitrao): If the clipboard is empty, should we show a
     // greyed-out "Paste and Go" or nothing at all?
     AutocompleteTextFieldObserver* observer = [self observer];
     DCHECK(observer);
     return observer->CanPasteAndGo();
   }
   return [super validateMenuItem:item];
 }
 
 - (void)copyToFindPboard:(id)sender {
-  NSRange selectedRange = [self selectedRange];
-  if (selectedRange.length == 0)
+  if (actualSelectedRange_.length == 0)
     return;
   NSAttributedString* selection =
-      [self attributedSubstringForProposedRange:selectedRange
+      [self attributedSubstringForProposedRange:actualSelectedRange_
                                     actualRange:NULL];
   if (!selection)
     return;
 
   [[FindPasteboard sharedInstance] setFindText:[selection string]];
 }
 
 - (void)drawRect:(NSRect)rect {
   [super drawRect:rect];
   autocomplete_text_field::DrawGrayTextAutocompletion(
@@ skipping 10 matching lines @@
 // ThemedWindowDrawing implementation.
 
 - (void)windowDidChangeTheme {
   [self updateColorsToMatchTheme];
 }
 
 - (void)windowDidChangeActive {
 }
 
 @end