GN: add skia_use_mesa for OSMesa in tools.

BUILD.gn

 # Copyright 2016 Google Inc.
 #
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("gn/shared_sources.gni")
 
 declare_args() {
   skia_use_expat = true
   skia_use_fontconfig = is_linux
   skia_use_freetype = is_android || is_fuchsia || is_linux
   skia_use_giflib = !is_fuchsia
   skia_use_libjpeg_turbo = true
   skia_use_libpng = true
   skia_use_libwebp = !is_fuchsia
+  skia_use_mesa = false
   skia_use_sfntly = !is_fuchsia
   skia_use_vulkan = is_android && defined(ndk_api) && ndk_api >= 24
   skia_use_zlib = true
 
   skia_enable_android_framework_defines = false
   skia_enable_gpu = true
   skia_enable_tools = !is_fuchsia
 }
 
 # Our tools require static linking (they use non-exported symbols) and GPU support (just lazy).
@@ skipping 562 matching lines @@
       ":skia.h",
     ]
   }
 }
 
 # Targets guarded by skia_enable_tools may use //third_party freely.
 if (skia_enable_tools) {
   template("test_lib") {
     config(target_name + "_config") {
       include_dirs = invoker.public_include_dirs
+      if (defined(invoker.public_defines)) {
+        defines = invoker.public_defines
+      }
     }
     source_set(target_name) {
       forward_variables_from(invoker, "*", [ "public_include_dirs" ])
       public_configs = [
         ":" + target_name + "_config",
         ":skia_private",
       ]
 
       if (!defined(deps)) {
         deps = []
       }
       deps += [ ":skia" ]
       testonly = true
     }
   }
 
   test_lib("gpu_tool_utils") {
+    public_defines = []
     public_include_dirs = [ "tools/gpu" ]
     sources = [
       "tools/gpu/GrContextFactory.cpp",
       "tools/gpu/GrTest.cpp",
       "tools/gpu/TestContext.cpp",
       "tools/gpu/gl/GLTestContext.cpp",
       "tools/gpu/gl/debug/DebugGLTestContext.cpp",
       "tools/gpu/gl/debug/GrBufferObj.cpp",
       "tools/gpu/gl/debug/GrFrameBufferObj.cpp",
       "tools/gpu/gl/debug/GrProgramObj.cpp",
       "tools/gpu/gl/debug/GrShaderObj.cpp",
       "tools/gpu/gl/debug/GrTextureObj.cpp",
       "tools/gpu/gl/debug/GrTextureUnitObj.cpp",
       "tools/gpu/gl/null/NullGLTestContext.cpp",
     ]
     libs = []
 
     if (is_android) {
       sources += [ "tools/gpu/gl/egl/CreatePlatformGLTestContext_egl.cpp" ]
     } else if (is_linux) {
       sources += [ "tools/gpu/gl/glx/CreatePlatformGLTestContext_glx.cpp" ]
     } else if (is_mac) {
       sources += [ "tools/gpu/gl/mac/CreatePlatformGLTestContext_mac.cpp" ]
     }
 
     if (skia_use_vulkan) {
       sources += [ "tools/gpu/vk/VkTestContext.cpp" ]
     }
+    if (skia_use_mesa) {
+      public_defines += [ "SK_MESA" ]
+      sources += [ "tools/gpu/gl/mesa/GLTestContext_mesa.cpp" ]
+      libs += [ "OSMesa" ]
+    }
   }
 
   test_lib("flags") {
     public_include_dirs = [ "tools/flags" ]
     sources = [
       "tools/flags/SkCommandLineFlags.cpp",
     ]
   }
   test_lib("common_flags") {
     public_include_dirs = [ "tools/flags" ]
@@ skipping 234 matching lines @@
       "tools/get_images_from_skps.cpp",
     ]
     deps = [
       ":flags",
       ":skia",
       "//third_party/jsoncpp",
     ]
     testonly = true
   }
 }