GN: add skia_enable_gpu (default true)

BUILD.gn

 # Copyright 2016 Google Inc.
 #
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("gn/shared_sources.gni")
 
 declare_args() {
-  skia_enable_tools = !is_fuchsia && !is_component_build
-
   skia_use_expat = true
   skia_use_fontconfig = is_linux
   skia_use_freetype = is_android || is_fuchsia || is_linux
   skia_use_giflib = !is_fuchsia
   skia_use_libjpeg_turbo = true
   skia_use_libpng = true
   skia_use_libwebp = !is_fuchsia
   skia_use_sfntly = !is_fuchsia
   skia_use_vulkan = is_android && defined(ndk_api) && ndk_api >= 24
   skia_use_zlib = true
 
   skia_enable_android_framework_defines = false
+  skia_enable_gpu = true
+  skia_enable_tools = !is_fuchsia
 }
 
+# Our tools require static linking (they use non-exported symbols) and GPU support (just lazy).
+skia_enable_tools = skia_enable_tools && skia_enable_gpu && !is_component_build
+
 fontmgr_android_enabled = skia_use_expat && skia_use_freetype
 
 skia_public_includes = [
   "include/android",
   "include/c",
   "include/codec",
   "include/config",
   "include/core",
   "include/effects",
   "include/gpu",
@@ skipping 10 matching lines @@
 # Skia public API, generally provided by :skia.
 config("skia_public") {
   include_dirs = skia_public_includes
   defines = [ "SKIA_DLL" ]
   if (is_linux) {
     defines += [ "SK_SAMPLES_FOR_X" ]
   }
   if (skia_enable_android_framework_defines) {
     defines += skia_android_framework_defines
   }
+  if (!skia_enable_gpu) {
+    defines += [ "SK_SUPPORT_GPU=0" ]
+  }
 }
 
 # Skia internal APIs, used by Skia itself and a few test tools.
 config("skia_private") {
   visibility = [ ":*" ]
 
   include_dirs = [
     "include/private",
     "src/c",
     "src/codec",
@@ skipping 222 matching lines @@
   public_defines = [ "SK_HAS_GIF_LIBRARY" ]
 
   deps = [
     "//third_party/giflib",
   ]
   sources = [
     "src/codec/SkGifCodec.cpp",
   ]
 }
 
+optional("gpu") {
+  enabled = skia_enable_gpu
+  sources = skia_gpu_sources + [ "src/gpu/gl/GrGLDefaultInterface_native.cpp" ]
+
+  # These paths need to be absolute to match the ones produced by shared_sources.gni.
+  sources -= get_path_info([
+                             "src/gpu/gl/GrGLCreateNativeInterface_none.cpp",
+                             "src/gpu/gl/GrGLDefaultInterface_none.cpp",
+                           ],
+                           "abspath")
+  if (is_android) {
+    sources += [ "src/gpu/gl/android/GrGLCreateNativeInterface_android.cpp" ]
+  } else if (is_linux) {
+    sources += [ "src/gpu/gl/glx/GrGLCreateNativeInterface_glx.cpp" ]
+  } else if (is_mac) {
+    sources += [ "src/gpu/gl/mac/GrGLCreateNativeInterface_mac.cpp" ]
+  } else {
+    sources += [ "src/gpu/gl/GrGLCreateNativeInterface_none.cpp" ]
+  }
+}
+
 optional("jpeg") {
   enabled = skia_use_libjpeg_turbo
   public_defines = [ "SK_HAS_JPEG_LIBRARY" ]
 
   deps = [
     "//third_party/libjpeg-turbo:libjpeg",
   ]
   sources = [
     "src/codec/SkJpegCodec.cpp",
     "src/codec/SkJpegDecoderMgr.cpp",
@@ skipping 86 matching lines @@
     ":arm64",
     ":armv7",
     ":avx",
     ":crc32",
     ":dsp",
     ":fontmgr_android",
     ":fontmgr_custom",
     ":fontmgr_fontconfig",
     ":fontmgr_fuchsia",
     ":gif",
+    ":gpu",
     ":jpeg",
     ":none",
     ":pdf",
     ":png",
     ":sse2",
     ":sse41",
     ":sse42",
     ":ssse3",
     ":typeface_freetype",
     ":vulkan",
     ":webp",
     ":xml",
   ]
 
   sources = []
   sources += skia_core_sources
   sources += skia_effects_sources
-  sources += skia_gpu_sources
   sources += skia_sksl_sources
   sources += skia_utils_sources
   sources += [
     "src/android/SkBitmapRegionCodec.cpp",
     "src/android/SkBitmapRegionDecoder.cpp",
     "src/codec/SkAndroidCodec.cpp",
     "src/codec/SkBmpCodec.cpp",
     "src/codec/SkBmpMaskCodec.cpp",
     "src/codec/SkBmpRLECodec.cpp",
     "src/codec/SkBmpStandardCodec.cpp",
     "src/codec/SkCodec.cpp",
     "src/codec/SkCodecImageGenerator.cpp",
     "src/codec/SkMaskSwizzler.cpp",
     "src/codec/SkMasks.cpp",
     "src/codec/SkSampledCodec.cpp",
     "src/codec/SkSampler.cpp",
     "src/codec/SkSwizzler.cpp",
     "src/codec/SkWbmpCodec.cpp",
-    "src/gpu/gl/GrGLDefaultInterface_native.cpp",
     "src/images/SkImageEncoder.cpp",
     "src/images/SkImageEncoder_Factory.cpp",
     "src/images/SkKTXImageEncoder.cpp",
     "src/ports/SkDiscardableMemory_none.cpp",
     "src/ports/SkGlobalInitialization_default.cpp",
     "src/ports/SkImageGenerator_skia.cpp",
     "src/ports/SkMemory_malloc.cpp",
     "src/ports/SkOSFile_stdio.cpp",
     "src/sfnt/SkOTTable_name.cpp",
     "src/sfnt/SkOTUtils.cpp",
     "src/svg/SkSVGCanvas.cpp",
     "src/svg/SkSVGDevice.cpp",
     "src/utils/mac/SkStream_mac.cpp",
     "third_party/etc1/etc1.cpp",
     "third_party/ktx/ktx.cpp",
   ]
 
-  # These paths need to be absolute to match the ones produced by
-  # shared_sources.gni, but this file may be used from different directory
-  # locations.
-  sources -= get_path_info([
-                             "src/gpu/gl/GrGLCreateNativeInterface_none.cpp",
-                             "src/gpu/gl/GrGLDefaultInterface_none.cpp",
-                           ],
-                           "abspath")
-
   libs = []
 
   if (is_win) {
     sources += [
       "src/ports/SkDebug_win.cpp",
       "src/ports/SkFontHost_win.cpp",
       "src/ports/SkFontMgr_win_dw.cpp",
       "src/ports/SkFontMgr_win_dw_factory.cpp",
       "src/ports/SkImageEncoder_WIC.cpp",
       "src/ports/SkImageGeneratorWIC.cpp",
@@ skipping 11 matching lines @@
       "src/ports/SkTLS_pthread.cpp",
       "src/xps/SkDocument_XPS_None.cpp",
     ]
   }
 
   if (is_android) {
     deps += [
       "//third_party/cpu-features",
       "//third_party/expat",
     ]
-    sources += [
-      "src/gpu/gl/android/GrGLCreateNativeInterface_android.cpp",
-      "src/ports/SkDebug_android.cpp",
-    ]
+    sources += [ "src/ports/SkDebug_android.cpp" ]
     libs += [
       "EGL",
       "GLESv2",
       "log",
     ]
   }
 
   if (is_linux) {
     libs += [
       "GL",
       "GLU",
       "X11",
     ]
-    sources += [
-      "src/gpu/gl/glx/GrGLCreateNativeInterface_glx.cpp",
-      "src/ports/SkDebug_stdio.cpp",
-    ]
+    sources += [ "src/ports/SkDebug_stdio.cpp" ]
   }
 
   if (is_mac) {
     sources += [
-      "src/gpu/gl/mac/GrGLCreateNativeInterface_mac.cpp",
       "src/ports/SkDebug_stdio.cpp",
       "src/ports/SkFontHost_mac.cpp",
       "src/ports/SkImageEncoder_CG.cpp",
       "src/ports/SkImageGeneratorCG.cpp",
     ]
     libs += [
       "ApplicationServices.framework",
       "OpenGL.framework",
     ]
   }
 
   if (is_fuchsia) {
-    sources += [
-      "src/gpu/gl/GrGLCreateNativeInterface_none.cpp",
-      "src/ports/SkDebug_stdio.cpp",
-    ]
+    sources += [ "src/ports/SkDebug_stdio.cpp" ]
   }
 }
 
 skia_h_headers = exec_script("gyp/find.py",
                              [ "*.h" ] + rebase_path(skia_public_includes),
                              "list lines",
                              []) -
                  [
                    rebase_path("include/gpu/gl/GrGLConfig_chrome.h"),
                    rebase_path("include/gpu/vk/GrVkBackendContext.h"),
                    rebase_path("include/gpu/vk/GrVkDefines.h"),
                    rebase_path("include/gpu/vk/GrVkInterface.h"),
                    rebase_path("include/gpu/vk/GrVkTypes.h"),
                    rebase_path("include/ports/SkFontMgr_fontconfig.h"),
                  ]
 
 action("skia.h") {
   script = "gn/echo_headers.py"
   args = [ rebase_path("$target_gen_dir/skia.h", root_build_dir) ] +
          rebase_path(skia_h_headers, target_gen_dir)
   outputs = [
     "$target_gen_dir/skia.h",
   ]
 }
 
-if (target_cpu == "x64") {
+if (skia_enable_gpu && target_cpu == "x64") {
   # Our bots only have 64-bit libOSMesa installed.
   # TODO: worth fixing?
   executable("fiddle") {
     include_dirs = [ "$target_gen_dir" ]
     libs = []
     if (is_linux) {
       libs += [ "OSMesa" ]
     }
 
     sources = [
@@ skipping 305 matching lines @@
       "tools/get_images_from_skps.cpp",
     ]
     deps = [
       ":flags",
       ":skia",
       "//third_party/jsoncpp",
     ]
     testonly = true
   }
 }