Add ui devtools server

ui/devtools/BUILD.gn

+# Copyright 2016 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+_inspector_protocol = "//third_party/WebKit/Source/platform/inspector_protocol"
+import("//build/config/ui.gni")
+import("$_inspector_protocol/inspector_protocol.gni")
+
+_protocol_generated = [
+  "DOM.cpp",
+  "DOM.h",
+  "Forward.h",
+  "Protocol.cpp",
+  "Protocol.h",
+]
+
+action("protocol_compatibility") {
+  visibility = [ ":*" ]  # Only targets in this file can depend on this.
+  script = "$_inspector_protocol/CheckProtocolCompatibility.py"
+  inputs = [
+    "protocol.json",
+  ]
+
+  _stamp = "$target_gen_dir/protocol.stamp"
+  outputs = [
+    _stamp,
+  ]
+
+  args = [
+    "--stamp",
+    rebase_path(_stamp, root_build_dir),
+    rebase_path("protocol.json", root_build_dir),
+  ]
+}
+
+inspector_protocol_generate("protocol_generated_sources") {
+  visibility = [ ":*" ]  # Only targets in this file can depend on this.
+
+  deps = [
+    ":protocol_compatibility",
+  ]
+
+  out_dir = target_gen_dir
+  config_file = "inspector_protocol_config.json"
+  inputs = [
+    "protocol.json",
+    "inspector_protocol_config.json",
+  ]
+
+  outputs = _protocol_generated
+}
+
+source_set("devtools") {
+  sources = rebase_path(_protocol_generated, ".", target_gen_dir)
+  sources += [
+    "devtools_client.cc",
+    "devtools_client.h",
+    "devtools_server.cc",
+    "devtools_server.h",
+    "protocol_platform.h",
+    "string_util.cc",
+    "string_util.h",
+    "switches.cc",
+    "switches.h",
+  ]
+
+  configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
+
+  deps = [
+    ":protocol_generated_sources",
+    "//base",
+    "//net:http_server",
+  ]
+}