[Bindings] Pass files to compute_interfaces_info_individual.py in one way

third_party/WebKit/Source/bindings/scripts/scripts.gni

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//third_party/WebKit/Source/core/core_idl_files.gni")
 import("//third_party/WebKit/Source/modules/modules_idl_files.gni")
 
 bindings_scripts_dir = get_path_info(".", "abspath")
 bindings_scripts_output_dir = "$root_gen_dir/blink/bindings/scripts"
 
@@ skipping 39 matching lines @@
                                      "v8_methods.py",
                                      "v8_types.py",
                                      "v8_union.py",
                                      "v8_utilities.py",
                                    ],
                                    "abspath")
 
 # Calls the compute_interfaces_info_individual script.
 #
 # Parameters:
-#   sources_static = list of IDL files to pass as inputs
-#   sources_generated = list of generated IDL files to pass as inputs
-#   component_dir = name if subdirectory (one word, no slashes) of component.
+#   sources = list of IDL files to pass as inputs
 #   interfaces_info_file = output pickle file for interfaces info.
 #   component_info_file = output pickle file for component wide info.
 #   deps = dependencies
-#
-# FIXME: Note the static/generated split is for consistency with GYP. This
-# split is not necessary in the GN build and could be combined into a single
-# "sources".
 template("compute_interfaces_info_individual") {
   action(target_name) {
     script = "$bindings_scripts_dir/compute_interfaces_info_individual.py"
     if (defined(invoker.visibility)) {
       visibility = invoker.visibility
     }
 
-    # Save static list to temp file to avoid blowing out command-line length
-    # limit.
-    file_list = "$target_gen_dir/${target_name}_file_list.txt"
-    write_file(file_list, rebase_path(invoker.sources_static, root_build_dir))
-
-    inputs = [
-               "$bindings_scripts_dir/utilities.py",
-               file_list,
-             ] + invoker.sources_static + invoker.sources_generated
-
+    inputs = [ "$bindings_scripts_dir/utilities.py" ] + invoker.sources
     outputs = [
       invoker.interfaces_info_file,
       invoker.component_info_file,
     ]
 
+    response_file_contents = rebase_path(invoker.sources, root_build_dir)

[bashi, 2016/09/26 06:26:26]

Help me understand: what does 'response' mean here?

[Yuki, 2016/09/26 06:44:33]

It seems we don't need to struggle with naming if we inline |rebase_path(...)|.

[peria, 2016/09/26 06:47:30]

This is a meta variable feature of GN to store a GN list into a temporary file
to avoid blowing out command line length limit.
See "gn help response_file_contents" in your command line, or
https://chromium.googlesource.com/chromium/src/+/master/tools/gn/docs/referen...

     args = [
-             "--cache-directory",
-             rebase_path(bindings_scripts_output_dir, root_build_dir),
-             "--idl-files-list",
-             rebase_path(file_list, root_build_dir),
-             "--interfaces-info-file",
-             rebase_path(invoker.interfaces_info_file, root_build_dir),
-             "--component-info-file",
-             rebase_path(invoker.component_info_file, root_build_dir),
-             "--write-file-only-if-changed=1",
-             "--",
-           ] + rebase_path(invoker.sources_generated, root_build_dir)
+      "--cache-directory",
+      rebase_path(bindings_scripts_output_dir, root_build_dir),
+      "--idl-files-list",
+      "{{response_file_name}}",
+      "--interfaces-info-file",
+      rebase_path(invoker.interfaces_info_file, root_build_dir),
+      "--component-info-file",
+      rebase_path(invoker.component_info_file, root_build_dir),
+      "--write-file-only-if-changed=1",
+    ]
 
     deps = [ "//third_party/WebKit/Source/bindings/scripts:cached_lex_yacc_tables" ] + invoker.deps
   }
 }
 
 # Calls generate_event_interfaces
 #
 # Parameters:
 #   sources = A list of IDL files to process.
 #   output_file = The .in file to write, relative to the blink_gen_dir.
@@ skipping 270 matching lines @@
       args += [ rebase_path(output_idl_file, root_build_dir) ]
       output_idl_files += [ output_idl_file ]
       output_header_files +=
           [ "$output_dir/${interface}${component}Constructors.h" ]
     }
 
     outputs = output_idl_files + output_header_files
     deps = invoker.deps
   }
 }