[ARC] Converts parts of ios/web/web_state to ARC.

ios/web/web_state/crw_web_view_scroll_view_proxy.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/web/public/web_state/crw_web_view_scroll_view_proxy.h"
 
+#import <objc/runtime.h>

[marq (ping after 24h), 2016/10/04 12:49:05]

Is this needed?

[stkhapugin, 2016/10/04 13:02:50]

Yes, before it was transitevly included from base/ios/weak_nsobject.h

+
 #include "base/auto_reset.h"
 #import "base/ios/crb_protocol_observers.h"
-#import "base/ios/weak_nsobject.h"
 #include "base/mac/foundation_util.h"
 #import "base/mac/scoped_nsobject.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 @interface CRWWebViewScrollViewProxy () {
-  base::WeakNSObject<UIScrollView> _scrollView;
+  __weak UIScrollView* _scrollView;
   base::scoped_nsobject<id> _observers;

[marq (ping after 24h), 2016/10/04 12:49:05]

Why not convert this to a strong property as well? Or is that happening in a
different set of changes?

[stkhapugin, 2016/10/04 13:02:50]

The plan is to remove scoped_nsobject boilerplate at a later stage, yes. Doing
this now will generate a lot more changed code, which will put a lot of load on
reviewers. 

   // When |_ignoreScroll| is set to YES, do not pass on -scrollViewDidScroll
   // calls to observers.  This is used by -setContentInsetFast, which needs to
   // update and reset the contentOffset to force a fast update.  These updates
   // should be a no-op for the contentOffset, so the callbacks can be ignored.
   BOOL _ignoreScroll;
 }
 
 // Returns the key paths that need to be observed for UIScrollView.
 + (NSArray*)scrollViewObserverKeyPaths;
 
 // Adds and removes |self| as an observer for |scrollView| with key paths
 // returned by |+scrollViewObserverKeyPaths|.
 - (void)startObservingScrollView:(UIScrollView*)scrollView;
 - (void)stopObservingScrollView:(UIScrollView*)scrollView;
 
 @end
 
 @implementation CRWWebViewScrollViewProxy
 
 - (instancetype)init {
   self = [super init];
   if (self) {
     Protocol* protocol = @protocol(CRWWebViewScrollViewProxyObserver);
-    _observers.reset(
-        [[CRBProtocolObservers observersWithProtocol:protocol] retain]);
+    _observers.reset([CRBProtocolObservers observersWithProtocol:protocol]);
   }
   return self;
 }
 
 - (void)dealloc {
   [self stopObservingScrollView:_scrollView];
-  [super dealloc];
 }
 
 - (void)addGestureRecognizer:(UIGestureRecognizer*)gestureRecognizer {
   [_scrollView addGestureRecognizer:gestureRecognizer];
 }
 
 - (void)removeGestureRecognizer:(UIGestureRecognizer*)gestureRecognizer {
   [_scrollView removeGestureRecognizer:gestureRecognizer];
 }
 
 - (void)addObserver:(id<CRWWebViewScrollViewProxyObserver>)observer {
   [_observers addObserver:observer];
 }
 
 - (void)removeObserver:(id<CRWWebViewScrollViewProxyObserver>)observer {
   [_observers removeObserver:observer];
 }
 
 - (void)setScrollView:(UIScrollView*)scrollView {
   if (_scrollView == scrollView)
     return;
   [_scrollView setDelegate:nil];
   [self stopObservingScrollView:_scrollView];
   DCHECK(!scrollView.delegate);
   scrollView.delegate = self;
   [self startObservingScrollView:scrollView];
-  _scrollView.reset(scrollView);
+  _scrollView = scrollView;
   [_observers webViewScrollViewProxyDidSetScrollView:self];
 }
 
 - (CGRect)frame {
   return _scrollView ? [_scrollView frame] : CGRectZero;
 }
 
 - (BOOL)isScrollEnabled {
   return [_scrollView isScrollEnabled];
 }
@@ skipping 49 matching lines @@
   });
   scrollViewSetContentInsetImpl(_scrollView, setContentInset, contentInset);
 
   // Change and then reset the contentOffset to force the view into updating the
   // absolute position of elements and content frame. Updating the
   // contentOffset will cause the -scrollViewDidScroll callback to fire.
   // Because we are eventually setting the contentOffset back to it's original
   // position, we can ignore these calls.
   base::AutoReset<BOOL> autoReset(&_ignoreScroll, YES);
   CGPoint contentOffset = [_scrollView contentOffset];
-  _scrollView.get().contentOffset =
-      CGPointMake(contentOffset.x, contentOffset.y + 1);
-  _scrollView.get().contentOffset = contentOffset;
+  _scrollView.contentOffset = CGPointMake(contentOffset.x, contentOffset.y + 1);
+  _scrollView.contentOffset = contentOffset;
 }
 
 - (void)setContentInset:(UIEdgeInsets)contentInset {
   [_scrollView setContentInset:contentInset];
 }
 
 - (UIEdgeInsets)contentInset {
   return _scrollView ? [_scrollView contentInset] : UIEdgeInsetsZero;
 }
 
@@ skipping 100 matching lines @@
 
 - (void)stopObservingScrollView:(UIScrollView*)scrollView {
   for (NSString* keyPath in [[self class] scrollViewObserverKeyPaths])
     [scrollView removeObserver:self forKeyPath:keyPath];
 }
 
 - (void)observeValueForKeyPath:(NSString*)keyPath
                       ofObject:(id)object
                         change:(NSDictionary*)change
                        context:(void*)context {
-  DCHECK_EQ(object, _scrollView.get());
+  DCHECK_EQ(object, _scrollView);
   if ([keyPath isEqualToString:@"contentSize"])
     [_observers webViewScrollViewDidResetContentSize:self];
 }
 
 @end