Ensure the sanitizer runtime library is copied to app bundle if enabled.

build/config/sanitizers/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build_overrides/build.gni")
 import("//build/config/chrome_build.gni")
 import("//build/config/chromecast_build.gni")
 import("//build/config/clang/clang.gni")
 import("//build/config/sanitizers/sanitizers.gni")
 import("//build/toolchain/toolchain.gni")
 
+if (is_ios) {
+  import("//build/config/ios/ios_sdk.gni")
+}
+
 # Contains the dependencies needed for sanitizers to link into executables and
 # shared_libraries. Unconditionally depend upon this target as it is empty if
 # |is_asan|, |is_lsan|, |is_tsan|, |is_msan| and |use_custom_libcxx| are false.
 group("deps") {
   public_deps = [
     ":deps_no_options",
   ]
   if (using_sanitizer) {
     public_configs = [
       ":sanitizer_options_link_helper",
@@ skipping 43 matching lines @@
     }
     if (use_custom_libcxx) {
       public_deps += [ "//buildtools/third_party/libc++:libcxx_proxy" ]
       data += [ "$root_out_dir/libc++.so" ]
     }
     if (is_mac || is_win) {
       data_deps = [
         ":copy_asan_runtime",
       ]
     }
-    if (is_mac) {
+    if (is_mac || (is_ios && !use_xcode_clang)) {

[Dirk Pranke, 2016/09/27 17:54:44]

Can we use the sanitizers w/ xcode_clang at all? Maybe using_sanitizer should be
checking for that instead?

[sdefresne, 2016/09/28 14:01:46]

Yes we can use asan and clang Xcode as the version of clang shipping with Xcode
does provide the necessary runtime library. This requires selecting ASAN support
in Xcode for the moment as the runtime library is incompatible (it is versioned)
but Xcode helpfully copy it when ASAN is enabled in Xcode.

I may in the future extend this to support copying the clang runtime library
from Xcode when using Xcode clang, but it will require some invasive change to
ios_sdk.gni.

[Dirk Pranke, 2016/09/28 16:24:37]

Okay. Well, given that xcode clang isn't our first choice for compilers, I don't
think we should put in any work to support that condition unless we get to a
point where we're stuck building w/ xcode clang for an indefinite time, so I
wouldn't put the effort in for that.

       public_deps += [ ":asan_runtime_bundle_data" ]
     }
   }
 }
 
-if ((is_mac || is_win) && using_sanitizer) {
-  copy("copy_asan_runtime") {
-    if (is_mac) {
-      clang_rt_dso_path = "darwin/libclang_rt.asan_osx_dynamic.dylib"
-    } else if (is_win && target_cpu == "x86") {
-      clang_rt_dso_path = "windows/clang_rt.asan_dynamic-i386.dll"
-    } else if (is_win && target_cpu == "x64") {
-      clang_rt_dso_path = "windows/clang_rt.asan_dynamic-x86_64.dll"
-    }
-    sources = [
-      "$clang_base_path/lib/clang/$clang_version/lib/$clang_rt_dso_path",
-    ]
-    outputs = [
-      "$root_out_dir/{{source_file_part}}",
-    ]
+if ((is_mac || is_win || (is_ios && !use_xcode_clang)) && using_sanitizer) {
+  if (is_mac) {
+    _clang_rt_dso_path = "darwin/libclang_rt.asan_osx_dynamic.dylib"
+  } else if (is_ios) {
+    _clang_rt_dso_path = "darwin/libclang_rt.asan_iossim_dynamic.dylib"
+  } else if (is_win && target_cpu == "x86") {
+    _clang_rt_dso_path = "windows/clang_rt.asan_dynamic-i386.dll"
+  } else if (is_win && target_cpu == "x64") {
+    _clang_rt_dso_path = "windows/clang_rt.asan_dynamic-x86_64.dll"
   }
 
-  if (is_mac) {
+  _clang_rt_dso_full_path =
+      "$clang_base_path/lib/clang/$clang_version/lib/$_clang_rt_dso_path"
+
+  if (!is_ios) {
+    copy("copy_asan_runtime") {
+      sources = [
+        _clang_rt_dso_full_path,
+      ]
+      outputs = [
+        "$root_out_dir/{{source_file_part}}",
+      ]
+    }
+  } else {
+    # On iOS, the runtime library need to be code signed (adhoc signature)
+    # starting with Xcode 8, so use an action instead of a copy on iOS.
+    action("copy_asan_runtime") {

[justincohen, 2016/09/27 18:08:23]

copy_and_sign_asan_runtime?

[sdefresne, 2016/09/28 14:01:46]

That would make the BUILD file unnecessarily complex (as I'll have to
conditionally define a variable with the name of this target, and use the
variable instead of the target name) for little benefit (having a more accurate
target name on iOS).

I won't do this change.

+      script = "//build/config/ios/codesign.py"
+      sources = [
+        _clang_rt_dso_full_path,
+      ]
+      outputs = [
+        "$root_out_dir/" + get_path_info(sources[0], "file"),
+      ]
+      args = [
+        "code-sign-file",
+        "--identity=" + ios_code_signing_identity,
+        "--output=" + rebase_path(outputs[0], root_build_dir),
+        rebase_path(sources[0], root_build_dir),
+      ]
+    }
+  }
+
+  if (is_mac || is_ios) {
     bundle_data("asan_runtime_bundle_data") {
       sources = get_target_outputs(":copy_asan_runtime")
       outputs = [
         "{{bundle_executable_dir}}/{{source_file_part}}",
       ]
       public_deps = [
         ":copy_asan_runtime",
       ]
     }
   }
 }
 
 config("sanitizer_options_link_helper") {
-  if (is_mac) {
+  if (is_mac || is_ios) {
     ldflags = [ "-Wl,-U,_sanitizer_options_link_helper" ]
   } else if (!is_win) {
     ldflags = [ "-Wl,-u_sanitizer_options_link_helper" ]
   }
 }
 
 static_library("options_sources") {
   # This is a static_library instead of a source_set, as it shouldn't be
   # unconditionally linked into targets.
   visibility = [
@@ skipping 378 matching lines @@
 # This allows to selectively disable ubsan_vptr, when needed. In particular,
 # if some third_party code is required to be compiled without rtti, which
 # is a requirement for ubsan_vptr.
 config("default_sanitizer_flags_but_ubsan_vptr") {
   configs = all_sanitizer_configs - [ ":ubsan_vptr_flags" ]
 }
 
 config("default_sanitizer_flags_but_coverage") {
   configs = all_sanitizer_configs - [ ":coverage_flags" ]
 }