[Mac/GN] Add a product_type option to mac_app_bundle.

build/config/mac/rules.gni

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/mac/base_rules.gni")
 
 # Generates Info.plist files for Mac apps and frameworks.
 #
 # Arguments
 #
@@ skipping 382 matching lines @@
 }
 
 set_defaults("mac_framework_bundle") {
   configs = default_shared_library_configs
 }
 
 # Template to create a Mac executable application bundle.
 #
 # Arguments
 #
+#     package_type:
+#         (optional) string, the product package type to create. Options are:
+#             "app" to create a .app bundle (default)
+#             "xpc" to create an .xpc service bundle
+#
 #     info_plist:
 #         (optional) string, path to the Info.plist file that will be used for
 #         the bundle.
 #
 #     info_plist_target:
 #         (optional) string, if the info_plist is generated from an action,
 #         rather than a regular source file, specify the target name in lieu
 #         of info_plist. The two arguments are mutually exclusive.
 #
 #     output_name:
@@ skipping 10 matching lines @@
 #     extra_substitutions:
 #         (optional) string array, 'key=value' pairs for extra fields which are
 #         specified in a source Info.plist template.
 template("mac_app_bundle") {
   _target_name = target_name
   _output_name = target_name
   if (defined(invoker.output_name)) {
     _output_name = invoker.output_name
   }
 
+  _package_type = "app"
+  if (defined(invoker.package_type)) {
+    _package_type = invoker.package_type
+  }
+
+  if (_package_type == "app") {
+    _output_extension = "app"
+    _product_type = "com.apple.product-type.application"
+    _write_pkg_info = true
+  } else if (_package_type == "xpc") {
+    _output_extension = "xpc"
+    _product_type = "com.apple.product-type.xpc-service"
+    _write_pkg_info = false
+  } else {
+    assert(false, "Unsupported packge_type: " + packge_type)
+  }
+
   _executable_target = target_name + "_executable"
   _executable_bundle_data = _executable_target + "_bundle_data"
 
   _info_plist_target = target_name + "_info_plist"
 
   mac_info_plist(_info_plist_target) {
     executable_name = _output_name
     forward_variables_from(invoker,
                            [
                              "extra_substitutions",
                              "info_plist",
                              "info_plist_target",
                              "testonly",
                            ])
   }
 
-  _pkg_info_target = target_name + "_pkg_info"
+  if (_write_pkg_info) {
+    _pkg_info_target = target_name + "_pkg_info"
 
-  action(_pkg_info_target) {
-    forward_variables_from(invoker, [ "testonly" ])
-    script = "//build/config/mac/write_pkg_info.py"
-    sources = get_target_outputs(":$_info_plist_target")
-    outputs = [
-      "$target_gen_dir/$_pkg_info_target",
-    ]
-    args = [ "--plist" ] + rebase_path(sources, root_build_dir) +
-           [ "--output" ] + rebase_path(outputs, root_build_dir)
-    deps = [
-      ":$_info_plist_target",
-    ]
+    action(_pkg_info_target) {
+      forward_variables_from(invoker, [ "testonly" ])
+      script = "//build/config/mac/write_pkg_info.py"
+      sources = get_target_outputs(":$_info_plist_target")
+      outputs = [
+        "$target_gen_dir/$_pkg_info_target",
+      ]
+      args = [ "--plist" ] + rebase_path(sources, root_build_dir) +
+             [ "--output" ] + rebase_path(outputs, root_build_dir)
+      deps = [
+        ":$_info_plist_target",
+      ]
+    }
   }
 
   executable(_executable_target) {
     visibility = [ ":$_executable_bundle_data" ]
     forward_variables_from(invoker,
                            "*",
                            [
                              "assert_no_deps",
                              "data_deps",
                              "info_plist",
@@ skipping 31 matching lines @@
     visibility = [ ":$_target_name" ]
     sources = get_target_outputs(":$_info_plist_target")
     outputs = [
       "{{bundle_root_dir}}/Info.plist",
     ]
     public_deps = [
       ":$_info_plist_target",
     ]
   }
 
-  _pkg_info_bundle_data = _pkg_info_target + "_bundle_data"
+  if (_write_pkg_info) {
+    _pkg_info_bundle_data = _pkg_info_target + "_bundle_data"
 
-  bundle_data(_pkg_info_bundle_data) {
-    forward_variables_from(invoker, [ "testonly" ])
-    visibility = [ ":$_target_name" ]
-    sources = get_target_outputs(":$_pkg_info_target")
-    outputs = [
-      "{{bundle_root_dir}}/PkgInfo",
-    ]
-    public_deps = [
-      ":$_pkg_info_target",
-    ]
+    bundle_data(_pkg_info_bundle_data) {
+      forward_variables_from(invoker, [ "testonly" ])
+      visibility = [ ":$_target_name" ]
+      sources = get_target_outputs(":$_pkg_info_target")
+      outputs = [
+        "{{bundle_root_dir}}/PkgInfo",
+      ]
+      public_deps = [
+        ":$_pkg_info_target",
+      ]
+    }
   }
 
   create_bundle(_target_name) {
     forward_variables_from(invoker,
                            [
                              "data_deps",
                              "deps",
                              "public_deps",
                              "testonly",
                            ])
     if (!defined(deps)) {
       deps = []
     }
     deps += [
       ":$_executable_bundle_data",
       ":$_info_plist_bundle_data",
-      ":$_pkg_info_bundle_data",
     ]
-    product_type = "com.apple.product-type.application"
-    bundle_root_dir = "$root_out_dir/${_output_name}.app/Contents"
+    if (_write_pkg_info) {
+      deps += [ ":$_pkg_info_bundle_data" ]
+    }
+    product_type = _product_type
+    bundle_root_dir =
+        "$root_out_dir/${_output_name}.${_output_extension}/Contents"
     bundle_resources_dir = "$bundle_root_dir/Resources"
     bundle_executable_dir = "$bundle_root_dir/MacOS"
   }
 }
 
 # Template to package a loadable_module into a .plugin bundle.
 #
 # This takes no extra arguments that differ from a loadable_module.
 template("mac_plugin_bundle") {
   assert(defined(invoker.deps),
@@ skipping 47 matching lines @@
                            ])
     if (!defined(deps)) {
       deps = []
     }
     deps += [ ":$_loadable_module_bundle_data" ]
 
     bundle_root_dir = "$root_out_dir/$_output_name.plugin/Contents"
     bundle_executable_dir = "$bundle_root_dir/MacOS"
   }
 }