[merge-m54] Mac: Hack around Sierra autolayout bug in the certificate viewer.

chrome/browser/ui/cocoa/certificate_viewer_mac.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/certificate_viewer_mac.h"
 
 #include <Security/Security.h>
 #include <SecurityInterface/SFCertificatePanel.h>
+#import <objc/runtime.h>
 #include <vector>
 
 #include "base/mac/foundation_util.h"
+#include "base/mac/mac_util.h"
 #include "base/mac/scoped_cftyperef.h"
 #include "base/macros.h"
 #include "chrome/browser/certificate_viewer.h"
 #import "chrome/browser/ui/cocoa/constrained_window/constrained_window_mac.h"
 #import "chrome/browser/ui/cocoa/constrained_window/constrained_window_sheet.h"
 #import "chrome/browser/ui/cocoa/constrained_window/constrained_window_sheet_controller.h"
 #include "net/cert/x509_certificate.h"
 #include "net/cert/x509_util_mac.h"
 #import "ui/base/cocoa/window_size_constants.h"
 
 class SSLCertificateViewerCocoaBridge;
 
+namespace {
+
+// The maximum height of the certificate panel. Imposed whenever Sierra's buggy
+// autolayout algorithm tries to change it. Doesn't affect user resizes.
+const CGFloat kMaxPanelSetFrameHeight = 400;
+
+// Pointer to the real implementation of -[SFCertificatePanel setFrame:..]. This
+// is cached so a correct lookup is performed before we add the override.
+IMP g_real_certificate_panel_setframe = nullptr;
+
+// Provide a workaround for a buggy autolayout algorithm in macOS Sierra when
+// running Chrome linked against the 10.10 SDK on macOS 10.12.
+// See http://crbug.com/643123 for more details.
+// Note it's not possible to inherit from SFCertificatePanel without triggering
+// *** Assertion failure in -[BrowserCrApplication
+// _commonBeginModalSessionForWindow:relativeToWindow:modalDelegate:
+// didEndSelector:contextInfo:], .../AppKit.subproj/NSApplication.m:4077
+// After that assertion, the sheet simply refuses to continue loading.
+// It's also not possible to swizzle the -setFrame: method because
+// SFCertificatePanel doesn't define it. Attempting to swizzle that would
+// replace the implementation on NSWindow and constrain all dialogs.
+// So, provide a regular C method and append it to the SFCertificatePanel
+// implementation using the objc runtime.
+// TODO(tapted): Remove all of this when Chrome's SDK target gets bumped.
+id SFCertificatePanelSetFrameOverride(id self,
+                                      SEL _cmd,
+                                      NSRect frame,
+                                      BOOL display,
+                                      BOOL animate) {
+  if (frame.size.height > kMaxPanelSetFrameHeight)
+    frame.size.height = kMaxPanelSetFrameHeight;
+
+  DCHECK(g_real_certificate_panel_setframe);
+  return g_real_certificate_panel_setframe(self, _cmd, frame, display, animate);
+}
+
+void MaybeConstrainPanelSizeForSierraBug() {
+#if defined(MAC_OS_X_VERSION_10_11) && \
+    MAC_OS_X_VERSION_MAX_ALLOWED >= MAC_OS_X_VERSION_10_11
+  // This is known not to be required when linking against the 10.11 SDK. Early
+  // exit in that case but assume anything earlier is broken.
+  return;
+#endif
+
+  // It's also not required when running on El Capitan or earlier.
+  if (base::mac::IsAtMostOS10_11() || g_real_certificate_panel_setframe)
+    return;
+
+  const SEL kSetFrame = @selector(setFrame:display:animate:);
+  Method real_method =
+      class_getInstanceMethod([SFCertificatePanel class], kSetFrame);
+  const char* type_encoding = method_getTypeEncoding(real_method);
+  g_real_certificate_panel_setframe = method_getImplementation(real_method);
+  DCHECK(g_real_certificate_panel_setframe);
+  IMP method = reinterpret_cast<IMP>(&SFCertificatePanelSetFrameOverride);
+  BOOL method_added = class_addMethod([SFCertificatePanel class], kSetFrame,
+                                      method, type_encoding);
+  DCHECK(method_added);
+}
+
+}  // namespace
+
 @interface SFCertificatePanel (SystemPrivate)
 // A system-private interface that dismisses a panel whose sheet was started by
 // -beginSheetForWindow:
 //        modalDelegate:
 //       didEndSelector:
 //          contextInfo:
 //         certificates:
 //            showGroup:
 // as though the user clicked the button identified by returnCode. Verified
 // present in 10.8.
@@ skipping 103 matching lines @@
   constrainedWindow_ =
       CreateAndShowWebModalDialogMac(observer_.get(), webContents, self);
 }
 
 - (NSWindow*)overlayWindow {
   return overlayWindow_;
 }
 
 - (void)showSheetForWindow:(NSWindow*)window {
   overlayWindow_.reset([window retain]);
+
+  MaybeConstrainPanelSizeForSierraBug();
+
   [panel_ beginSheetForWindow:window
                 modalDelegate:self
                didEndSelector:@selector(sheetDidEnd:
                                          returnCode:
                                             context:)
                   contextInfo:NULL
                  certificates:certificates_
                     showGroup:YES];
 }
 
@@ skipping 42 matching lines @@
   return panel_;
 }
 
 - (void)onConstrainedWindowClosed {
   panel_.reset();
   constrainedWindow_.reset();
   [self release];
 }
 
 @end