Add framework for sending feedback for Blimp.

blimp/client/core/feedback/BUILD.gn

Index: blimp/client/core/feedback/BUILD.gn
diff --git a/blimp/client/core/feedback/BUILD.gn b/blimp/client/core/feedback/BUILD.gn
new file mode 100644
index 0000000000000000000000000000000000000000..4981e304c032507207226a21e5ff98ebfbcaac39
--- /dev/null
+++ b/blimp/client/core/feedback/BUILD.gn
@@ -0,0 +1,67 @@
+# Copyright 2016 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+if (is_android) {
+  import("//build/config/android/config.gni")
+  import("//build/config/android/rules.gni")
+}
+
+source_set("feedback") {
+  visibility = [ "//blimp/client/core/*" ]
+
+  sources = [
+    "blimp_feedback_data.cc",
+    "blimp_feedback_data.h",
+  ]
+
+  deps = [
+    "//base",
+  ]
+
+  if (is_android) {
+    sources += [
+      "android/blimp_feedback_data_android.cc",
+      "android/blimp_feedback_data_android.h",
+    ]
+
+    deps += [ ":feedback_jni_headers" ]
+  }
+}
+
+source_set("unit_tests") {
+  visibility = [ "//blimp/client/core:unit_tests" ]
+
+  testonly = true
+
+  sources = [
+    "blimp_feedback_data_unittest.cc",
+  ]
+
+  deps = [
+    ":feedback",
+    "//testing/gtest",
+  ]
+}
+
+if (is_android) {
+  android_library("feedback_java") {
+    visibility = [ "//blimp/client/core/*" ]
+
+    java_files = [ "android/java/src/org/chromium/blimp/core/feedback/BlimpFeedbackData.java" ]
+
+    deps = [
+      "//base:base_java",
+    ]
+  }
+
+  generate_jni("feedback_jni_headers") {
+    visibility = [ ":*" ]
+
+    sources = [
+      "android/java/src/org/chromium/blimp/core/feedback/BlimpFeedbackData.java",
+    ]
+
+    jni_package = "blimp/client/core"
+  }
+}